Plot 0
	name <Promotion Reward>
	% The PC has gone up a rank in the military, and will
	% now get a reward for it.

	% Element 1 is the calling faction
	% Element 2 is the character who'll give the PC the reward
	Element2 <Character Guardian>

	% These are faction rewards...
	Element3 <Prefab>
	Element4 <Prefab>
	Element5 <Prefab>
	Element6 <Prefab>

	% V1 = Email Indicator

	% This plot will remain active until the PC collects his
	% reward, until the NPC dies, or until the PC is no longer
	% a member of the calling faction.
	% start <ifNPCOK E2 else GoReschedule if= PCFac E1 else GoDelete if= V1 0 Email d5 V= 1 1>
	Init_Start <ifNPCOK E2 else GoReschedule if= PCFac E1 else GoDelete if= V1 0 SetNPC E2 Email d5 V= 1 1>
	start <ifNPCOK E2 else GoReschedule if= PCFac E1 else GoDelete if= V1 0 SetNPC E2 Email d5 V= 1 1>
	GoReschedule <FacVar+ E1 1 1 AdvancePlot 0>
	GoDelete <AdvancePlot 0>

	% Msg1 <\ELEMENT 2 @ \SCENE EScene 2 :// You've earned a promotion. Come see me to accept your reward.>
	Msg1 <\ELEMENT 2 @ \SCENE EScene 2 :// 貴官は昇進した。報酬を受け取りに来たまえ。>
	% Msg2 <\ELEMENT 2 @ \SCENE EScene 2 :// I have urgent business which requires your attention at once.>
	Msg2 <\ELEMENT 2 @ \SCENE EScene 2 :// 貴官の手が直ちに必要な急を要する任務がある。>
	% Msg3 <\ELEMENT 2 @ \SCENE EScene 2 :// Report here for debriefing at once, \RANK .>
	Msg3 <\ELEMENT 2 @ \SCENE EScene 2 :// 直ちに報告に来たまえ、 \RANK 。>
	% Msg4 <\ELEMENT 2 @ \SCENE EScene 2 :// You have been promoted. Report here to receive your commission.>
	Msg4 <\ELEMENT 2 @ \SCENE EScene 2 :// 貴官は昇進した。任務を受けに来たまえ。>
	% Msg5 <\ELEMENT 2 @ \SCENE EScene 2 :// Your presence is required at headquarters immediately.>
	Msg5 <\ELEMENT 2 @ \SCENE EScene 2 :// 速やかに本部へ来たまえ。>

