Plot 0
	name <Member Three>

	% Member Three is "The Collector", a gifted student who
	% collects body parts from his victims. As of the PC's entry
	% into this story E4 has kidnapped a citizen from E1. It
	% will be up to the PC to head in there and rescue the
	% hapless local.

	% E1 is the scene for this episode; E2 the scene for the next
	element1 <Grab 2>
	element2 <Scene Town !Far 1 !Member 11>

	% E3 is the guardian who will give the PC a reward
	element3 <Character Guardian !Near 1>

	% E4 is the murderer, E5 is the victim.
	element4 <Prefab>
	element5 <Character Citizen !Near 1>

	% E6 is the prop to be used for the victim.
	% E7 is the prop that can tell the PC where to go next.
	element6 <PREFAB>
	element7 <PREFAB>

	% V1 = Initialization Counter / NPC defeated indicator
	% V2 = Combat has been entered
	% V3 = Time limit for rescue; 6 hours from start of plot
	% V4 = Have rescued E5
	% V5 = Conversation indicator

	Init_Start <ifNPCOK E3 else GoDelete if= V1 0 V= 1 1 goto InitCheckE5>
	InitCheckE5 <ifNPCinPlay E5 else InitCheckFin print 10005 goto InitCheckFin>
	% Msg10005 <\ELEMENT 5 has left this area.>
	Msg10005 <\ELEMENT 5 はこのエリアを去った。>
	InitCheckFin <FreezeChar E5 goto GoInitNPC>
	start <ifNPCOK E3 else GoDelete if= V1 0 V= 1 1 FreezeChar E5 Goto GoInitNPC>
	GoInitNPC <S= 6 E4 Compose UTD E4 .e4dies NPCLevel E4 S2 P= 3 ComTime P+ 3 21600 Goto GoInitItem>
	GoInitItem <Compose KEY E6 .usekey Compose KEY E7 .useclue ItemVar= E6 1 P3 ItemVar= E6 2 E5 ItemVar= E6 4 E4 ItemVar= E7 10 E2>
	.e4dies <if= P1 1 P= 1 2 P= 2 3 S= 201 0 S+ 202 1 S= 5 ComTime S+ 5 13800 N= 2 E2>
	.usekey <if= V4 0 V= 4 1 Return>
	.useclue <ifG S202 S203 S= 203 S202 FacXP+ N1 1>
	GoDelete <S= 201 0 N= 2 E2 AdvancePlot 0>

	% On a cleanup request, put everything back to normal,
	% unless the PC has started the combat mission.
	CleanUp <if= V2 0 MoveChar E5 E1 DeleteChar E4 AdvancePlot 0>

	TM1 <if= SceneID 0 ifNPCinPlay E4 if= V5 0 ifG 6 Range PCUID NPCUID E4 V= 5 1 Print 101 ForceChat E4>
	% Msg101 <\ELEMENT 4 shouts at you!>
	Msg101 < \ELEMENT 4 があなたに向かって叫んだ！>

