[ < ] [ > ]   [ << ] [] [ >> ]         [冒頭] [目次] [見出し] [ ? ]

12. Plotting


[ < ] [ > ]   [ << ] [] [ >> ]         [冒頭] [目次] [見出し] [ ? ]

12.1 Introduction to Plotting

Maximaはプロットするために外部のプロットパッケージを使います。 (以下のPlottingフォーマットを参照してください)。 プロット関数は点一式を計算し、コマンド一式と一緒にプロットパッケージに渡します。 その情報は、 パイプを通したり データが保存されたファイル名と共にプログラムをコールしたりして 外部のプログラムに渡されます。 データファイルの名前は maxout.interfaceです。 interfaceは使用するプロットインターフェース名 (gnuplotか, xmaxima, mgnuplot, gnuplot_pipes)です。

maxout.interfaceファイルを使う場合、 システム変数 maxima_tempdir で指定されたディレクトリに生成します。 場所は変更できます; そのためには、 Maximaが新しいファイルを作ることができる有効なディレクトリを示す文字列を 変数に割り当てます。

プロットを生成した後でも、 ファイルmaxout.interfaceは、 適切な外部のプログラムで再度実行することができます。 もし Maximaのプロットコマンドが何かを表示するのに失敗したなら、 問題の可能性のある元をファイルで調べることができます。

この章で記述されたプロット関数と合わせて、 パッケージ drawは他の機能を追加します。 いくつかのプロットオプションはどちらのプロット文脈でも同じ名前が付けられていますが、 異なる構文を持つことに注意してください; もしこれらのオプションに関係した描画情報をアクセスしたいなら、 きっと ?? optとタイプするでしょう。ここで optはオプション名です。

·

Categories:  Plotting


[ < ] [ > ]   [ << ] [] [ >> ]         [冒頭] [目次] [見出し] [ ? ]

12.2 Plotting Formats

今のところ、Maximaが使う外部のプロットプログラムは2つあります: GnuplotとXmaximaです。 これらのプログラムに対して様々な異なるフォーマットがあります。 それらはオプション plot_format で選択することができます。 (Plotting Options節を参照してください。)

プロットフォーマットは以下の通りです:

·

Categories:  Plotting


[ < ] [ > ]   [ << ] [] [ >> ]         [冒頭] [目次] [見出し] [ ? ]

12.3 Functions and Variables for Plotting

関数: contour_plot (expr, x_range, y_range, options, …)

exprの等高線を領域 x_range, y_rangeでプロットします。 他の引数は plot3d と同じように扱われます。

プロットフォーマットがgnuplotgnuplot_pipesの時だけ この関数は動作します。 追加パッケージ implicit_plotも等高線をプロットするのに使われますが、 それは任意のフォーマットで動作します。 implicit_plot も参照してください。

例:

 
(%i1) contour_plot (x^2 + y^2, [x, -4, 4], [y, -4, 4])$
figures/contour1
 
(%i1) F(x, y) := x^3 + y^2;
                                   3    2
(%o1)                  F(x, y) := x  + y
(%i2) contour_plot (F, [u, -4, 4], [v, -4, 4])$
figures/contour2

plot3dが受け付ける任意のオプションを足すことができます; 例えば、オプション legend に falseの値を入れると凡例を取り除きます。 Gnuplotはデフォルトで3つの高等線を示すように選びます。 レベルの数を増やすにはカスタムの gnuplot前置きを指定する必要があります;

 
(%i1) contour_plot (u^3 + v^2, [u, -4, 4], [v, -4, 4], 
                    [legend,false],
                    [gnuplot_preamble, "set cntrparam levels 12"])$
figures/contour3
·

Categories:  Plotting

関数: get_plot_option (keyword, index)

keywordという名前を持つオプションの値を返します。 オプションはグローバル変数 plot_optionsに保存されています。 (訳注: indexはオプションです。省略された場合、下記内容を含むリストを返します。) indexに1を与えるとキーワード自身を返します; 2を与えるとキーワードに続く一番目のパラメータを返す、という具合です。

plot_optionsset_plot_option , Plotting Optionの節も参照してください。

関数: implicit_plot (expr, x_range, y_range)
関数: implicit_plot ([expr_1, ..., expr_n], x_range, y_range)

1つ以上の式のプロットを陰形式で表示します。 exprはプロットされる式で、 x_rangeは水平軸の範囲、 y_rangeは垂直軸の範囲です。 implicit_plotset_plot_option関数が設定するgnuplotドライバのグローバル設定を考慮します。 オプションはオプション引数としてimplicit_plot関数にも渡されることができます。

implicit_plotx_rangey_rangeで与えられる領域上で符号の変化を辿ることで機能し、 複雑な式では失敗する可能性があります。

