Plot 0
	name <ARC: DZ-Resistance>

	% Faction N1 is trying to expand into the dead zone, but
	% not everyone is happy about that.

	% E1 is the faction behind the story
	Element1 <Grab 1>

	% E2 is the NPC who will give the PC the mission.
	Element2 <Character Bandit HasMecha Heroic>


	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	% V1 = Time Limit
	% V2 = Combat Indicator, if V2=1 combat has been entered
	% V3 = Email sent indicator.

	% On a cleanup request, delete this plot unless combat has been
	% entered.
	cleanup <if= V2 0 AdvancePlot 0>

	% Time limit. This plot will conclude in one day, or immediately
	% if NPC E2 is killed. It will also conclude if the corporation has
	% been behaving itself extremely well in the dead zone... as
	% measured by the public opposition variable dropping beneath -d10.
	Init_Start <ifNPCOK E2 else GoDelete if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	start <ifNPCOK E2 else GoDelete if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	GoCheckTime <if= V2 0 ifG S102 -d10 else GoFlatDelete ifG ComTime V1 if= d2 1 else GoDelete S+ 101 -1 AdvancePlot 0>
	GoDelete <S+ 102 1 AdvancePlot 0>
	GoFlatDelete <AdvancePlot 0>

	% Combat check. If combat has been entered, V2=1.
	nu1 <if= T1 0 if= V2 1  V= 2 2  LoseRenown  S+ 102 1>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 50  S+ 101 -d3 S+ 102 1>

	% 5Min <if= d50 23 if= V3 0 ifG RReact E2 d70 if# PCFac E1 ifG -d25 PCRep 2 ifG PCRep 1 d25 V= 3 1 Email d5>
	5Min <if= d50 23 if= V3 0 ifG RReact E2 d70 if# PCFac E1 ifG -d25 PCRep 2 ifG PCRep 1 d25 V= 3 1 SetNPC E2 Email d5>

	% *********************
	% *** MESSAGE BLOCK ***
	% *********************

	% 01 - 05 :  Email Messages.
	%  The NPC is offering the PC a mission via email.
	% Msg1 <\PERSONA E2 @ \SCENE EScene 2 :// I need some help. My home is in trouble... please respond.>
	Msg1 <\PERSONA E2 @ \SCENE EScene 2 :// 協力が必要だ。私の故郷に問題が起きている…来てくれ。>
	% Msg2 <\PERSONA E2 @ \SCENE EScene 2 :// How'd you like to be an activist? Come see me for details.>
	Msg2 <\PERSONA E2 @ \SCENE EScene 2 :// 活動をするのはどうだろう？詳細を聞きに来てくれ。>
	% Msg3 <\PERSONA E2 @ \SCENE EScene 2 :// Got a mission planned against \ELEMENT 1 . Want to take part?>
	Msg3 <\PERSONA E2 @ \SCENE EScene 2 :// \ELEMENT 1 に対抗しようという作戦がある。参加するか？>
	% Msg4 <\PERSONA E2 @ \SCENE EScene 2 :// \ELEMENT 1 is moving into my clan's territory, going to shut them down...>
	Msg4 <\PERSONA E2 @ \SCENE EScene 2 :// \ELEMENT 1 が我が一門の領土に進入してきた。奴らを追い出そう…。>
	% Msg5 <\PERSONA E2 @ \SCENE EScene 2 :// Got a job for you if you're interested.>
	Msg5 <\PERSONA E2 @ \SCENE EScene 2 :// もしその気があれば君に仕事を用意している。>