sub
	Persona 3
	% rumor <!3 has been investigating the "Murder Club".>
	rumor <!3 は「殺人クラブ」を捜査している>
	% V1 = Given mission or not
	% V2 = Message Randomizer
	% V4 = Cash reward offered
	greeting <NewChat if= P4 1 else GoNoRescue ifNPCOK S7 else GoNoS7 Say 1 CashPrize V4 MoveChar E5 E1 S+ 103 1 DeleteKeyItem E6 DeleteKeyItem E7 AdvancePlot 1>
	GoNoS7 <Say 2 CashPrize V4 MoveChar E5 E1 DeleteKeyItem E6 DeleteKeyItem E7 AdvancePlot 1>
	GoNoRescue <if= P1 2 else GoNoCapture V= 2 2 V+ 2 d2 Say V2 CashPrize V4 DeleteKeyItem E6 DeleteKeyItem E7 AdvancePlot 0>
	GoNoCapture <ifG P2 0 else GoCheckMission V= 2 4 V+ 2 d2 Say V2 LoseRenown DeleteChar E4 DeleteChar E5 S= 201 0 N= 2 E2 DeleteKeyItem E6 DeleteKeyItem E7 AdvancePlot 0>
	GoCheckMission <if= V1 1 else GoFirstTime Say 7 AddChat d3 V= 2 3 V+ 2 d3 AddChat V2>
	GoFirstTime <V= 4 Reward Threat S2 100 200 V= 1 1 V= 2 8 V+ 2 d2 Say V2 AddChat d3 V= 2 3 V+ 2 d3 AddChat V2 if# PCFac N1 V= 2 6 V+ 2 d2 AddChat V2>

	result1 <EndCHat Memo 101 V= 2 11 V+ 2 d2 Say V2 SavePos Goto GoStartCombat>
	GoStartCombat <LoadD .scene MStockD S2 .mdesc P= 2 1 DynaNPC E4 3 DynaItemTeam E6 4 DynaItemTeam E7 3>
	.scene <SCENE_Stronghold.txt>
	.mdesc <Robot Synth>
	result2 <Goto result1>
	result3 <Goto result1>

	result4 <NewChat Say 8>
	result5 <Goto result4>
	result6 <Goto result4>

	result7 <EndChat Reputation 3 -10 LoseRenown Say 11 DeleteChar E4 DeleteChar E5 AdvancePlot 0>
	result8 <goto result7>

	% Msg1 <You did it! The killer has been stopped, and \PERSONA E5 has been rescued. Here's the money you earned. When \SPR E5 gets out of the hospital, you should go visit \OPR E5 . Also you should visit \PERSONA S7 in \SCENE S8 .>
	Msg1 <やりましたね！ 殺人犯は止められ、 \PERSONA E5 は救出されました。こちらがあなたの分の報酬です。 \SPR E5 が退院したら、 \OPR E5 を訪ねるといいでしょう。 \SCENE S8 の \PERSONA S7 も訪ねるといいでしょう。>
	% Msg2 <You rescued \ELEMENT 5 ! The killer has been taken out of action, and we're hopefully one step closer to ending this "Murder Club" once and for all. Here's your reward.>
	Msg2 <あなたは \ELEMENT 5 を救出しました！ 殺人犯は止められ、我々はたぶん「殺人クラブ」を永久に終わらせるのに一歩近づきました。こちらが報酬です。>
	% Msg3 <The killer has been stopped, but not before taking one last victim... You did the best you could. Here's the reward I promised you.>
	Msg3 <殺人犯は止められましたが、すでに最後の犠牲者が出た後でした…。あなたはあなたにできる最善を尽くしました。こちらが約束の報酬です。>
	% Msg4 <You stopped the murderer, just unfortunately not in time. At least he won't be able to kill again. Here's your reward.>
	Msg4 <あなたは殺人犯を止めましたが、残念ながらわずかに間に合いませんでした。少なくとも奴は二度と殺人を犯すことができません。こちらが報酬です。>
	% Msg5 <That was a complete failure. \ELEMENT 4 escaped capture.>
	Msg5 <作戦は完全に失敗しました。 \ELEMENT 4 は逮捕を免れました。>
	% Msg6 <You have failed. \ELEMENT 4 got away.>
	Msg6 <あなたは失敗しました。 \ELEMENT 4 は逃走しました。>
	% Msg7 <Are you ready for the mission yet?>
	msg7 <もう任務の準備は整いましたか？>
	% Msg8 <Don't take too long. Remember, the killer has a hostage... there's no telling what is going on right now.>
	Msg8 <あまり時間をかけないでください。いいですか、殺人犯は人質をとっています…人質が今どうなっているか分かりません。>
	% Msg9 <It's an emergency! One of our town citizens, \ELEMENT 5 , has been kidnapped by a member of the "Murder Club"! I need a hunter immediately to go perform a rescue mission. If you can help, we'll discuss payment when you get back...>
	Msg9 <緊急事態です！ 市民の \ELEMENT 5 が「殺人クラブ」のメンバーに誘拐されました！ 救出任務を実行しに行ってくれるハンターが直ちに必要です。もし手を貸せるのなら、あなたが戻ってきたときに報酬の話をしましょう…。>
	% Msg10 <\ELEMENT 5 has been kidnapped by a member of the "Murder Club"! We have to stage a rescue mission quickly, before the killer has a chance to finish \PPR E4 deed! Can you help us? We have to hurry... we can discuss payment after you get back...>
	Msg10 < \ELEMENT 5 が「殺人クラブ」のメンバーに誘拐されました！ 殺人犯が \PPR E4 の悪行を終える前に、速やかに救出作戦を実行しなければなりません！ 手を貸してくれますか？ 我々は急がなくてはなりません…報酬の話はあなたが帰ってきてからにしましょう…。>
	% Msg11 <You don't care about other people, but some day you may need their help.>
	Msg11 <あなたが他人に気をかけなくとも、いつかはあなたも他人の助けが必要になるでしょう。>
	% Msg12 <Good luck out there. Don't become their next victim.>
	Msg12 <幸運を祈ります。奴らの次なる犠牲者とならないように。>
	% Msg13 <Good luck. I only hope that we aren't too late...>
	Msg13 <幸運を祈ります。手遅れでなければいいのですが…。>
	% Msg101 <\ELEMENT 3 in \SCENE EScene 5 asked you to rescue \ELEMENT 5 from the murder club.>
	Msg101 <\SCENE EScene 5 の \ELEMENT 3 に \ELEMENT 5 を殺人クラブの手から救出するよう頼まれた。>

	% Prompt1 <I'm ready to go right now.>
	Prompt1 <今すぐ行ける%JG。>
	% Prompt2 <There's no time to lose.>
	Prompt2 <無駄にできる時間はない%JG。>
	% Prompt3 <Let's catch this killer.>
	Prompt3 <その殺人犯を捕らえてみせよう。>
	% Prompt4 <I need some time to get ready.>
	Prompt4 <準備する時間が要る%JG。>
	% Prompt5 <Maybe I should get ready first.>
	Prompt5 <まずは準備しないと。>
	% Prompt6 <I'll start the mission in a bit.>
	Prompt6 <少ししたら任務を始めよう。>
	% Prompt7 <I don't care about \PERSONA E5 .>
	Prompt7 < \PERSONA E5 のことなどどうでもいい。>
	% Prompt8 <That's not my problem.>
	Prompt8 <%JFには関係ない%JG。>

	Persona 4
	greeting <EndChat if= V1 0 else GoAgain V= 1 d5 Say V1>
	GoAgain <Say V1>
	% Msg1 <So, you've discovered my lair. They call me "The Collector". Killing is how I get materials for my study... After I'm finished with this one, I'll take you apart and see what makes you so special.>
	Msg1 <%JFの隠れ家を見つけたな。%JFは「コレクター」と呼ばれている%JG。%JFにとって殺戮とは研究材料を集める方法だ… こいつの解剖が終わったら、%JSをバラバラにして、どうして%JSがそんなに並外れているのかを調べるとしよう。>
	% Msg2 <Welcome to my lair. It would be a shame not to introduce myself. In the murder club I'm known as "Dark Harvest". I like to collect all the interesting things people have inside their bodies. Prepare to become my next acquisition...>
	Msg2 <%JFの隠れ家にようこそ。せっかくだから自己紹介をしよう。%JFは殺人クラブ内で「ダーク・ハーベスト」と呼ばれている%JG。%JFは人間の体内にある全ての興味深い物を収集するのが好きなんだ。%JFの次なる獲物になる準備をするといい…。>
	% Msg3 <My name in the murder club is "Doctor". I think you need some of my attention... a nice painful death by vivisection is what I prescribe.>
	Msg3 <殺人クラブ内での%JFの名は「ドクター」だ。%JSには%JFの手当てが必要なようだね…%JSを生きたまま解剖して苦痛に満ちたすばらしい死を与えてあげよう。それが%JFの処方だ。>
	% Msg4 <Ah, another specimen has come to my lair. I'm known as "Gore Collector" because I like to keep parts of everyone I kill. Your head will make a splendid trophy, preserved in formaldehyde...>
	Msg4 <標本がもう一つ%JFの隠れ家にやってきたね。%JFは「ゴア・コレクター」と呼ばれている%JG。なぜなら殺した人間の部品を取っておくのが好きだからだ。%JSの頭はすばらしい記念品になるだろう。それをホルムアルデヒドに浸けて保存しよう…>
	% Msg5 <You've wandered into the lair of "Mad Genius". That's what they call me at school. Try not to fight too hard. I'm hoping to remove your brain intact for one of my projects.>
	Msg5 <%JSは「マッド・ジーニアス」の隠れ家に迷い込んできた%JG。%JFは学校でそう呼ばれている%JG。あまり暴れないでくれよ。%JFの計画のためにも、%JSの脳を無傷で取り除きたいからね。>


	Plot 1
	Init_Start <if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400 Memo 1>
	start <if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400 Memo 1>
	GoCheckTime <ifG ComTime V1 AdvancePlot 0>
	% Msg1 <You should go speak with \ELEMENT 5 in \SCENE EScene 5 .>
	Msg1 < \SCENE EScene 5 の \ELEMENT 5 と話しに行く必要がある。>
	sub
		Persona 5
		% rumor <!5 has been waiting to speak with you.>
		rumor <!5 はあなたと話すのを待っている>
		greeting <NewChat AddReact 20 Reputation 1 1 Say d3 AdvancePlot 0>
		% Msg1 <Thank you for rescuing me! You're very heroic.>
		Msg1 <%JFを助けてくれてありがとう！ %JSはまさにヒーローだよ。>
		% Msg2 <The doctors say I still have all my organs. Thank you so much for rescuing me!>
		Msg2 <医者によれば%JFの内臓は全部無事らしい%JG。%JFを助けてくれてありがとう！>
		% Msg3 <Thanks for rescuing me! Without your help, I'd most certainly be dead by now.>
		Msg3 <%JFを助けてくれてありがとう！ %JSが助けてくれなければ、今頃%JFはきっと死んでいたでしょう。>
	end

