# Maintainer: Alexey Pavlov <alexpux@gmail.com>

pkgbase=libcrypt
pkgname=('libcrypt-lib-static' 'libcrypt-doc-text')
pkgver=2.1
pkgrel=2
pkgdesc="Encryption/Decryption utility and library"
groups=('base')
arch=('x86_64')
license=('custom')
url="https://cygwin.com/"
makedepends=('gcc' 'git' 'make')
source=(${pkgbase}-${pkgver}::git+https://sourceware.org/git/cygwin-apps/crypt.git#tag=crypt-${pkgver//./_}-release
	0100-static-only.patch)
sha256sums=('SKIP'
	   '171272cbe04a4cbb502fddd518973f50ca2478c772770dd336f80eb92b5df322')

prepare() {
  cd ${srcdir}/${pkgbase}-${pkgver}

  patch -p1 -i ${srcdir}/0100-static-only.patch
}

build() {
  cd "${srcdir}/${pkgbase}-${pkgver}"
  make CC=gcc AR=ar CFLAGS="${CFLAGS}"

  make DESTDIR=${srcdir}/dest install
}

package_libcrypt-lib-static() {
  pkgdesc="Libcrypt headers and libraries"
  groups=('development')
  options=('staticlibs')

  mkdir -p ${pkgdir}/usr

  cp -rf ${srcdir}/dest/usr/include ${pkgdir}/usr/
  cp -rf ${srcdir}/dest/usr/lib ${pkgdir}/usr/
}

package_libcrypt-doc-text() {
  pkgdesc="LIBCRYPT text documentation"
  groups=('documentation' 'doc-text')

  mkdir -p ${pkgdir}/usr/share
  cp -rf ${srcdir}/dest/usr/share/doc ${pkgdir}/usr/share/
}