sub
	% This next bit is the conversation which will happen when the
	% PC speaks to E2.
	Persona 2
	% rumor <!2 has been fighting against the !1 dead zone industrial project.>
	rumor <!2 は !1 死の大地産業進出事業に対抗して戦っている>


	%  V1 = Job offer counter, V1=1 is job offered, V1=-1 if job denied
	%  V2 = Message Randomizer
	%  V3 = Threat value of enemy mecha
	%  V4 = Reward offered to PC for the mission
	% At startup, first check to see whether the PC has already
	% completed the mission or not.
	Greeting <NewChat if= P2 3 else GoCheckLoss Say d5 CashPrize V4 AdvancePlot 0>
	GoCheckLoss <if= P2 2 else GoCheckJob V= 2 5 V+ 2 d5 Say V2 AdvancePlot 0>
	GoCheckJob <if= V1 1 else GoCheckFirst Say 101 Goto GoAddComOps>

	% The first time the PC meets the NPC, the PC will be given the
	% mission automatically if he's part of the same faction, or if
	% he is a friend of the NPC, or if he's already been sent email.
	GoCheckFirst <if= V1 0 else GoDenied V= 1 -1 V= 3 Threat PCRenown 100 V= 4 Reward V3 100 if= PCFac E1 else GoCheckEmail Goto GoDenied>
	GoCheckEmail <if= P3 1 else GoCheckFriend V= 2 10 V+ 2 d5 Say V2 Goto GoAddComOps>
	% If the reaction score is greater than 40, PC will automatically
	% be offered the job, but unlike above will not be automatically
	% expected to accept it,
	GoCheckFriend <ifG React 60 else GoNoAutomatic V= 2 15 V+ 2 d5 Say V2 V= 2 6 V+ 2 d2 AddChat V2 V= 2 8 V+ 2 d2 AddChat V2>
	% If the PC is not automatically offered the job, there's still
	% a chance to get the job... as long as the NPC doesn't hate him.
	GoNoAutomatic <ifG React d40 else GoDenied ifG PCRep 1 d25 else GoDenied V= 2 20 V+ 2 d5 Say V2 V= 2 10 V+ 2 d3 AddChat V2 V= 2 13 V+ 2 d3 AddChat V2 V= 2 16 V+ 2 d3 Say V2>
	GoDenied <V= 1 -1 SayAnything AdvancePlot 0>

	GoAddComOps <V= 1 1 AddChat d2 V= 2 2 V+ 2 d2 AddChat V2 V= 2 4 V+ 2 d2 AddChat V2 Memo 107>

	% The PC will enter combat here.
	result1 <EndChat V= 2 35 V+ 2 d5 Say V2 SavePos P= 2 1 Dynamic 2 V3 .nu1 .nu2 Encounter 1 15 .edesc SetMapType RoughMap>
	.edesc <ArchEnemy Lawful>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Salvage Return>
	result2 <Goto Result1>

	% The PC needs some time to get ready.
	result3 <NewChat Say 103>
	result4 <Goto Result3>

	% The PC will be told the enemy's point value.
	result5 <NewChat V= 2 25 V+ 2 d5 Say V2 AddChat 1 AddChat 3>
	result6 <Goto result5>

	% The PC accepts the job offer.
	result7 <NewChat V= 2 10 V+ 2 d5 Say V2 Goto GoAddComOps>
	result8 <Goto result7>

	% The PC refuses the job offer.
	result9 <NewChat Say 102 V= 1 -1  AdvancePlot 0>
	result10 <Goto result9>

	% The PC will impress the NPC with CHAOTIC reputation...
	result11 <NewChat ifG -PCRep 2 d75 else GoR11Lose V= 2 30 V+ 2 d5 Say V2 V= 2 6 V+ 2 d2 AddChat V2 V= 2 8 V+ 2 d2 AddChat V2>
	result12 <Goto result11>
	result13 <Goto result11>
	GoR11Lose <NewChat Say 104 V= 1 -1 AdvancePlot 0>

	% The PC tries to get the job via "PLAN B"- be heroic.
	result14 <NewChat ifG PCRep 1 d20 else GoR14Lose V= 2 30 V+ 2 d5 Say V2 V= 2 6 V+ 2 d2 AddChat V2 V= 2 8 V+ 2 d2 AddChat V2>
	result15 <Goto result14>
	result16 <Goto result14>
	GoR14Lose <NewChat Say 105 V= 1 -1 AdvancePlot 0>

	result17 <NewChat Say 106 V= 1 -1 AdvancePlot 0>
	result18 <Goto result17>
	result19 <Goto result17>


	% *********************
	% *** MESSAGE BLOCK ***
	% *********************

	% 01 - 05 :  Player has won the battle and is being paid.
	% Msg1 <Good job out there, but I don't think we can expect \ELEMENT 1 to give up so easily. Here's the cash I promised you.>
	Msg1 <よくやってくれた。しかし \ELEMENT 1 が簡単に諦めるとは思えない。これが約束の金だ。>
	% Msg2 <Maybe if we keep this up \ELEMENT 1 will get the message and pull out. Here's your reward; thanks for the help.>
	Msg2 <今回のような成功を続ければそのうち \ELEMENT 1 も我々の真意が分かり撤退するかもしれない。これが君の報酬だ。ご協力感謝する。>
	% Msg3 <You did it. Here's your pay.>
	Msg3 <よくやってくれた。これが君の報酬だ。>
	% Msg4 <You've driven back the forces of \ELEMENT 1 . Here's the money I promised you.>
	Msg4 <君は \ELEMENT 1 の部隊を追い払ってくれた。これが約束の金だ。>
	% Msg5 <Here's the cash I promised you for a successful mission.>
	Msg5 <これが作戦成功に対する約束の金だ。>

	% 06 - 10 :  Player has lost the battle.
	% Msg6 <Maybe \ELEMENT 1 is just too strong for us to defeat...>
	Msg6 <\ELEMENT 1 は我々が倒すにはあまりに強すぎるのかもしれない…。>
	% Msg7 <The mission was a failure.>
	Msg7 <作戦は失敗に終わった。>
	% Msg8 <We've failed... \ELEMENT 1 is one step closer to domination.>
	Msg8 <我々は失敗した…。 \ELEMENT 1 は支配に一歩近づいた。>
	% Msg9 <They won, we lost, the mission is over.>
	Msg9 <奴らが勝利し、我々は敗北した。作戦は終了した。>
	% Msg10 <You got creamed by \ELEMENT 1 . Maybe they're too strong for us to face on our own...>
	Msg10 <君は \ELEMENT 1 に敗北した。奴らは我々が孤軍奮闘するには強すぎるのかもしれない…。>

	% 11 - 15 :  Description of mission.
	%  use "$ \VAL V4 " to insert the pay for the mission,
	%  and don't forget to mention that the PC also gets salvage.
	% Msg11 <A \ELEMENT 1 security team has been intimidating the settlements around their new project, trying to force people out of the area. Disable this team and I can give you $ \VAL V4 , plus whatever salvage you can find.>
	Msg11 <\ELEMENT 1 の警備隊がその新事業の周囲に位置する村落を脅かし、開発地域から住民を追い出そうとしている。この部隊を倒してくれれば $ \VAL V4 出そう。それと、見つけた戦利品を何でもやろう。>
	% Msg12 <\ELEMENT 1 has just moved a heavy strike force into the dead zone. This type of firepower isn't just for scaring off bandits... It's worth $ \VAL V4 plus salvage if you can get rid of them.>
	Msg12 <最近 \ELEMENT 1 が死の大地へ重装備の突撃部隊を送り込んでいる。これほど大きな火力はまったく賊を撃退するためのものではない…。もしやつらを排除してくれれば $ \VAL V4 と戦利品になる。>
	% Msg13 <A shiny new mecha security force has just moved into the dead zone. It's worth $ \VAL V4 plus salvage if you can make them move out again.>
	Msg13 <ぴかぴかの新メック警備隊が最近死の大地へ進入してきた。もし奴らを追い出すことができれば $ \VAL V4 と戦利品になる。>
	% Msg14 <They've been beefing up the security around one of the big projects, probably so they can start driving out the residents and move in some company men... I can offer $ \VAL V4 plus salvage to take out their security force.>
	Msg14 <奴らはある大事業の警備を増強している。おそらく居住者を追い出し会社の人間を送り込むためだろう…。奴らの警備隊を追い出してくれれば $ \VAL V4 と戦利品を出そう。>
	% Msg15 <I can offer you $ \VAL V4 plus salvage to head in there and take out one of their security teams.>
	Msg15 <そこへ行き奴らの警備隊を追い出してくれれば $ \VAL V4 と戦利品を出そう。>

	% 16 - 20 :  Player is asked if he is looking for a job.
	% Msg16 <Hey, you wanna be an activist? \ELEMENT 1 is shaking down the communities around their dead zone project. It's time someone cut them down to size.>
	Msg16 <やあ、活動をやってみないか？ \ELEMENT 1 が奴らの死の大地進出事業の周囲にある村落を脅かしている。今こそ奴らのでしゃばりを叩いてそれ相応に戻す時だ。>
	% Msg17 <You wanna get involved in this? \ELEMENT 1 is flexing its muscles in the dead zone, and neither the Guardians or the Council are gonna do anything about it.>
	Msg17 <この問題に関わってみるか？ \ELEMENT 1 が死の大地で力を誇示している。そしてGuardiansも議会もそれについて何もしようとしない。>
	% Msg18 <You want a job? I have a mission lined up fighting \ELEMENT 1 in the dead zone.>
	Msg18 <仕事がほしいか？死の大地で \ELEMENT 1 と戦う仕事を用意している。>
	% Msg19 <The company bastards at \ELEMENT 1 have been stomping down the nomads in the dead zone. I'm planning a mission to give them some what-for, if you'd like to join in.>
	Msg19 <\ELEMENT 1 の社員どもが死の大地の遊動民を蹂躙している。もし君が参加したいなら、奴らに我々の意図を伝える作戦を計画している。>
	% Msg20 <I have a job available if you don't mind taking on \ELEMENT 1 . This is one of those missions of conscience, you know?>
	Msg20 <もし君が \ELEMENT 1 を相手にするのを気にしないなら求人中の仕事がある。これは道義にかなった仕事だ。>

	% 21 - 25 :  NPC implies job, PC might have chance to get it.
	% Msg21 <\NARRATIVE 1 calls all the people who live in the dead zone "ravagers". That's just not true... they're saying it to justify their attacks against the people there.>
	Msg21 <\NARRATIVE 1 は死の大地に住む者を皆「略奪者」と呼んでいる。それはまったくの間違いだ…奴らがそう言うのはそこに住む者に対し攻撃を加えるのを正当化するためなのだ。>
	% Msg22 <\NARRATIVE 1 has moved into the dead zone, and started claiming resources from the people who live there. Man I hate those corps...>
	Msg22 <\NARRATIVE 1 は死の大地へ進入し、そこに住む者から資源を要求し始めている。まったくもって企業というやつは気に入らない…。>
	% Msg23 <I grew up in the dead zone. It's a tough place, that's for sure. Now \NARRATIVE 1 is in there stealing what little the people have out from under them.>
	Msg23 <私は死の大地で育った。死の大地は厳しい場所だ。それは確かなことだ。今そこで \NARRATIVE 1 が住民の持つわずかな地下資源を奪っている。>
	% Msg24 <Life has always been rough in the dead zone. We don't need corporations in there forcibly moving settlements just so they can get the best parts for themselves.>
	Msg24 <死の大地では常に生活は険しい。企業が自分自身のために最高の地域を手に入れるためだけに、我々が住居をむりやり移動させられる必要はない。>
	% Msg25 <\NARRATIVE 1 says it's "civilizing" the dead zone, says that the people they've been killing there are "ravagers" and "bandits". It's all bull.>
	Msg25 <\NARRATIVE 1 はその事業を死の大地の「文明化」と言っており、奴らがそこで殺している人々は「略奪者」や「賊」であると言っている。すべてたわごとだ。>

	% 26 - 30 :  PC will be told exact enemy point value.
	%  use "\VAL V3 " to insert the value.
	% Msg26 <Our reports indicate that you'll be up against \VAL V3 threat points.>
	Msg26 <報告によると君は \VAL V3 ポイントの戦力を相手にすることになるようだ。>
	% Msg27 <I've heard from some friends in Last Hope that \ELEMENT 1 has around \VAL V3 threat points worth of mecha in the area.>
	Msg27 <Last Hope の友人から聞いたところによると \ELEMENT 1 は当該地域におよそ \VAL V3 ポイントの戦力を持つメック部隊を有しているらしい。>
	% Msg28 <They've got \VAL V3 points worth of death in there, give or take a few hundred.>
	Msg28 <奴らはそこに数百ポイントの誤差はあるとして \VAL V3 ポイントの戦力を持っている。>
	% Msg29 <You'll be fighting \VAL V3 tac-points of company mecha. Should be no problem for a badass like you, right?>
	Msg29 <君は \VAL V3 ポイントの戦力を持つ企業メックと戦うことになる。君のような凄腕のパイロットなら何の問題もないだろう？>
	% Msg30 <They've got around \VAL V3 worth in their strike team.>
	Msg30 <奴らの突撃部隊はおよそ \VAL V3 ポイントの戦力を有している。>

	% 31 - 35 :  "PLAN A" or "PLAN B" worked... the PC is offered
	%  a job and may choose either prompt7/8 to accept or prompt9/10
	%  to reject it.
	% Msg31 <Maybe you'd like to help. The corp security force has been raiding villages around their development site. I could use another pilot to cut them down a notch.>
	Msg31 <君なら役に立つかもしれない。 \NARRATIVE 1 の警備隊が奴らの開発地域の周辺にある村落を襲っている。奴らのでしゃばりを叩きそれ相応に戻してくれるパイロットを雇いたい。>
	% Msg32 <How'd you like to join the cause? I could use a mecha pilot to run some interference. The corp security force has been beating down the settlements... I think they could use a beating down themselves.>
	Msg32 <運動に加わらないか？妨害作戦を実行してくれるメックパイロットを雇いたい。 \NARRATIVE 1 の警備隊が村落を破壊している…。奴らは破壊した地域を自分自身で使うつもりだろう。>
	% Msg33 <It's time the corporations got what was coming to them. I have a mission planned, if you'd like to run with it.>
	Msg33 <今こそ \NARRATIVE 1 が受けるべき裁きを受ける時だ。もし君が実行する気があるなら、私は作戦を計画している。>
	% Msg34 <I've got a job lined up against \NARRATIVE 1 , if you'd like to help out.>
	Msg34 <もし手を貸す気があるなら、 \NARRATIVE 1 と戦う仕事を用意している。>
	% Msg35 <The Guardians can't touch them because it's outside the FedTer, the Council won't do anything because of the money involved, so it's up to petty thugs like us to stand up against \ELEMENT 1 . Do you want in or not?>
	Msg35 <襲撃は連邦外で行われているためGuardiansは \NARRATIVE 1 に何もできないし、金が絡んでいるため議会は何もしないだろう。そういうわけで我々のような小悪党が \ELEMENT 1 に対して立ち上がることになったのだ。君もやってみるか？>

	% 36 - 40 :  Combat is starting.
	% Msg36 <Good luck out there. Don't get your ass kicked by a bunch of fatass wage-slaves.>
	Msg36 <幸運を祈る。賃金奴隷のブタどもにやられるなよ。>
	% Msg37 <Here are the coordinates. Fight the power!>
	Msg37 <これが正確な位置だ。権力と戦え！>
	% Msg38 <Get out there and kick some corporate ass.>
	Msg38 <そこへ行って会社に一泡吹かせて来い。>
	% Msg39 <They thought taking on the dead zone would be a walk in the park... let's prove that it won't be.>
	Msg39 <奴らは死の大地を相手にするのを町を歩くのと同じように考えたようだ…それは全く違うことだということを証明してやろう。>
	% Msg40 <Here's the navigation info that you're going to need. Good luck out there.>
	Msg40 <これが必要な位置情報だ。幸運を祈る。>


	% 101 :  Player accepted job, then left to get ready.
	% Msg101 <Are you ready to start the mission?>
	Msg101 <作戦開始できるか？>
	% 102 :  Player has refused to take job; answer to prompts 9-10.
	% Msg102 <If you're not in it, you're out of it.>
	Msg102 <手を貸してくれないなら、用はない。>
	% 103 :  Player has asked for some time to get ready.
	% Msg103 <Sure. Better make sure your gear is ready, because corp security doesn't take any prisoners...>
	Msg103 <もちろん。装備を整えたほうがいい。なぜなら会社の警備隊は敵を刑務所に入れないからな…。>
	% 104 :  "PLAN A" has failed, and the PC is not offered a job.
	% Msg104 <Maybe not enough, though.>
	Msg104 <しかし、君では無理だ。>
	% 105 :  "PLAN B" has failed, and the PC is not offered a job.
	% Msg105 <Yeah, but you should do something to change it, not just talk about it.>
	Msg105 <そうだな。でも議論するだけでなく、変える努力をしなければならない。>
	% 106 :  Player doesn't want job; answer to prompts 17-19.
	% msg106 <Yeah, right. If the corps aren't opposed then they'll just continue doing whatever they like.>
	msg106 <そうか。抵抗されなければ \NARRATIVE 1 はやりたい放題を続けるだろうな。>
	% 107 :  Memo
	% msg107 <\ELEMENT 2 in \SCENE EScene 2 offered you a combat mission.>
	msg107 <\SCENE EScene 2 の \ELEMENT 2 に戦闘任務を依頼された。>

	% 01 - 02 :  Ready to start the mission
	% Prompt1 <I'm ready to start the mission.>
	Prompt1 <作戦開始できる%JG。>
	% Prompt2 <All ready to move out.>
	Prompt2 <作戦開始の準備は万端だ。>

	% 03 - 04 :  Need time to get ready first.
	% Prompt3 <Give me some time to get ready.>
	Prompt3 <準備する時間をくれ。>
	% Prompt4 <I need some time to prepare.>
	Prompt4 <準備する時間が要る%JG。>

	% 05 - 06 :  What is the enemy point value?
	% Prompt5 <What am I up against out there?>
	Prompt5 <どんな敵が相手になる？>
	% Prompt6 <What kind of stuff do they have?>
	Prompt6 <奴らはどんな武装を持っている？>

	% 07 - 08 :  After being asked if he wants a job, PC says yes.
	% Prompt7 <Give me the plan.>
	Prompt7 <計画を聞こう。>
	% Prompt8 <I'm in. Tell me the plan.>
	Prompt8 <やってみよう。計画を聞かせてくれ。>

	% 09 - 10 :  After being asked if he wants a job, PC says no.
	% Prompt9 <I'm afraid I can't help.>
	Prompt9 <残念だが手伝えない%JG。>
	% Prompt10 <I don't want to get involved in this.>
	Prompt10 <この件には関わりたくない%JG。>

	% 11 - 13 : Player tries to get job using PLAN "A".
	% Prompt11 <I hate the corps!>
	Prompt11 <企業は気に喰わない%JG！>
	% Prompt12 <I have no love of the corporations.>
	Prompt12 <%JFは企業を好まない%JG。>
	% Prompt13 <Those corps get away with murder...>
	Prompt13 <企業が殺人をやりおおせているというわけか…。>

	% 14 - 16 : Player tries to get job using PLAN "B".
	% Prompt14 <Something ought to be done about it.>
	Prompt14 <何か対策を講じるべきだ。>
	% Prompt15 <I wish there was some way I could help.>
	Prompt15 <%JFに手伝えることがあればいいのだけど。>
	% Prompt16 <That just isn't right.>
	Prompt16 <まったく不正なことだ。>

	% 17 - 19 : Player doesn't much care for the job.
	% Prompt17 <That's not my problem.>
	Prompt17 <%JFの問題ではない%JG。>
	% Prompt18 <I can't get involved in this matter.>
	Prompt18 <この問題には関わりたくない%JG。>
	% Prompt19 <Big deal. It doesn't affect me.>
	Prompt19 <大ごとだな。%JFには関係ない%JG。>


end