load(implicit_plot)はこの関数をロードします。

例:

 
(%i1) implicit_plot (x^2 = y^3 - 3*y + 1, [x, -4, 4], [y, -4, 4],
 [gnuplot_preamble, "set zeroaxis"]);
figures/implicit_plot

関数: make_transform ([var1, var2, var3], fx, fy, fz)

plot3dのオプション transform_xy での使用に適した関数を返します。 3変数 var1, var2, var3は3つのダミー変数名です。 それらは plot3dコマンドが与える3変数 (最初2つの独立変数と、そのあとそれら2つの変数に依存する関数)を表します。 3つの関数fx, fy, fzはそれら3変数だけで決まるはずで、 プロットすべき対応する x, y, z座標を与えます。 デフォルトで定義された2つの変換があります; polar_to_xyspherical_to_xyz ; それら2つの変換に関するドキュメンテーションを参照してください。

·

Categories:  Plotting

システム関数: polar_to_xy

plot3dの transform_xy オプションに対する値として与えることができます。 その効果は plot3dの2つの独立変数をz軸からの距離と方位角(極座標)として通訳し、 それらを xと y座標に変換することです。

·

Categories:  Plotting

関数: plot2d (plot, x_range, …, options, …)
関数: plot2d ([plot_1, …, plot_n], …, options, …)
関数: plot2d ([plot_1, …, plot_n], x_range, …, options, …)

ここで plot, plot_1, …, plot_nは式か関数名、もしくは以下のいずれかの形式のリストです:

[discrete, [x1, ..., xn], [y1, ..., yn]], [discrete, [[x1, y1], ..., [xn, ..., yn]], または [parametric, x_expr, y_expr, t_range]

1つもしくは複数の式を1変数か1パラメータの関数としてプロット表示します。

plot2dは1つもしくは複数のプロットを2次元に表示します。 プロットを定義するのに式や関数名を使う時には、 それらは1変数varだけに依存すべきであり 変数名とその最小値と最大値を提供するためにx_rangeの使用が必須です; x_rangeの構文は以下の通りです:

[variable, min, max]

プロットを離散形式やパラメトリック形式で定義することもできます。 離散形式は既定の座標で表された点の集合をプロットするのに使われます。 離散プロットはキーワード discreteで始まり、 値についてのリスト1つか2つが続くリストで定義されます。 もし2つのリストが与えられたら、それらは同じ長さを持たなければいけません; 1番目のリストはプロットされる点のx座標として、 2番目のリストはy座標として解釈されます。 もし discreteキーワードの後、リストが1つだけ与えられたら、 リスト上のそれぞれの要素は点のxとy座標に対応する2つの値を持つリストでなければいけません。

パラメトリックプロットはキーワード parametricで始まり、 式か関数名2つとパラメータの範囲を持つリストで定義されます。 パラメータの範囲はパラメータ名とその最小値、最大値が続くリストでなければいけません:

[param, min, max]

paramminから maxに増えるにつれ、 式または関数2つで与えられる座標点が描く軌跡をプロットは表示します。

垂直軸の範囲は以下の形式を持つオプション引数です:

[y, min, max](キーワード yはいつも垂直軸に使われます)。

このオプションを使うと、 プロットが到達する値に関係なくオプションの垂直範囲ぴったりをプロットは表示します。 もし垂直範囲を指定しなかったなら、 プロット点のy座標の最小値と最大値に従って垂直範囲が設定されます。

他のすべてのオプションも キーワードで始まり、1つか複数の値が続くリストでなければいけません。 plot_options を参照してください。

もし複数のプロットがプロットされるなら式のそれぞれを識別するために凡例が書かれます。 その凡例で使われるラベルはオプション legend で与えることができます。 もしそのオプションが使われないなら Maximaは式や関数名からラベルを生成します。

例:

よくある関数のプロット:

 
(%i1) plot2d (sin(x), [x, -%pi, %pi])$
figures/plotting2

もし関数の増大が速すぎるなら yオプションを使って垂直軸の値を制限する必要があるかもしれません:

 
(%i1) plot2d (sec(x), [x, -2, 2], [y, -20, 20])$
plot2d: some values were clipped.
figures/plotting3

プロットの外観は使うプロットプログラム次第で異なるかもしれません。 プロットボックスが使用不可能になっている時 Xmaximaは矢印を使って軸をプロットします:

 
(%i1) plot2d ( x^2-1, [x, -3, 3], [y, -2, 10],
                      [box, false], [plot_format, xmaxima])$
figures/plotting1

対数プロットの例:

 
(%i11) plot2d (exp(3*s), [s, -2, 2], [logy])$
figures/plotting4

関数を名前でプロット:

 
(%i1) F(x) := x^2 $
(%i2) :lisp (defun |$g| (x) (m* x x x))
$g
(%i2) H(x) := if x < 0 then x^4 - 1 else 1 - x^5 $
(%i3) plot2d ([F, G, H], [u, -1, 1], [y, -1.5, 1.5])$
figures/plotting5

パラメトリックに定義されたバタフライカーブのプロット:

 
(%i1) r: (exp(cos(t))-2*cos(4*t)-sin(t/12)^5)$
(%i2) plot2d([parametric, r*sin(t), r*cos(t), 
             [t, -8*%pi, 8*%pi], [nticks, 2000]])$
figures/plotting6

7点だけでプロットする時の2回転「円」:

 
(%i1) plot2d ([parametric, cos(t), sin(t),
              [t, -2*%pi, 2*%pi], [nticks, 8]])$
figures/plotting7

円のパラメトリック表現を使ったよくある関数のプロット。 円を丸く楕円のように変形しないように プロットのサイズは xとyオプションで調整されています。 これらの値はこのプロットを生成するのに使った Postscript端末ではうまく機能します; あなたはあなたのスクリーンのために値を調整しなければいけないかもしれません。

 
(%i1) plot2d([[parametric, cos(t), sin(t),
              [t,0,2*%pi], [nticks, 80]],
        abs(x)], [x,-2,2], [y, -1.5, 1.5])$
plot2d: some values were clipped.
figures/plotting8

x座標, y座標を別々に定義した点の離散集合のプロット:

 
(%i1) plot2d ([discrete, [10, 20, 30, 40, 50],
                         [.6, .9, 1.1, 1.3, 1.4]])$
figures/plotting9

前の例で示された同じ点ですが、それぞれの点を別々に定義し点を繋ぐ線をなくしました。

 
(%i1) plot2d([discrete, [[10, .6], [20, .9], [30, 1.1],
                         [40, 1.3], [50, 1.4]]],
                        [style, points])$
figures/plotting10

この例では、3つの列を持つテーブルがファイル”data.txt”に保存され、 読み込まれ、2番目、3番目の列は2つの軸上にプロットされます:

 
(%i1) with_stdout ("data.txt", for x:0 thru 10 do 
                                   print (x, x^2, x^3))$
(%i2) data: transpose ( read_matrix ("data.txt"))$
(%i3) plot2d ([discrete, transpose(data)[2], transpose(data)[3]],
  [style,points], [point_type,diamond], [color,red])$
figures/plotting11

実験データ点をデータを予測する理論的関数と一緒にプロット:

 
(%i1) xy: [[10, .6], [20, .9], [30, 1.1], [40, 1.3], [50, 1.4]]$
(%i2) plot2d([[discrete, xy], 2*%pi*sqrt(l/980)], [l,0,50],
        [style, points, lines], [color, red, blue],
        [point_type, asterisk],
        [legend, "experiment", "theory"],
        [xlabel, "pendulum's length (cm)"],
        [ylabel, "period (s)"])$
figures/plotting12

プロットオプションに関する節も参照してください。

·

Categories:  Plotting

関数: plot3d (expr, x_range, y_range, …, options, …)
関数: plot3d ([expr_1, expr_2, expr_3], x_range, y_range, …, options, …)

2変数関数もしくはパラメトリック形式で定義された1つか複数の表面のプロットを表示します。

プロットされる関数は式か関数名として指定できます。 違った側面から表面を見るためにマウスを使ってプロットを回転することができます。

例:

よくある関数のプロット:

 
(%i1) plot3d (2^(-u^2 + v^2), [u, -3, 3], [v, -2, 2]);
figures/plotting13

無限大に発散する関数を制限するための zオプションの使用(この場合、関数はxとy軸上でマイナス無限だい); これは線のみ陰影なしでプロットする仕方も示します。

 
(%i1) plot3d ( log ( x^2*y^2 ), [x, -2, 2], [y, -2, 2], [z, -8, 4],
               [palette, false], [color, magenta, blue])$
figures/plotting14

zの無限大はいかなる漸近線上にも落ちないグリッドを選ぶことによっても避けることができます; この例は事前に定義されたパレットの1つ、この場合4番目のものを選択する仕方も示します:

 
(%i1) plot3d( log (x^2*y^2), [x, -2, 2], [y, -2, 2], 
         [grid, 29, 29],
         [palette, get_plot_option(palette,5)])$
figures/plotting15

同じ領域を共有する同じプロットでの2つの表面; gnuplotでは2つの表面は同じパレットを使用します:

 
(%i1) plot3d ([2^(-x^2 + y^2), 4*sin(3*(x^2+y^2))/(x^2+y^2),
              [x, -3, 3], [y, -2, 2]])$
figures/plotting16

異なる領域を持つ同じ2つの表面; xmaximaでは、 それぞれの表面はオプションパレットで定義されたリストから選ばれた異なるパレットを使います:

 
(%i1) plot3d ( [[2^(-x^2 + y^2),[x,-2,2],[y,-2,2]],
         4*sin(3*(x^2+y^2))/(x^2+y^2),
         [x, -3, 3], [y, -2, 2]], [plot_format,xmaxima])$
figures/plotting17

パラメトリックに定義されたKleinの壷のプロット:

 
(%i1) expr_1:5*cos(x)*(cos(x/2)*cos(y)+sin(x/2)*sin(2*y)+3.0)-10.0$
(%i2) expr_2:-5*sin(x)*(cos(x/2)*cos(y) + sin(x/2)*sin(2*y) + 3.0)$
(%i3) expr_3: 5*(-sin(x/2)*cos(y) + cos(x/2)*sin(2*y))$
(%i4) plot3d ([expr_1, expr_2, expr_3], [x, -%pi, %pi],
        [y, -%pi, %pi], [grid, 40, 40])$
figures/plotting18

球座標から直交座標に変換するのにあらかじめ定義された変換 spherical_to_xyzを使った球調和のプロット。 spherical_to_xyz に関するドキュメンテーションを参照してください。

 
(%i1) plot3d (sin(2*theta)*cos(phi), [theta, 0, %pi],
              [phi, 0, 2*%pi],
              [transform_xy, spherical_to_xyz], [grid,30,60])$
figures/plotting19

円筒座標から直交座標に変換するのにあらかじめ定義された変換 polar_to_xyを使った球面調和関数のプロット。 polar_to_xy に関するドキュメンテーションを参照してください。 この例は境界ボックスと凡例を消去する仕方も示します。

 
(%i1) plot3d (r^.33*cos(th/3), [r, 0, 1], [th, 0, 6*%pi],
         [grid, 12, 80],
         [transform_xy, polar_to_xy], [box, false],
         [legend,false])$
figures/plotting20

球座標から直交座標への変換を使っての球のプロット。 xmaximaでは球の対称形を維持するように3つの軸は同じ比でスケールされます。 同一色で異なる陰影のパレットが使われます:

 
(%i1) plot3d ( 5, [theta, 0, %pi], [phi, 0, 2*%pi],
         [plot_format,xmaxima],
         [transform_xy, spherical_to_xyz],
         [palette,[value,0.65,0.7,0.1,0.9]])$
figures/plotting21

行列を使った2変数関数の定義。 関数の定義の中のシングルクォートに注意してください。 行列が整数添字を要求する状況に実際に至る時 plot3dが失敗しないためのものです。

 
(%i1) M: matrix([1, 2, 3, 4], [1, 2, 3, 2], [1, 2, 3, 4],
                [1, 2, 3, 3])$
(%i2) f(x, y) := float('M [round(x), round(y)])$
(%i3) plot3d (f(x,y), [x, 1, 4], [y, 1, 4], [grid, 4, 4])$
apply: subscript must be an integer; found: round(x)
figures/plotting22

elevationを零に設定することで表面を地図として見ることができます。 その地図はそれぞれの色は違ったレベルを表現します。 オプションcolorbox は色とレベルの対応を示すのに使われます。 メッシュ線を使用不可にし色が見やすいようにしています。

 
(%i1) plot3d (cos (-x^2 + y^3/4), [x, -4, 4], [y, -4, 4],
        [mesh_lines_color, false], [elevation, 0], [azimuth, 0],
        [colorbox, true], [grid, 150, 150])$
figures/plotting23

プロットオプションについての節も参照してください。

·

Categories:  Plotting

システム変数: plot_options

このリストの要素はプロットのデフォルトオプションを指定します。 plot2dplot3d がコールされる時もしオプションが指定されたら、 その値はデフォルトオプションより優先されます。 そうでないなら plot_optionsの中の値が使われます。 デフォルトオプションは set_plot_optionを使って割り当てられます。 プロットコマンドそれぞれに特化したローカルオプションがあり、 それらはグローバルオプションのこのリストには含まれません。

plot_optionsのそれぞれの要素は2つ以上の項目のリストです。 最初の項目はオプション名で残りはオプションに割り当てられる値です。 いくつかの場合、割り当てられた値はリストであり複数の項目からなることがあります。

set_plot_optionget_plot_option , Plottting Optionsの節も参照してください。

·

Categories:  Plotting

関数: set_plot_option (option)

プロットオプションの節にリストされているオプションのほとんどを受け付け それらをグローバル変数 plot_optionsに保存します。

set_plot_optionは引数を評価し、 (与えられたオプションを変更した後、)完全なリスト plot_optionsを返します。

plot_optionsget_plot_option , Plotting Optionsの節も参照してください。

例:

grid 値の変更。

 
(%i1) set_plot_option ([grid, 30, 40]);
(%o1) [[t, - 3, 3], [grid, 30, 40], [transform_xy, false], 
[run_viewer, true], [axes, true], [plot_format, gnuplot_pipes], 
[color, blue, red, green, magenta, black, cyan], 
[point_type, bullet, circle, plus, times, asterisk, box, square, 
triangle, delta, wedge, nabla, diamond, lozenge], 
[palette, [hue, 0.25, 0.7, 0.8, 0.5], 
[hue, 0.65, 0.8, 0.9, 0.55], [hue, 0.55, 0.8, 0.9, 0.4], 
[hue, 0.95, 0.7, 0.8, 0.5]], [gnuplot_term, default], 
[gnuplot_out_file, false], [nticks, 29], [adapt_depth, 5], 
[gnuplot_preamble, ], [gnuplot_default_term_command, 
set term pop], [gnuplot_dumb_term_command, set term dumb 79 22], 
[gnuplot_ps_term_command, set size 1.5, 1.5;set term postscript ¥
eps enhanced color solid 24], [plot_realpart, false]]
·

Categories:  Plotting

システム関数: spherical_to_xyz

plot3dtransform_xy オプションの値として与えることができます。 その効果は plot3dでの2つの独立変数と関数を点の球座標 (1番目はz軸に対する角度、次にxy射影のx軸に対する角度、最後に原点からの距離) として解釈し、それらをx,y,z座標に変換することです。

·

Categories:  Plotting


[ < ] [ > ]   [ << ] [] [ >> ]         [冒頭] [目次] [見出し] [ ? ]

12.4 Plotting Options

すべてのオプションは、この節のキーワードの1つで始まり1つ以上の値が続くリストで構成されます。 オプションのほとんどはどのプロットコマンド (plot2d , plot3d , contour_plot , implicit_plot )でも、 また関数 set_plot_option の中でも使うことができます; 例外は以下のリストの中で明記されます。

プロットオプション: adapt_depth [adapt_depth, integer]

デフォルト値: 5

適応プロットルーチンで使われる分割の最大数です。

·

Categories:  Plotting

プロットオプション: axes [axes, symbol]

デフォルト値: true

ここで symboltrue, false, x, yのいずれかです。 もし falseなら軸は表示されません; もし xyに等しいならxかy軸のみが表示され、 trueに等しいなら両方の軸が表示されます。 このオプションは plot2dと implicit_plotだけが使います。

·

Categories:  Plotting

プロットオプション: azimuth [azimuth, number]

デフォルト値: 30

plot3dプロットは、 plot2dと同じように水平軸と垂直軸を表す x軸と y軸と 紙から垂直に立つ z軸をスタート地点に考えることができます。 その後、z軸を x軸の回りに elevationに等しい角度だけ回転し、 さらに xy平面を新しい z軸の回りに角度 azimuthだけ回転します。 このオプションは azimuthに関する値を単位、度で設定します。

elevation も参照してください。

·

Categories:  Plotting

プロットオプション: box [box, symbol]

デフォルト値: true

もし trueに設定されるなら境界枠がプロットに表示されます; もし falseに設定されるなら枠は表示されません。

·

Categories:  Plotting

プロットオプション: color [color, color_1, …, color_n]

デフォルト値: blue, red, green, magenta, black, cyan

plot2dimplicit_plot では様々な曲線の色を定義します。 plot3d では、パレットが使われないとき表面のメッシュ線の色を定義します; 表面の片方の側面は色 color_1で、逆の側面は color_2(か もし1つの色しかないなら同じ色)です。

もし色よりも曲線や表面が多いなら色は順に繰り返されます。 gnuplotを使う時、色は blue, red, green, magenta, black, cyanです; xmaximaでは色はそれらか 文字#で始まり6桁の16進数字が続く文字列です; 2つは赤成分、2つは緑成分、2つは青成分です。 もし未知の色の名前が与えられたら黒が代わりに使われます。

·

Categories:  Plotting

プロットオプション: colorbox [colorbox, symbol]

デフォルト値: false

ここで symboltruefalseです。 もし trueなら、 plot3d が zの違った値を表現するために 違った色のパレットを使う時はいつでも、 zの値の大きさに従って使われた色を示す枠が右に示されます。 このオプションは xmaximaでは機能しません。

·

Categories:  Plotting

プロットオプション: elevation [elevation, number]

デフォルト値: 60

plot3d プロットは、 plot2d と同じように水平軸と垂直軸を表す x軸と y軸と 紙から垂直に立つ z軸をスタート地点に考えることができます。 その後、z軸を x軸の回りに elevationに等しい角度だけ回転し、 さらに xy平面を新しい z軸の回りに角度 azimuthだけ回転します。 このオプションは elevationの値を度単位で設定します。

azimuth も参照してください。

·

Categories:  Plotting

プロットオプション: grid [grid, integer, integer]

デフォルト値: 30, 30

3次元プロットのためにx方向、y方向で使われるグリッド点の数を設定します。

·

Categories:  Plotting

プロットオプション: legend [legend, string_1, …, string_n]
プロットオプション: legend [legend, false]

複数のプロットを表示する時プロットのラベルを指定します。 もし与えたラベルの数より多くの式があるならラベルは繰り返されます。 もし値 falseを与えたなら、凡例は表示されません。 デフォルトでは式や関数の名前が使われます。また、点の離散集合に関しては単語 discrete1, discrete2, …が使われます。 このオプションは set_plot_option で設定することができます。

·

Categories:  Plotting

プロットオプション: logx [logx]

水平軸を対数的にスケールするようにします。 set_plot_option では使うことはできません。

·

Categories:  Plotting

プロットオプション: logy [logy]

垂直軸を対数的にスケールするようにします。 set_plot_option では使うことはできません。

·

Categories:  Plotting

Plot option: mesh_lines_color [mesh_lines_color, color]

デフォルト値: black

パレットが使われる時 plot3dがメッシュ線を描くのに使う色を設定します。 オプション color と同じ色を受け付けます。 (colorで許される色のリストを参照してください。) 値 falseを与えてメッシュ線を完全に消すこともできます。

·

Categories:  Plotting

プロットオプション: nticks [nticks, integer]

デフォルト値: 29

plot2d で関数をプロットする時、 関数をプロットするための適応プロットルーチンによって使われる点の数の初期値を与えます。 plot2dや plot3d でパラメトリック関数をプロットする時、 プロットで表示される点の数を設定します。

·

Categories:  Plotting

プロットオプション: palette [palette, [palette_1], ..., [palette_n]]
プロットオプション: palette [palette, false]

デフォルト値: [hue, 0.25, 0.7, 0.8, 0.5], [hue, 0.65, 0.8, 0.9, 0.55], [hue, 0.55, 0.8, 0.9, 0.4], [hue, 0.95, 0.7, 0.8, 0.5]

1つのパレットか複数のパレットのリストで構成されます。 パレットそれぞれは4つの数が続くキーワード付きリストです。 最初の3つの数は0と1の間でなければならず、 zの最小値に割り当てられる基本色の色調と飽和、値を定義します。 キーワードは3つの属性(色調、飽和、値)のいずれかがzの値に従っての増えることを指定します。 その最後の数は1よりも大きいこともマイナスでもありえます; 変更された属性の対応する値は法1で丸められます。

gnuplotはリストの中の最初のパレットだけを使います; xmaximaは、複数の表面を一緒にプロットする時リストの中のパレットを順に使います; パレットの数が尽きたらそれらは順に繰り返されます。

メッシュ線の色はオプション mesh_lines_color で与えられます。 もし paletteが値 falseを与えられたら、 表面は陰影されず曲線のメッシュだけで表されます。 その場合、線の色はオプション color で決定されます。

·

Categories:  Plotting

プロットオプション: plot_format [plot_format, format]

デフォルト値: Windowsシステムではgnuplot, 他のシステムではgnuplot_pipes

ここでformatは以下のいずれかです; gnuplot, xmaxima, mgnuplot, gnuplot_pipes.

プロットで使われるフォーマットを設定します。

·

Categories:  Plotting

プロットオプション: plot_realpart [plot_real_part, symbol]

デフォルト値: false

trueに設定される時、 プロットされる関数は実数値がプロットされる複素関数と見なされます; これは realpart(function)をプロットすることと同値です。 もし falseに設定されたら、 関数が実数値を与えない時には何も表示されません。 例えば、 xが負の時、 log(x)は実数値がlog(abs(x))に等しい複素数値を与えます; もし plot_realparttrueだったなら log(-5)log(5)としてプロットされますが、 もし plot_realpartfalseだったなら 何もプロットされません。

·

Categories:  Plotting

プロットオプション: point_type [point_type, type_1, …, type_n]

デフォルト値: bullet, circle, plus, times, asterisk, box, square, triangle, delta, wedge, nabla, diamond, lozenge

gnuplotでは、 スタイル“points”か“linespoints”でプロットされた点の集合それぞれは このリストから取られたオブジェクトを使って順に表されます。 もしこのリスト内のオブジェクト以上に点の集合があるなら、 それらは順に繰り返されます。 使うことができる可能なオブジェクト: bullet, circle, plus, times, asterisk, box, square, triangle, delta, wedge, nabla, diamond, lozenge

·

Categories:  Plotting

プロットオプション: psfile [psfile, string]

このオプションは、プロットをスクリーンに表示する代わりに stringに等しい名前のポストスクリプトファイルに保存します。 デフォルトでは、そのファイルは変数 maxima_tempdir で定義されたディレクトリに 生成されます; 変数の値を変えて違うディレクトリにファイルを保存できます。

·

Categories:  Plotting

プロットオプション: run_viewer [run_viewer, symbol]

デフォルト値: true

プロットフォーマット用の適切なビューアを走らせるかどうか制御します。

·

Categories:  Plotting

プロットオプション: style [style, type_1, …, type1_n]
プロットオプション: style [style, [style_1], …, [style_n]]

デフォルト値: lines (太さ 1でオプション colorで与えられた最初の色を持つ線で結んだ点一式をプロットします)

様々な関数やデータ一式のために2dプロットで使われるスタイル。 単語 styleの後には1つ以上のスタイルが続きます。 もし与えられたスタイルよりも多くの関数やデータ集合があったらスタイルは繰り返されます。 それぞれのスタイルは、実線のためにはlines、孤立点のためにはpoints、 線分と孤立点のためにはlinespoints、点線のためにはdotsを取り得ます。 Gnuplotでは impulsesスタイルも使えます。

スタイルそれぞれはいくつかの追加のパラメータとリストの中に入れることができます。 linesは1つか2つの数を取ります: 線の太さと、色を指定する整数。 デフォルトの色コードは、1: 青, 2: 赤, 3: マゼンタ, 4: オレンジ, 5: ブラウン, 6: ライム, 7: アクア、です。 もしX11ではない端末でGnuplotを使うならこれらの色は違っているかもしれません; 例えば、もしオプション [gnuplot_term, ps]を使うなら 色インデックス 4はオレンジではなく黒に対応します。

pointsは1つか2つか3つのパラメータを取ります; 最初のパラメータは点の半径、2番目のパラメータは同じ色を選択する (linesで使われるコードと同じ)整数、 3番目のパラメータは現在Gnuplotでだけ使われており、 点の代わりにいくつかのオブジェクトに対応します。 オブジェクトのデフォルト値は、1: 黒丸, 2: 白丸, 3: 十字, 4: ×, 5: 米印, 6: 黒四角, 7: 白四角, 8: 黒三角, 9: 白三角, 10: 黒逆三角, 11: 白逆三角, 12: 黒菱形, 13: 白菱形 です。

linesdotsは4つまでのパラメータを取ります; 線の太さ、点の半径、色、点を置き換えるオブジェクトのタイプ。

colorpoint_type も参照してください。

·

Categories:  Plotting

プロットオプション: t [t, min, max]

デフォルト値: -3, 3

パラメトリックプロットのデフォルトの範囲。

·

Categories:  Plotting

プロットオプション: transform_xy [transform_xy, symbol]

デフォルト値: false

ここで、symbolfalseか関数 transform_xyを使って得られる結果をです。 もし falseと違うなら plot3dで3座標を変換するのに使われます。

make_transform , polar_to_xy , spherical_to_xyz を参照してください。

·

Categories:  Plotting

プロットオプション: x [x, min, max]

plot2d コマンドの最初の(または plot3d の最初の二つのどちらかの) オプションとして使われる時、 1番目の独立変数が xであることを示しその範囲を設定します。 最初のオプションの後(またはplot3dでは2番目のオプションの後)、 プロット内で示される有効な水平領域を定義するために再び使うことができます。

·

Categories:  Plotting

プロットオプション: xlabel [xlabel, string]

1番目の軸をラベルするstringを指定します; もしこのオプションが使われないなら、 plot2dimplicit_plot で関数をプロットする時、 そのラベルは独立変数の名前です。 plot3d で表面を、もしくはcontour_plot で等高線をプロットする時、 そのラベルは1番目の変数の名前です。 パラメトリックプロットの場合、1番目の式です。 set_plot_option では使うことはできません。

·

Categories:  Plotting

プロットオプション: y [y, min, max]

plot3d での最初の2つのオプションの1つとして使われる時、 独立変数の1つが yであることを示しその範囲を設定します。 そうでないならプロットで示される2番目の変数の有効領域を定義します。

·

Categories:  Plotting

プロットオプション: ylabel [ylabel, string]

二番目の軸をラベルするstringを指定します; もしこのオプションが使われないなら、 plot2dimplicit_plot で関数をプロットする時 そのラベルは、”y”となり、 plot3d で表面をプロットする時や contour_plot で等高線をプロットする時 二番目の変数名となり、 パラメトリックプロットの場合には二番目の式になります。 set_plot_option では使うことはできません。

·

Categories:  Plotting

プロットオプション: z [z, min, max]

プロットで示されるzの値の有効範囲を設定するために plot3d で使われます。

·

Categories:  Plotting

プロットオプション: zlabel [zlabel, string]

plot3d を使う時、第三軸をラベルする stringを指定します。 もしこのオプションが使われないなら、 そのラベルは表面をプロットする時は“z”となり、 パラメトリックプロットの場合には三番目の式になります。 set_plot_option では使うことはできません。 また、plot2d , implicit_plot では無視されます。

·

Categories:  Plotting


[ < ] [ > ]   [ << ] [] [ >> ]         [冒頭] [目次] [見出し] [ ? ]

12.5 Gnuplot Options

gnuplotに特化したプロットオプションがいくつかあります。 これらのオプションのいくつかは gnuplotコマンドそのものであり文字列として指定されます。 詳細はgnuplotドキュメンテーションを参照してください。 ほとんどの場合、これらのオプションは より一般的な上記のオプションの1つで置き換えることができます; これらの場合、より一般的な形式を使うことをお勧めします。

プロットオプション: gnuplot_term

gnuplot用の出力端末タイプを設定します。

·

Categories:  Plotting

プロットオプション: gnuplot_out_file

gnuplot_term オプションと関連して使われる時、 Gnuplotがサポートするグラフィックフォーマットの1つで ファイルにプロットを保存するのに使われます。 もしポストスクリプトファイルを生成したいなら、 代わりにオプション psfile を使うことができます。 これはOpenmathでも機能し、たった1つのオプションで同じことができます。

 
[gnuplot_term, png], [gnuplot_out_file, "graph3.png"]
·

Categories:  Plotting

プロットオプション: gnuplot_pm3d

falseの値ではPM3Dモードの使用を抑制するのに使われます。 PM3Dモードはデフォルトで使用可能です。

·

Categories:  Plotting

プロットオプション: gnuplot_preamble

プロットを描く前に gnuplotコマンドを挿入します。 有効な gnuplotコマンドはどんなものでも使うことができます。 複数のコマンドはセミコロンで分離されなければいけません。 提示例はログスケールプロットを生成します。 gnuplot_preambleのデフォルト値は空の文字列""です。

·

Categories:  Plotting

プロットオプション: gnuplot_curve_titles

これは上記で記載した legend で置き換えられた古いオプションです。

·

Categories:  Plotting

プロットオプション: gnuplot_curve_styles

これは上記で記載した style で置き換えられた古いオプションです。

·

Categories:  Plotting

プロットオプション: gnuplot_default_term_command

デフォルト端末の端末タイプを設定する gnuplotコマンド。 デフォルト値は "set term pop"です。

·

Categories:  Plotting

プロットオプション: gnuplot_dumb_term_command

ダム端末の端末タイプを設定するgnuplotコマンド。 デフォルト値は "set term dumb 79 22"です。 これは79文字 x 22文字のテキスト出力を生成します。

·

Categories:  Plotting

プロットオプション: gnuplot_ps_term_command

ポストスクリプト端末の端末タイプを設定するgnuplotコマンド。 デフォルト値は "set size 1.5, 1.5; set term postscript eps enhanced color solid 24", です。 これはサイズをgnuplotのデフォルトの1.5倍に設定し、フォントサイズを24に設定などします。 set term postscriptの詳細については gnuplotドキュメンテーションを参照してください。

·

Categories:  Plotting


[ < ] [ > ]   [ << ] [] [ >> ]         [冒頭] [目次] [見出し] [ ? ]

12.6 Gnuplot_pipes Format Functions

関数: gnuplot_start ()

gnuplot_pipesフォーマットでのプロットのため使われる gnuplotへのパイプを開きます。 プロットの前に手動でパイプを開く必要はありません。

·

Categories:  Plotting

関数: gnuplot_close ()

gnuplot_pipesフォーマットで使われた gnuplotへのパイプを閉じます。

·

Categories:  Plotting

関数: gnuplot_restart ()

gnuplot_pipesフォーマットで使われた gnuplotへのパイプを閉じて新しいパイプを開きます。

·

Categories:  Plotting

関数: gnuplot_replot ()
関数: gnuplot_replot (s)

gnuplotウィンドウを更新します。 もし gnuplot_replotが文字列 sの中の gnuplotコマンドを引数としてコールされたなら ウィンドウが再プロットされる前に sを gnuplotに送ります。

·

Categories:  Plotting

関数: gnuplot_reset ()

gnuplot_pipesフォーマットと一緒に使われる gnuplotの状態をリセットします。 gnuplotウィンドウを更新するには gnuplot_resetの後に gnuplot_replot をコールください。

·

Categories:  Plotting


[ << ] [ >> ]           [冒頭] [目次] [見出し] [ ? ]

この文書は市川 雄二によって2012年1月月7日texi2html 1.82を用いて生成されました。