Plot 0
	name <PLOT: New Guard Mission 1>
	% [[Ver1.4]]


	% **********************
	% *** ELEMENTS BLOCK ***
	% **********************
	% E1 is the faction behind the story
	Element1 <Faction Police>
	Element2 <Character Guardian>

	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	%  V1 = Time Limit
	%  V2 = Combat Indicator, if V2=1 combat has been entered
	%  V3 = Email sent indicator.

	% Time limit. This plot will conclude in one day, or immediately
	% if NPC E2 is killed.
	Init_Start <ifNPCOK E2 else GoDelete if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	start <ifNPCOK E2 else GoDelete if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	GoCheckTime <if= V2 0 ifG ComTime V1 AdvancePlot 0>
	GoDelete <AdvancePlot 0>

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	% Finally, if the player won, the calling story's faction victory
	% count (by default now story variable 101) will be increased.
	nu1 <if= T1 0 if= V2 1  V= 2 2  LoseRenown>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 50  FacXP+ E1 1>

	% Email check. If the PC belongs to the same faction as the NPC,
	% he may receive an email about the mission. Make a check every
	% 5 minutes.
	% 5Min <if= d50 23 if= V3 0 if= PCFac E1 V= 3 1 Email d5>
	5Min <if= d50 23 if= V3 0 if= PCFac E1 V= 3 1 SetNPC E2 Email d5>

	% *********************
	% *** MESSAGE BLOCK ***
	% *********************

	% 01 - 05 :  Email Messages.
	%  The NPC is offering the PC a mission via email.
	% Msg1 <\PERSONA E2 @ \SCENE EScene 2 :// Got a mission for you here in \SCENE ESCENE 2 if you're in the area.>
	Msg1 <\PERSONA E2 @ \SCENE EScene 2 :// もしここ \SCENE ESCENE 2 へ来ることがあれば、あなたに仕事があります。>
	% Msg2 <\PERSONA E2 @ \SCENE EScene 2 :// Guardian business in \SCENE EScene 2 ; report here for mission against bandits.>
	Msg2 <\PERSONA E2 @ \SCENE EScene 2 :// \SCENE EScene 2 でGuardianの仕事があります。賊を掃討する仕事がありますのでお越しください。>
	% Msg3 <\PERSONA E2 @ \SCENE EScene 2 :// If you're in the area I could use your assistance on a case.>
	Msg3 <\PERSONA E2 @ \SCENE EScene 2 :// もしここへ来ることがあればある事件についてあなたの力をお借りしたい。>
	% Msg4 <\PERSONA E2 @ \SCENE EScene 2 :// Got a bandit problem in \SCENE EScene 2 ; if you're in the area stop by for mission.>
	Msg4 <\PERSONA E2 @ \SCENE EScene 2 :// \SCENE EScene 2 は賊に悩まされています。もしここへ来ることがあれば仕事がありますので立ち寄ってください。>
	% Msg5 <\PERSONA E2 @ \SCENE EScene 2 :// Your assistance is required on an important case.>
	Msg5 <\PERSONA E2 @ \SCENE EScene 2 :// ある重要な事件についてあなたの力が必要です。>


