plot 0
	name <The Kidnapped Professor>

	% - Edited to v0.901 "light" standard

	% E1 is the scene for the current episode.
	% E2 is the character who will tell the PC where to go.
	% E3 is the scene to be used in the next episode.
	% E4 is the character who will give the PC the combat mission.
	Element1 <Grab 3>
	Element2 <Character Guardian !Near 1>
	Element3 <Scene Town Target !Far 1>
	Element4 <Character Guardian !Far 1 !Far 3>

	% E5 is the professor who's been kidnapped
	% E6 is the enemy pilot who might or might not talk to the PC.
	Element5 <Prefab>
	Element6 <Prefab>

	Element7 <Grab 2>

	% V1 = Initialization Counter
	% V2 = Combat Counter
	% V3 = Time limit for search
	% V4 = Got confession from captured pilot

	% On a cleanup request just delete this plot.
	cleanup <AdvancePlot 0>

	% If Persona E2 or E4 dies, load a new plot.
	Init_Start <ifNPCOK E4 else GoDelete ifNPCOK E2 else GoDelete if= V1 0 V= 1 1 Compose EWM E1 .entry>
	start <ifNPCOK E4 else GoDelete ifNPCOK E2 else GoDelete if= V1 0 V= 1 1 Compose EWM E1 .entry>
	GoDelete <S= 101 1 AdvancePlot 0>

	.entry <if= P1 1 ifG PCScale 0 Block Alert 1 SavePos dynamic 2 Threat S103 50 .nu1 .nu2 PassVar 1 E1 P= 1 2 History 2>
	.nu1 <if= T1 0 return>
	.nu2 <if= T2 0 if= V2 0 V= 2 1 Exit V1 SeekGate 1>

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	nu1 <if= T1 0 if= V2 1  V= 2 2  LoseRenown>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 100>

	% Msg1 <As you approach \ELEMENT 1 , you encounter a group of mecha bearing \ELEMENT 7 markings!>
	Msg1 <\ELEMENT 1 に近づくと、 \ELEMENT 7 のシンボルを付けたメックの一団に遭遇した！>
	% Msg2 <You were attacked by \ELEMENT 7 on the way to \ELEMENT 1 .>
	Msg2 <\ELEMENT 1 へ向かう途中 \ELEMENT 7 に襲われた。>