end
inv
	NPC Soldier
	job <Student>
	chardesc Young Pragmatic Villainous Villainous Villainous
	equipchar 15000

	STC VICTIM-1
	% V1 = Time limit for healthy rescue
	% V2 = Identity of the victim
	% V3 = Have tended to the victim's wounds
	% V4 = Identity of E4
	use <ifNPCOK V4 else GoE4Dead Print 1>
	Clue16 <Goto Use>
	Clue20 <Goto Use>
	GoCheckDie <>
	GoNoGood <>
	GoE4Dead <if= V3 1 else GoCheckStatus Print 2>
	GoCheckStatus <ifG V1 ComTime else GoHurt V= 3 1 Alert 3 Trigger KEY SelfNID>
	GoHurt <ifYesNo 4 5 6 Mental ifG SkRoll 16 7 else GoDead Print 8 V= 3 1 Trigger KEY SelfNID>
	GoDead <Print 7 SelfRunAway DeleteChar V2>
	% Msg1 <You can't do anything for \PERSONA V2 while \PERSONA V4 is still fighting you!>
	Msg1 < \PERSONA V4 が自分と戦っている内は \PERSONA V2 をどうにもできない！>
	% Msg2 <\PERSONA V2 will be fine, thanks to you.>
	Msg2 <%JSのお陰で、 \PERSONA V2 は快方に向かうだろう。>
	% Msg3 <You arrived here in time. \PERSONA V2 has been drugged but doesn't appear to have been harmed.>
	Msg3 <間に合った。 \PERSONA V2 は麻酔をかけられているものの、傷つけられてはいないようだ。>
	% Msg4 <\PERSONA V2 looks as if \SPR V2 has been operated upon. You may need to use Medical skill to save \PPR V2 life.>
	Msg4 < \PERSONA V2 はすでに手術を施されたようだ。 \PPR V2 の命を救うには医療スキルを使わなければならない。>
	% Msg5 <Attempt medical aid.>
	Msg5 <医療処置を試みる。>
	% Msg6 <I'm not qualified.>
	Msg6 <医療処置なんて自分には無理だ。>
	% Msg7 <\PERSONA V2 dies.>
	Msg7 < \PERSONA V2 は死亡した。>
	% Msg8 <You stabilize \PERSONA V2 , and call for backup.>
	Msg8 < \PERSONA V2 の容態を安定させ、救急隊を呼んだ。>

	STC APPARATUS-2
	% V10 = Location of next town
	update <>
	clue29 <Print 101>
	% Msg101 <It's a collection of actual human body parts.>
	Msg101 <人体部品のコレクションがある。>
	Clue37 <if= T3 0 else GoNotDead if= V30 0 else GoDid Mental ifG SkRoll 37 6 else GoFail V= 30 1 Print 2 XPV 100 Trigger KEY SelfNID>
	GoNotDead <Print 4>
	GoFail <V= 30 -1 Print 1>
	GoDid <Print 3>
	% Msg1 <You don't learn anything from this macabre collection.>
	Msg1 <この気味の悪いコレクションからは何も学べない。>
	% Msg2 <One of the names on a sample jar matches that of a missing person from \SCENE V10 .>
	Msg2 <あるサンプル瓶に書かれている名前が \SCENE V10 から失踪した人物の名前と一致した。>
	% Msg3 <You've already examined this collection. You don't want to do it again.>
	Msg3 <このコレクションはすでに調べた。二度と調べたくない。>
	% Msg4 <You shouldn't take time out to examine things while there's still someone trying to kill you.>
	Msg4 <自分を殺そうとしている人間がいる内は物を調べる時間をとれない。>

end