sub
	% This next bit is the conversation which will happen when the
	% PC speaks to E2.
	Persona 2

	% rumor <!2 the guardian needs a mecha pilot for a combat mission against bandits.>
	rumor <!2 Guardianは賊を掃討する戦闘任務を実行してくれるメックパイロットを必要としている>

	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	% If you're feeling faint of heart, just skip this
	% and jump straight to the messages block below.
	% Here are the variables used in this conversation:
	%  V1 = Job offer counter, V1=1 is job offered, V1=-1 if job denied
	%  V2 = Message Randomizer
	%  V3 = Threat value of enemy mecha
	%  V4 = Reward offered to PC for the mission
	% At startup, first check to see whether the PC has already
	% completed the mission or not.
	Greeting <NewChat if= P2 3 else GoCheckLoss Say d5 CashPrize V4 AdvancePlot 0>
	GoCheckLoss <if= P2 2 else GoCheckJob V= 2 5 V+ 2 d5 Say V2 AdvancePlot 0>
	GoCheckJob <if= V1 1 else GoCheckFirst Say 101 Goto GoAddComOps>

	% The first time the PC meets the NPC, the PC will be given the
	% mission automatically if he's part of the same faction, or if
	% he is a friend of the NPC, or if he's already been sent email.

	% The PC will be denied the mission if he's helped the enemy.
	GoCheckFirst <if= V1 0 else GoDenied V= 1 -1 V= 3 Threat PCRep 6 90 V= 4 Reward V3 90 Goto GoCheckFaction>

	GoCheckFaction <if= PCFac E1 else GoCheckEmail V= 2 10 V+ 2 d5 Say V2 Goto GoAddComOps>
	GoCheckEmail <if= P3 1 else GoCheckFriend V= 2 10 V+ 2 d5 Say V2 Goto GoAddComOps>
	GoCheckFriend <ifG PCRep 2 d40 else GoNoAutomatic V= 2 15 V+ 2 d5 Say V2 V= 2 6 V+ 2 d2 AddChat V2 V= 2 8 V+ 2 d2 AddChat V2>
	% If the PC is not automatically offered the job, there's still
	% a chance to get the job... as long as the NPC doesn't hate him.
	GoNoAutomatic <ifG PCRep 1 -d10 else GoDenied V= 2 20 V+ 2 d5 Say V2 V= 2 10 V+ 2 d3 AddChat V2 V= 2 13 V+ 2 d3 AddChat V2 V= 2 16 V+ 2 d3 AddChat V2>
	GoDenied <V= 1 -1 SayAnything AdvancePlot 0>

	GoAddComOps <V= 1 1 AddChat d2 V= 2 2 V+ 2 d2 AddChat V2 V= 2 4 V+ 2 d2 AddChat V2 Memo 107>

	result1 <EndChat V= 2 35 V+ 2 d5 Say V2 Goto GoStartCombat>
	GoStartCombat <SavePos S+ 103 1 P= 2 1 Dynamic 2 V3 .nu1 .nu2 Encounter 10 15 .edesc Reputation 2 1>
	.edesc <Bandit Chaotic +PCRA +ECRA>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Salvage Return>
	result2 <Goto Result1>

	% The PC needs some time to get ready.
	result3 <NewChat Say 103>
	result4 <Goto Result3>

	% The PC will be told the enemy's point value.
	result5 <NewChat V= 2 25 V+ 2 d5 Say V2 AddChat 1 AddChat 3>
	result6 <Goto result5>

	% The PC accepts the job offer.
	result7 <NewChat V= 2 10 V+ 2 d5 Say V2 Goto GoAddComOps>
	result8 <Goto result7>

	% The PC refuses the job offer.
	result9 <NewChat Say 102 Reputation 2 -1 V= 1 -1 AdvancePlot 0>
	result10 <Goto result9>

	% The PC tries to get the job via "PLAN A"- Lawful reputation.
	result11 <NewChat ifG PCRep 2 0 else GoR11Lose V= 2 30 V+ 2 d5 Say V2 V= 2 6 V+ 2 d2 AddChat V2 V= 2 8 V+ 2 d2 AddChat V2>
	result12 <Goto result11>
	result13 <Goto result11>
	GoR11Lose <NewChat Say 104 V= 1 -1 AdvancePlot 0>


	% The PC tries to get the job via "PLAN B"- be friendly.
	% This is done with the Conversation skill.
	result14 <NewChat ifG Conversation 15 else GoR14Lose V= 2 30 V+ 2 d5 Say V2 V= 2 6 V+ 2 d2 AddChat V2 V= 2 8 V+ 2 d2 AddChat V2>
	result15 <Goto result14>
	result16 <Goto result14>

	% PLAN "B", whatever it was, has failed...
	GoR14Lose <NewChat Say 105 V= 1 -1 AdvancePlot 0>

	% The player doesn't want this stinkin' job.
	result17 <NewChat Say 106 Reputation 4 d10 V= 1 -1 AdvancePlot 0>
	result18 <Goto result17>
	result19 <Goto result17>


	% *********************
	% *** MESSAGE BLOCK ***
	% *********************

	% 01 - 05 :  Player has won the battle and is being paid.
	% Msg1 <You did well. Here's the money you earned.>
	Msg1 <よくやってくれました。こちらがあなたへの報酬です。>
	% Msg2 <Here's your reward for a job well done.>
	Msg2 <こちらが仕事を成功させてくれたことへの報酬です。>
	% Msg3 <You did it! Here's your pay.>
	Msg3 <よくやってくれました！こちらが報酬です。>
	% Msg4 <The bandit gang has been destroyed. Good job.>
	Msg4 <賊の一味は倒されました。よくやってくれました。>
	% Msg5 <Brilliant show of piloting out there. Let's work together again some time.>
	Msg5 <あなたのメック操縦はすばらしい腕前でした。いつかまた一緒に働きましょう。>

	% 06 - 10 :  Player has lost the battle.
	% Msg6 <You failed.>
	Msg6 <あなたは失敗しました。>
	% Msg7 <The mission was a failure.>
	Msg7 <作戦は失敗しました。>
	% Msg8 <You blew it.>
	Msg8 <あなたは失敗しました。>
	% Msg9 <That didn't go so well...>
	Msg9 <うまくいきませんでしたね…。>
	% Msg10 <Let's not speak of this mission ever again.>
	Msg10 <この仕事の話はもうやめにしましょう。>

	% 11 - 15 :  Description of mission.
	%  use "$ \VAL V4 " to insert the pay for the mission,
	%  and don't forget to mention that the PC also gets salvage.
	% Msg11 <We've tracked a group of bandits to a camp outside of town. It's worth $ \VAL V4 plus salvage if you can defeat them.>
	Msg11 <賊の一味の居場所を町の外の野営地に突き止めました。彼らを倒してくれれば $ \VAL V4 と戦利品を出します。>
	% Msg12 <A gang of highway bandits has set up base outside of town. They need to be removed. The job pays $ \VAL V4 plus salvage.>
	Msg12 <幹線道路に出没する賊の一味が町の外に基地を設けました。彼らを排除しなければなりません。この仕事の報酬は $ \VAL V4 と戦利品になります。>
	% Msg13 <We've got bandit troubles. I need you to eliminate a gang that's recently moved into the area. You'll get $ \VAL V4 and salvage if you succeed.>
	Msg13 <この町は賊に悩まされています。最近この地域に入り込んだ一味を抹殺してください。もし成功すればあなたは $ \VAL V4 と戦利品を得られます。>
	% Msg14 <There's been a group of bandits terrorizing the highway leading into town. If you can defeat them, you'll earn $ \VAL V4 and the salvage rights to their mecha.>
	Msg14 <この町に続く幹線道路を脅かしている賊の一味がいます。彼らを倒すことができれば、あなたは $ \VAL V4 と敵メックのサルベージ権を得られます。>
	% Msg15 <Just outside of town is a den of highway robbers. I want them removed immediately. I can offer you $ \VAL V4 and salvage to take them out.>
	Msg15 <町のすぐ外に幹線道路を襲撃している強盗団のアジトがあります。彼らを即刻排除しなければなりません。彼らを追い出してくれれば $ \VAL V4 と戦利品を出しましょう。>

	% 16 - 20 :  Player is asked if he is looking for a job.
	% Msg16 <Hey, are you looking for work? I've got a mecha contract against some bandits if you're interested.>
	Msg16 <こんにちは、仕事をお探しですか？もしよければ、賊を掃討するメック用の仕事があります。>
	% Msg17 <I've got a mission contract available if you're interested in working with the guardians.>
	Msg17 <もしGuardiansと共に働きたいなら空いている仕事があります。>
	% Msg18 <I need a mecha pilot to run a combat mission. How'd you like to do that?>
	Msg18 <ある戦闘任務を実行してくれるメックパイロットが必要です。やってみませんか？>
	% Msg19 <I have a mission that I think might appeal to you. How'd you like to help me fight a gang of bandits?>
	Msg19 <あなたの気に入りそうな仕事があります。賊の一味と戦うのに手を貸してくれませんか？>
	% Msg20 <If you're looking for work, the guardians need a cavalier to fly a combat mission.>
	Msg20 <もし仕事をお探しなら、Guardiansはある戦闘任務を実行してくれる騎士を必要としています。>

	% 21 - 25 :  NPC implies job, PC might have chance to get it.
	% Msg21 <Lately there have been too many bandits on the highway.>
	Msg21 <最近幹線道路に多くの賊が出没しています。>
	% Msg22 <There have been too many raids against convoys coming into town.>
	Msg22 <この町へ向かう輸送隊が襲撃される事件が多発しています。>
	% Msg23 <The highways outside of town aren't safe. There are too many bandits operating in the area.>
	Msg23 <町の外の幹線道路の安全が損なわれています。この地域ではあまりに多くの賊が活動しています。>
	% Msg24 <Bandits attacked a convoy last week... One attack is one attack too many. They have to be stopped.>
	Msg24 <先週、賊がある輸送隊を襲いました…。こうした襲撃は一件たりともあってはなりません。彼らを止めなければなりません。>
	% Msg25 <It's been a real headache. We have bandits operating near town. They've got to go...>
	Msg25 <この事件のことを考えると本当に頭が痛い。町の近くで賊が活動していて、行き過ぎた行いをしています…。>

	% 26 - 30 :  PC will be told exact enemy point value.
	%  use "\VAL V3 " to insert the value.
	% Msg26 <Our reports indicate that you'll be up against \VAL V3 threat points worth of enemy hardware. Do you feel up to the challenge?>
	Msg26 <報告によると、あなたは \VAL V3 ポイントの戦力を持つ敵軍備と対峙することになります。やれそうですか？>
	% Msg27 <They've got around \VAL V3 points worth of mecha.>
	Msg27 <敵はおよそ \VAL V3 ポイントの戦力を持つメックを有しています。>
	% Msg28 <In order to qualify for the reward, you'll have to disable all \VAL V3 threat points of their mecha.>
	Msg28 <報酬をもらう資格を得るためには、あなたは \VAL V3 ポイントの戦力を持つ敵メックをすべて倒さなければなりません。>
	% Msg29 <The bandits have \VAL V3 tac points worth of hardware.>
	Msg29 <賊は \VAL V3 ポイントの戦力を持つ軍備を有しています。>
	% Msg30 <In the past they've been able to field around \VAL V3 points worth of mecha. There's no reason to believe they've upgraded significantly since then.>
	Msg30 <彼らは過去におよそ \VAL V3 ポイントの戦力を持つメックを展開していました。彼らの戦力は今もその当時からあまり変わっていないと思われます。>

	% 31 - 35 :  "PLAN A" or "PLAN B" worked... the PC is offered
	%  a job and may choose either prompt7/8 to accept or prompt9/10
	%  to reject it.
	% Msg31 <I've got a combat mission available for a mecha pilot. How'd you like the job?>
	Msg31 <メックパイロット向けの戦闘任務があります。やってみませんか？>
	% Msg32 <If you're looking for work, I might just have something to interest you...>
	Msg32 <もし仕事をお探しなら、あなたの気に入る仕事がちょうどあるかもしれません…。>
	% Msg33 <Are you looking for a job or something? I have one available if you are.>
	Msg33 <仕事か何かをお探しですか？もしそうなら空いている仕事があります。>
	% Msg34 <If you'd like to work with us on the bandit case, I have a mission available.>
	Msg34 <我々と賊がらみの事件に取りかかる気があるのなら、空いている仕事があります。>
	% Msg35 <You want to work with me? I've got a guardian mission available for a mecha pilot.>
	Msg35 <私と働く気はありますか？メックパイロット向けのGuardianの仕事があります。>

	% 36 - 40 :  Combat is starting.
	% Msg36 <Good luck out there.>
	Msg36 <幸運を祈ります。>
	% Msg37 <Come back when you're finished and I'll give you your pay.>
	Msg37 <仕事が終わったら戻ってきてください。そうすればあなたに報酬を渡しましょう。>
	% Msg38 <Take the fight to them!>
	Msg38 <存分に戦ってください！>
	% Msg39 <I'll send the navigation data to your onboard computer. Proceed to the destination and engage the bandits. Return when you've disabled them and I'll give you your pay.>
	Msg39 <あなたのメックに搭載されたコンピュータに位置情報を送りましょう。目的地に向かい賊と交戦してください。敵を倒したら戻ってきてください。そうすれば報酬を支払います。>
	% Msg40 <Here's the navpoint where you can find the bandits. Disable their mecha, then return to town.>
	Msg40 <賊のいる位置はこちらです。敵メックを倒したら、町へ戻ってきてください。>


	% 101 :  Player accepted job, then left to get ready.
	% Msg101 <Are you ready to start the mission?>
	Msg101 <作戦開始の準備はできましたか？>
	% 102 :  Player has refused to take job; answer to prompts 9-10.
	% Msg102 <That's too bad.>
	Msg102 <それは残念です。>
	% 103 :  Player has asked for some time to get ready.
	% Msg103 <Okay. Hurry back once your equipment is in shape and we can start the mission then.>
	Msg103 <いいでしょう。装備を万全にしたら急いで戻りなさい。作戦開始はそれからです。>
	% 104 :  "PLAN A" has failed, and the PC is not offered a job.
	% Msg104 <No, I don't think we need your help. The guardians have plenty of loyal pilots who are far better suited to this job.>
	Msg104 <いや、あなたの力が要るとは思えません。Guardiansにはあなたよりもはるかに適任の忠実なパイロットがたくさんいますから。>
	% 105 :  "PLAN B" has failed, and the PC is not offered a job.
	% Msg105 <Rest assured that the guardians have this matter well under control.>
	Msg105 <この事件の捜査は思い通りに進んでいますから安心してください。>
	% 106 :  Player doesn't want job; answer to prompts 17-19.
	% msg106 <If we don't put a stop to this now, it will be the start of a descent into anarchy!>
	Msg106 <今この事態に終止符を打たなければ、この町は混沌へと堕落し始めてしまうでしょう！>
	% 107 :  Memo
	% msg107 <\ELEMENT 2 in \SCENE EScene 2 offered you a combat mission against bandits.>
	msg107 <\SCENE EScene 2 の \ELEMENT 2 に賊の掃討任務を依頼された。>

	% 01 - 02 :  Ready to start the mission
	% Prompt1 <All ready to go.>
	Prompt1 <準備万端だ。>
	% Prompt2 <Let's start this mission.>
	Prompt2 <仕事を始めよう。>

	% 03 - 04 :  Need time to get ready first.
	% Prompt3 <I need some time to get ready.>
	Prompt3 <準備する時間が要る%JG。>
	% Prompt4 <Maybe I should gas up first.>
	Prompt4 <まずは燃料補給しないと。>

	% 05 - 06 :  What is the enemy point value?
	% Prompt5 <What am I up against?>
	Prompt5 <%JFはどれだけの敵と戦うことになる？>
	% Prompt6 <What kind of mecha do they have?>
	Prompt6 <敵はどれだけのメックを持っている？>

	% 07 - 08 :  After being asked if he wants a job, PC says yes.
	% Prompt7 <I'd love to do that.>
	Prompt7 <是非やってみよう。>
	% Prompt8 <Sounds good to me.>
	Prompt8 <よさそうだな。>

	% 09 - 10 :  After being asked if he wants a job, PC says no.
	% Prompt9 <I don't work with the guardians.>
	Prompt9 <Guardiansとは働きたくない%JG。>
	% Prompt10 <This isn't my kind of work.>
	Prompt10 <%JFのやるような仕事じゃないな。>

	% 11 - 13 : Player tries to get job using PLAN "A".
	% Prompt11 <What can I do to help?>
	Prompt11 <%JFに手伝えることは？>
	% Prompt12 <I'd like to volunteer to help.>
	Prompt12 <協力したい%JG。>
	% Prompt13 <Maybe I could help you.>
	Prompt13 <%JFなら役に立てるかもしれない%JG。>

	% 14 - 16 : Player tries to get job using PLAN "B".
	%   By default, PLAN "B" is to be friendly and personable.
	% Prompt14 <Are you planning to do something about it?>
	Prompt14 <何か対策を練っているのか？>
	% Prompt15 <You should maybe hire a mecha pilot.>
	Prompt15 <%JSはメックパイロットを雇ったほうがいい。>
	% Prompt16 <What are the guardians going to do?>
	Prompt16 <Guardiansは何をしようとしている？>

	% 17 - 19 : Player doesn't much care for the job.
	% Prompt17 <Eh, there's always been too many bandits.>
	Prompt17 <まあ、賊はいつでも多いものだよ。>
	% Prompt18 <I'm not going to worry about it.>
	Prompt18 <そんなことは気にならないね。>
	% Prompt19 <That's not a big problem.>
	Prompt19 <大したことじゃないさ。>


end