sub
	Persona 2
	% V1 = Faction level the PC is being rewarded for.
	greeting <NewChat XPV 100 V= 1 FacVar E1 2 V+ 1 1 FacVar= E1 2 V1 AdvancePlot 0 Goto GoL0>
	GoL0 <ifG 9 V1 else GoBigLevel ifG FXPNeeded V1 PCRep 6 else GoL1 CashPrize Reward Threat FXPNeeded V1 100 250 Say 10>
	GoL1 <if= V1 1 else GoL2 Say 1 MechaPrize .mek1>
	.mek1 <Corsair.txt>
	GoL2 <if= V1 2 else GoL3 Say 2 CashPrize 250000>
	GoL3 <if= V1 3 else GoL4 Say 3 GiveKeyItem E3>
	GoL4 <if= V1 4 else GoL5 Say 4 MechaPrize .mek2>
	.mek2 <Vadel.txt>
	GoL5 <if= V1 5 else GoL6 Say 5 GiveKeyItem E4 GiveKeyItem E6>
	GoL6 <if= V1 7 else GoL7 Say 6 PCSkill+ 5 2 PCSkill+ 10 2>
	GoL7 <if= V1 6 else GoL8 Say 7 GiveKeyItem E5>
	GoL8 <if= V1 8 else GoBigLevel Say 8 MechaPrize .mek3>
	.mek3 <Monstrous.txt>
	GoBigLevel <Say 9 CashPrize 500000>

	% Msg1 <As you have been promoted to the rank of \FacRank E1 V1 , you will need a spare mecha. This battroid will be more versatile than the patrol car you were originally given. In any case, it's always good to have a spare vehicle.>
	Msg1 <貴官は \FacRank E1 V1 に昇進した。そこで貴官には予備のメックが必要になるだろう。このバトロイドは最初に授けた警備用車両よりも多目的に使用できる。いずれにせよ、予備の乗り物は持って損はない。>
	% Msg2 <You have been promoted to the rank of \FacRank E1 V1 . You could probably use some new equipment. Here's a cash bonus.>
	Msg2 <貴官は \FacRank E1 V1 に昇進した。恐らく新しい装備を使用することもあるだろう。ボーナスを用意した。>
	% Msg3 <You have been promoted to the rank of \FacRank E1 V1 . You've earned the right to carry this officer's sidearm, which should keep the bad guys at bay.>
	Msg3 <貴官は \FacRank E1 V1 に昇進した。この武器の携帯を許可する。そうすれば悪漢どもはうかつに手を出せないはずだ。>
	% Msg4 <You have been promoted to the rank of \FacRank E1 V1 . From here on in you'll be tackling our most dangerous missions, and you'll need to stay one step ahead of your foes. Here's a new mecha that should serve the purpose.>
	Msg4 <貴官は \FacRank E1 V1 に昇進した。これより貴官は最も危険な任務に臨むことになる。そこで貴官は敵に対し一歩距離を取っておかねばならない。その目的に適うはずのメックを用意した。>
	% Msg5 <You have been promoted to the rank of \FacRank E1 V1 . You may be called upon to engage criminals face to face, and for that you're going to need some protection. This S.W.A.T armor is the most advanced in our arsenal.>
	Msg5 <貴官は \FacRank E1 V1 に昇進した。貴官は犯罪者と相対して戦うことを求められるかもしれない。そのような場合貴官には身を守る物が必要になる。この S.W.A.T 防具は我々の最新装備だ。>
	% Msg6 <You have been promoted to the rank of \FacRank E1 V1 . In order to help you perform your job well, you've been enrolled in a special defensive strategy training course.>
	Msg6 <貴官は \FacRank E1 V1 に昇進した。貴官が任務をスムーズに遂行するのに役立つよう、貴官を特別防御方法訓練コースに登録した。>
	% Msg7 <You have been promoted to the rank of \FacRank E1 V1 . As a symbol of your new rank, take this weapon. Only the most decorated of guardians are entitled to use it.>
	Msg7 <貴官は \FacRank E1 V1 に昇進した。新しい地位の象徴として、この武器を受け取りたまえ。最高の勲章を授けられたGuardian隊員達にしか使用を許可されていないものだ。>
	% Msg8 <You have been promoted to the rank of \FacRank E1 V1 . Here's a heavy patrol car for your use. Really heavy. Actually, it's not so much a car as it is a tank... Try not to damage the city streets when you park it.>
	Msg8 <貴官は \FacRank E1 V1 に昇進した。貴官に使用してもらうために大型の警備用車両を用意した。かなり大型だ。実際のところ、それは車両というより戦車だ…。駐車するときは市街地を損壊しないように努めてくれ。>
	% Msg9 <Here is a cash reward in recognition of your dedicated service to \ELEMENT 1 .>
	Msg9 <貴官の \ELEMENT 1 に対する献身的な奉仕を認め報酬を用意した。>
	% Msg10 <You have been promoted to the rank of \FacRank E1 V1 . Here is a small cash reward in recognition of your service.>
	Msg10 <貴官は \FacRank E1 V1 に昇進した。貴官の奉仕を認め小額の報酬を用意した。>

end
inv
	Gun 6
	name <Peacemaker>
	name_I18N <ピースメーカー>
	Range 5
	BV 3
	Magazine 80
	mass -7
	Acc 1
	Recharge 7
	sub
		ammo 6
		name_I18N <ピースメーカー用弾倉>
		type <ARMORPIERCING>
		mass -1
	end

	BodyArmor 9
	name <SWAT Armor>
	name_I18N <SWAT スーツ>
	Mass -13
	sub
		MLauncher 3
		name <Rocket Pack>
		name_I18N <ロケットパック>
		Acc -1
		Magazine 30
		range 8
		type <SWARM>
		sub
			Rockets 3
			name_I18N <ロケットパック用弾倉>
		end
	end

	Melee 23
	name <Hammer of Justice>
	name_I18N <正義の鉄槌>
	mass -15
	type <BRUTAL EXTEND THROWN RETURNING>
	Acc 2
	Recharge 4

	HeadArmor 9
	name <SWAT Helmet>
	name_I18N <SWAT ヘルメット>
	mass -16
	sub
		PCS 3
		name_I18N <電子機器>
		mass -2
	end


end