sub
	Persona 2
	% rumor <!2 captured one of the !7 pilots who just attacked town.>
	rumor <!2 は最近この町を襲った !7 のパイロットたちを捕らえた>
	% V1 = Time limit for confession
	greeting <NewChat if= P4 1 else GoCheckTime Say 9 Memo 10>
	GoCheckTime <ifG V1 ComTime else GoCheckCOnfess Say 1>
	GoCheckCOnfess <if# V1 0 else GoFirstTime Say 2 Memo 10>
	GoFirstTime <V= 1 ComTime V+ 1 18000 P= 3 ComTime P+ 3 45000 Say 3 AddChat 1 AddChat 2 AddChat 3>
	result1 <NewChat AddChat 4 AddChat 5 Say 4>
	result2 <NewChat AddChat 4 AddChat 5 Say 5 Reputation 5 d6>
	result3 <NewChat AddChat 4 AddChat 5 Reputation 4 -d6 ifG React 25 else GoR3NoKnow Say 6>
	GoR3NoKnow <Say 7>
	result4 <EndChat Say 8 ForceChat E6>
	result5 <NewChat Say 11 AddChat 4 ifG SkRoll 37 10 AddChat 6>
	result6 <NewChat Say 12 Memo 10>
	% Msg1 <We're still interrogating the pilot from \ELEMENT 7 . Hopefully \SPR E6 will give us some information. It'll probably take a few hours. My only fear is, by that time it might be too late...>
	Msg1 <我々は今も \ELEMENT 7 のパイロットを尋問しているところです。うまくいけば \SPR E6 から情報を得られるでしょう。たぶんあと数時間かかります。それまでに事態が手遅れになるかもしれないということだけが心配です…。>
	% Msg2 <The pilot we captured finally spilled! They are taking the kidnapped professor to \SCENE EScene 4 ; \ELEMENT 4 there is leading the investigation.>
	Msg2 <我々の捕らえた例のパイロットがついに白状しました！彼らは誘拐した教授を \SCENE EScene 4 へ連れて行ったようです。そこの \ELEMENT 4 が捜査の指揮をとっています。>
	% Msg3 <Our town was just attacked by mecha. They appeared to belong to \ELEMENT 7 , but we can't be sure yet... The worst thing is, while they were here they kidnapped Professor \ELEMENT 5 from the university!>
	Msg3 <最近この町はメックに襲われました。奴らは \ELEMENT 7 に所属しているようでしたが、まだ確信は持てません…。最悪なことに、彼らはここにいる間に \ELEMENT 5 教授を大学から誘拐してしまいました！>
	% Msg4 <We don't know. They're using some kind of ECM gear... we haven't been able to track them. We did manage to capture one of their pilots who was forced to eject, though, and might be able to get some answers from \OPR E6 .>
	Msg4 <分かりません。奴らは何らかのＥＣＭ装置を使っていたので…我々は奴らを追うことができませんでした。我々はやむを得ずメックから脱出した敵パイロットを捕らえることができたので、 \OPR E6 から答を得られるかもしれません。>
	% Msg5 <\ELEMENT 5 is an expert on archeology. Maybe they think \SPR E5 can lead them to a buried treasure. We did manage to capture one of their pilots who was forced to eject, though, so maybe we can get some answers from \OPR E6 .>
	Msg5 <\ELEMENT 5 は考古学の専門家です。たぶん奴らは \SPR E5 を使って埋もれた宝物を探そうとでもいうのでしょう。我々はそのパイロットたちの一人をメックから脱出させ、捕らえることができたので、 \OPR E6 から答を得られるかもしれません。>
	% Msg6 <I know that you and \ELEMENT 7 have been enemies... maybe you could help us on this case. We captured one of their pilots and hope to find out soon where they've taken the professor, and for what purpose.>
	Msg6 <あなたと \ELEMENT 7 が敵同士だということは知っています…この事件の捜査に協力してくれませんか？我々は犯人のパイロットたちの一人を捕らえたので、奴らが教授をどこへ、そして何のために連れて行ったのかが分かることを願っています。>
	% Msg7 <We don't know what they're plotting yet. We did capture one of their pilots who was forced to eject during the raid, though... maybe \SPR E6 can tell us something.>
	Msg7 <奴らの企みは未だつかめていません。しかし、我々は襲撃中やむを得ずメックから脱出した敵パイロットを捕らえました… \SPR E6 から何か情報を得られるかもしれません。>
	% Msg8 <Alright, you can do that, but we've already tried getting \OPR E6 to talk... I don't know what good it'll do.>
	Msg8 <分かりました。そうしてもらっても結構ですが、すでに我々による \OPR E6 への尋問が行われていますから、あなたの協力がどれだけ役に立つかは分かりません。>
	% Msg9 <Good job with that pilot. \ELEMENT 4 in \SCENE EScene 4 is working on the case now. We better hurry; once they get the information they want out of the professor, they aren't likely to leave any witnesses.>
	Msg9 <よくやってくれました。今 \SCENE EScene 4 の \ELEMENT 4 がこの事件に取り組んでいます。急がなくてはなりません。教授から聞き出したい情報を手に入れれば、奴らは目撃者を放ってはおかないでしょうから。>
	% Msg10 <\ELEMENT 4 in \SCENE EScene 4 is investigating the kidnapped professor.>
	Msg10 <\SCENE EScene 4 の \ELEMENT 4 は誘拐された教授を捜査している。>
	% Msg11 <We're still analyzing the data from the encounter site. Here, take a look through these pictures... It'll take hours of analysis to learn anything useful.>
	Msg11 <交戦地点から回収したデータは未だ分析中です。どうぞ、これらの写真を見てください…。何か役に立つ手がかりを得るには、あと数時間は分析しなければならないでしょう。>
	% Msg12 <Ah, I see what you're getting at... If they followed the \ELEMENT 1 Trench to \SCENE EScene 4 , they'd escape most of the surveillance radar. I'll call \ELEMENT 4 and get \OPR E4 on the case right away!>
	Msg12 <成程、%JSが何を言いたいのか分かりました…もし奴らが \ELEMENT 1 の堀を通って \SCENE EScene 4 へ向かったなら、奴らはほとんどの監視レーダーに捉えられないでしょう。 \ELEMENT 4 に連絡してこの事件を今すぐ \OPR E4 に任せるとします！>
	% Prompt1 <Where did they take \OPR E5 ?>
	Prompt1 <奴らは \OPR E5 をどこへ連れて行った？>
	% Prompt2 <Who is this professor they took?>
	Prompt2 <奴らにさらわれた教授というのは何者？>
	% Prompt3 <They must be plotting something evil...>
	Prompt3 <奴らは悪巧みをしているに違いない…。>
	% Prompt4 <I want to speak with this pilot.>
	Prompt4 <そのパイロットと話したい。>
	% Prompt5 <Do you have any other leads?>
	Prompt5 <他に手がかりは？>
	% Prompt6 <Wait, isn't this near the \ELEMENT 1 trench?>
	Prompt6 <待て、これは \ELEMENT 1 の堀の近くじゃ？>

	Persona 6
	greeting <NewChat Say 1 AddChat 1 AddChat 2>
	result1 <NewChat ifG Intimidation 5 else GoNoDice Say 2 AddChat 3 AddChat 4 AddChat 5>
	GoNoDice <EndChat Say 3 ForceChat E2>
	result2 <NewChat ifG Conversation 5 else GoNoDice Say 4 AddChat 4 AddChat 6 AddChat 7>
	result3 <NewChat ifG Conversation 15 else GoR3NoDice Say 5 P= 4 1 ForceChat E2>
	GoR3NoDice <Say 6 AddChat 6 AddChat 7>
	result4 <NewChat Say 7 AddChat 8 AddChat 9>
	result5 <NewChat ifG Intimidation 10 else GoR5NoDice Say 8 P= 4 1 ForceChat E2>
	GoR5NoDice <EndChat Say 9 ForceChat E2>
	result6 <NewChat Say 10 AddChat 9>
	result7 <NewChat ifG Conversation 10 else GoR7Fail Say 13 P= 4 1 ForceChat E2>
	GoR7Fail <EndChat Say 14 ForceChat E2>
	result8 <ifG PCRep 2 -d100 else GoR8Success EndChat Say 11 ForceChat E2>
	GoR8Success <Say 12 P= 4 1 ForceChat E2>
	result9 <NewChat Say 15 P= 4 1 ForceChat E2>
	% Msg1 <What do you want? I've already told the cops- I don't know anything about no professor, and I'm not talking.>
	Msg1 <何の用だ？%JFはその教授について何も知らないし、話すこともない%JG。%JFはおまわり達にそう言ったはずだが。>
	% Msg2 <Alright, I'm listening. What do you want?>
	Msg2 <分かった、聞いてみよう。どうしたいんだ？>
	% Msg3 <Then you better think something else. I'm not opening my mouth again until my lawyer gets here.>
	Msg3 <それなら他の方法を考えたほうがいい。%JFは弁護士が来るまで口を開くつもりはないからな。>
	% Msg4 <You, help me? That's a laugh. How in hell are you gonna help me? And what do I need from a loser like you?>
	Msg4 <%JSが？%JFを？とんだ笑い種だね。%JSは一体どうやって%JFを助けるつもりだ？それに%JFは%JSのような負け犬に何を求めればいいんだ？>
	% Msg5 <They're going to \SCENE EScene 4 if you absolutely must know, but that's all you're getting from me.>
	Msg5 <もしどうしても知りたいというなら教えてやろう。奴らは \SCENE EScene 4 へ向かっている%JG。でも%JFに言えるのはそれだけだ。>
	% Msg6 <I already said that I'm not talking! What are you, stupid or something?>
	Msg6 <話すことはないとすでに言っただろう！%JSは何だ？馬鹿か何かか？>
	% Msg7 <Oh, yeah? What kind of deal?>
	Msg7 <へえ？どんな取引き？>
	% Msg8 <Alright, I've heard about you, I don't want to make any enemies I can't handle... They're headed for \SCENE EScene 4 . What they're going to do with the geezer I don't know.>
	Msg8 <分かった、%JSのことは噂に聞いている%JG。%JFも手に負えない敵は作りたくないからな…。奴らは \SCENE EScene 4 へ向かっている%JG。奴らがあの変人をどうするつもりかは知らない%JG。>
	% Msg9 <You can't threaten me... the guardians would bust your ass if you tried anything. That's it; I'm finished talking.>
	Msg9 <%JSなど怖くない%JG…もし%JSが何かしようものならGuardiansが%JSを逮捕するだろうからな。それだけだ。%JFの話は終わりだ。>
	% Msg10 <Er... Well, they can't get to me as long as I'm in jail... and they wouldn't hurt me if I don't talk, right? So I'm not gonna talk.>
	Msg10 <う…まあ、奴らも%JFが刑務所にいる限りは手を出せないだろう…それに%JFが喋らなければ奴らも%JFに危害を加えないはずだ、そうだろう？だから%JFは話すつもりはない%JG。>
	% Msg11 <Yeah, like I believe that! I don't think you've offered anyone a bribe before any time in your life... I'm finished talking. You're just wasting my time.>
	Msg11 <へえ、%JFがそんなことを信じるとでも？%JSはこれまで人に賄賂を贈ったことなどないだろう…。%JFの話は終わりだ。%JSは%JFの時間を無駄にしただけだったな。>
	% Msg12 <Yeah, like I believe that! You've got a lot of nerve to try, though... Look, the gang is headed to \SCENE EScene 4 . I don't know what they have planned but it's gonna get ugly real fast.>
	Msg12 <へえ、%JFがそんなことを信じるとでも？しかし、賄賂を申し出るとは%JSも度胸のある奴だな…。いいか、一味は \SCENE EScene 4 へ向かっている%JG。奴らが何を企んでいるのかは知らないが、事態は急速に悪化するだろうね。>
	% Msg13 <I didn't really want to get involved with them... and kidnapping that geezer, I didn't like that. Look, they're headed for \SCENE EScene 4 . I'm not such a bad person, y'know?>
	Msg13 <%JFはあまり奴らと関わりたくなかったし、あの変人を誘拐することにも関わりたくなかった%JG。%JFはそういうことは好きじゃない%JG。いいか、奴らは \SCENE EScene 4 へ向かっている%JG。%JFはそんなに悪い奴じゃないだろう？>
	% Msg14 <Easier? How're you supposed to make it easier in jail? Look, just leave me alone...>
	Msg14 <楽になる？刑務所なんかでどうやって楽になれというんだ？もういい、放っておいてくれ…。>
	% Msg15 <I guess my best chance of survival is to hope that you can beat them... they've gone to \SCENE EScene 4 . After they get the information they need the orders are to kill the professor. You better hurry... there's only a few hours left.>
	Msg15 <%JSが奴らを倒してくれるのに期待するほうが、%JFが生き残る見込みはあるかもしれない…。奴らは \SCENE EScene 4 へ行った%JG。必要な情報を手に入れたらあの教授を殺せという命令だった%JG。急いだほうがいい…あと数時間しかない。>
	% Prompt1 <Oh, I think you'll talk to me.>
	Prompt1 <%JSも%JFになら話そうと思うはずだ。>
	% Prompt2 <I'm here to help you.>
	Prompt2 <%JFは%JSを助けに来た%JG。>
	% Prompt3 <Where is your gang headed?>
	Prompt3 <%JSの仲間はどこへ向かっている？>
	% Prompt4 <I've got a deal for you.>
	Prompt4 <取引きがある%JG。>
	% Prompt5 <Tell me what I want to know, or else.>
	Prompt5 <%JFの知りたいことを教えろ。さもないと…。>
	% Prompt6 <\ELEMENT 7 doesn't like failure.>
	Prompt6 <\ELEMENT 7 は失敗を許さないだろう。>
	% Prompt7 <Tell us everything, and it'll be easier.>
	Prompt7 <すべて話してくれ、そうすれば楽になる%JG。>
	% Prompt8 <I'll pay you to tell me where they went.>
	Prompt8 <奴らがどこへ行ったか教えれば金をやろう。>
	% Prompt9 <I can protect you from \ELEMENT 7 .>
	Prompt9 <%JFが%JSを \ELEMENT 7 から守ろう。>

	Persona 4
	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	% If you're feeling faint of heart, just skip this
	% and jump straight to the messages block below.
	% Here are the variables used in this conversation:
	%  V1 = Job offer counter, V1=1 is job offered, V1=-1 if job denied
	%  V2 = Message Randomizer
	%  V3 = Threat value of enemy mecha
	%  V4 = Reward offered to PC for the mission
	%  V5 = Recharge time if mission fails
	% At startup, first check to see whether the PC has already
	% completed the mission or not.
	greeting <NewChat if= P3 0 else GoCheckWin SayAnything>
	GoCheckWin <if= P2 3 else GoCheckLoss  ifG P3 ComTime else GoProfDead Say 102 History 104 History 106 Goto GoBigWin>
	GoBigWin <Reputation 1 1 MoveChar E5 EScene 4 XRMystery NAV_XRMItem S= 101 1 S+ 102 1 S= 105 -1 N= 3 E3 AdvancePlot 1>
	GoProfDead <Say 103 S= 101 1 S+ 102 1 N= 3 E3 S= 105 -1 History 105 AdvancePlot 0>
	GoCheckLoss <if= P2 2 else GoCheckMission Say 101 S= 101 1 N= 3 E3 AdvancePlot 0>
	% Msg101 <The professor was killed. Now we may never learn what they were up to.>
	Msg101 <教授は殺されてしまいました。もはや奴らが何を企んでいたのかを知ることはできません。>
	% Msg102 <You did it! The gang has been stopped and \ELEMENT 5 rescued. We discovered that they were hoping the professor would lead them to an ancient weapon system... \SPR E5 will get out of the hospital in a while, you should visit later.>
	Msg102 <やりましたね！一味は止められ、 \ELEMENT 5 は救出されました。奴らは教授に古代兵器のところへ案内させようとしていたことが分かりました…。しばらくすれば \SPR E5 は病院から出てくるでしょうから、また後で来てください。>
	% Msg103 <The mecha gang was stopped, but they had already killed \ELEMENT 5 . Now we might never learn what they were planning... but at least they'll never get a chance to complete it.>
	Msg103 <メックの一味は止められましたが、 \ELEMENT 5 はすでに殺されていました。もはや奴らが何を企んでいたのかを知ることはできません…。少なくとも奴らがその企みを全うすることもできないわけですが。>
	% Msg104 <You rescued Professor \ELEMENT 5 from \ELEMENT 7 .>
	Msg104 <\ELEMENT 7 から \ELEMENT 5 を救出した。>
	% Msg105 <Professor \ELEMENT 5 died before you could rescue \OPR E5 .>
	Msg105 <救出する前に \ELEMENT 5 を殺されてしまった。>
	% Msg106 <You learned \ELEMENT 7 is searching for an ancient weapon.>
	Msg106 <\ELEMENT 7 が古代兵器を探していると分かった。>

	GoCheckMission <if= V1 1 else GoFirstTime Say 4 AddChat 1 AddChat 2 AddChat 3>

	% Unlike most combat missions, the PC is guaranteed to be offered
	% this one, since it's personal.
	% Set V1, V3, V4 here.
	GoFirstTime <V= 1 1 V= 3 Threat S103 100  Say 6 AddChat 4 AddChat 5>

	% Do everything here that has to be done. If some of the ExtraRandom
	% parameters need to be changed, do that here as well.
	GoEndMission <S= 101 1 S+ 102 1 N= 3 E3 AdvancePlot 0>

	% Combat being entered
	result1 <EndChat Say 5 SavePos P= 2 1 V= 5 ComTime V+ 5 86400 Dynamic 2 V3 .nu1 .nu2>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Salvage Return>
	% Combat being delayed
	result2 <NewChat Say 7>
	% How many points do the enemy have?
	result3 <NewChat Say 8 AddChat 1 AddChat 2>

	% Result 4 - may add Reputation command or whatnot
	result4 <NewChat Reputation 4 d8 Say 9 AddChat 1 AddChat 2 AddChat 3>

	% Result 5 - may add Reputation command or whatnot
	result5 <NewChat Reputation 4 -d8 Say 10 AddChat 1 AddChat 2 AddChat 3>

	% 4 : Player has accepted mission, has returned from repair
	% Msg4 <Are you ready to head out now? We can't waste time... there's no telling what they're doing to the professor even as we speak.>
	Msg4 <もう出発できますか？時間を無駄にはできません…我々がこうして話している間にも奴らが教授に何をしているか分かりません。>

	% 5 : Combat is starting
	% Msg5 <Good luck. Defeat the raiders, and hopefully we can bring \ELEMENT 5 back safely.>
	Msg5 <幸運を祈ります。襲撃者を倒してください。そうすればたぶん我々は \ELEMENT 5 を無事に連れ戻せるでしょう。>

	% 6 : NPC explains what the PC should do in this mission, and why
	% Msg6 <Some mecha marked like \ELEMENT 7 just rolled in from \ELEMENT 1 . They've holed up out of town, and it appears that they have a hostage... a kidnapped professor by the name of \ELEMENT 5 .>
	Msg6 <最近 \ELEMENT 1 から入り込んできた \ELEMENT 7 の部隊と思われるメック集団がいます。奴らはこの町の外に隠れており、人質を取っているようです…その人質は \ELEMENT 5 という名の誘拐された教授です。>

	% 7 : PC needs some time to get ready
	% Msg7 <You better hurry up. The best guess is they kidnapped the professor because \SPR E5 has some information they need... Once they get it, \SPR E5 will almost certainly be killed.>
	Msg7 <急いでください。奴らが教授を誘拐したのは \SPR E5 が奴らの必要とする情報を持っているからだと考えられます…。奴らがその情報を手に入れれば、教授はほぼ確実に殺されてしまうでしょう。>

	% 8 : How many points? Use "\VAL V3 " for that
	% Msg8 <They have around \VAL V3 tactical threat points worth of mecha.>
	Msg8 <奴らはおよそ \VAL V3 ポイントの戦力を持つメック部隊を有しています。>

	% 9 : Response to Prompt4
	% Msg9 <It's good to have you on our side. We really need a mecha pilot to disable their machines so the SWAT team can head in and rescue the professor.>
	Msg9 <あなたを我々の味方に迎えられて嬉しいです。SWAT 部隊が隠れ家に進入し教授を救出できるように奴らのメック部隊を倒してくれるパイロットが本当に必要なのです。>

	% 10 : Response to Prompt5
	% Msg10 <Woah, cool down... We do need a mecha pilot to disable their defenses so that our regular police can head in and rescue the professor. If you'd like to assist in the operation the job is all yours.>
	Msg10 <おっと、落ち着いてください…。正規の警官隊が隠れ家に進入し教授を救出できるように奴らの守りを破ってくれるメックパイロットが本当に必要です。>


	% 1 - 3 :  Standard combat entry options:
	%         Start Mission, Delay Mission, Mission Details
	% Prompt1 <I'm ready to do that now.>
	Prompt1 <もう準備は整った%JG。>
	% Prompt2 <Give me a minute to prepare.>
	Prompt2 <準備する時間をくれ。>
	% Prompt3 <What will I be facing?>
	Prompt3 <どんな敵が相手になる？>

	% 4 - 5 :  PC can have different reactions to Msg6 above
	% Prompt4 <I know... I'm here to help.>
	Prompt4 <知ってるよ…。%JFは協力しに来た%JG。>
	% Prompt5 <Tell me where the dogs are hiding!>
	Prompt5 <あの犬どもがどこに隠れているのか教えてくれ！>

	Plot 1
	Init_Start <if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	start <if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	GoCheckTime <ifG ComTime V1 AdvancePlot 0>
	sub
		Persona 5
		greeting <NewChat Say 1 AddCHat 1 PCAlly E5>
		result1 <NewChat Say 2 S= 105 1 AdvancePlot 0>
		% Msg1 <Hello \PC ; they told me that you were the one who rescued me. Thank you very much... I don't have anything to give you as a reward, other than my gratitude.>
		Msg1 <こんにちは \PC 。私を救出してくれたのはあなただと聞きました。ありがとうございます…。お礼に差し上げられるものは、感謝の気持ちしかありませんが。>
		% Msg2 <They were looking for an ancient weapon from the previous age... They thought I might know where to find it. I didn't tell them anything, of course, but I will tell you this: \ELEMENT 3 is the most likely place.>
		Msg2 <奴らは旧時代の古代兵器を探していました…。奴らは私ならその兵器がある場所を知っているかもしれないと考えたようです。私は奴らに何も教えませんでしたが、もちろんあなたには教えましょう。その兵器の在り処としては \ELEMENT 3 が最有力です。>
		% Prompt1 <Why did they kidnap you?>
		Prompt1 <奴らはなぜ%JSを誘拐したんだ？>
	end

end
inv
	NPC Professor
	chardesc old heroic lawful

	NPC Mecha Pilot
	CharDesc Chaotic Villainous Wangtta

end
