Story
	name <STORY: Ex-Aegis>

	% V1 = Initialization Counter
	% S101 = Load new episode when S101 = 1
	% S102 = # PC Wins
	% S103 = Difficulcy Level, load ending when S103>75
	% S104 = # Wins when level last increased
	% S105 = Location Clue

	% The first START, force a conversation with Hyolee.
	Init_Start <>
	Start <if= V1 0 else GoCheckClue V= 1 1  MoreText .intro  S= 103 7  Print 1 ForceChat 1 History 2 History 3 DeleteChar N1 Goto GoInit>
	.intro <TS_TEXT_Entry_Luna2.txt>
	% Msg1 <Hyolee strikes up a conversation with you.>
	Msg1 <Hyolee が話しかけてきた。>
	% Msg2 <You fled Luna after deserting from Aegis Overlord Luna.>
	Msg2 <Aegis Overlord Luna から脱走し、月を逃れた。>
	% Msg3 <You arrived in Hogye as a refugee.>
	Msg3 <Hogye へ亡命した。>
	GoInit <Cash+ 5000 Reputation 1 -8>

	GoCheckClue <ifG S105 0 else GoNoClue Memo 5 S= 105 0>
	GoNoClue <ifG 0 S105 Memo 0 S= 105 0>
	% Msg5 <Your personal quest has so far led to \NARRATIVE 3 .>
	Msg5 <これまでの旅で得た手がかりが示す次なる目的地は \NARRATIVE 3 だ。>


	Element1 <Prefab>
	Element2 <Faction>
	Stat 2 7
	Element3 <Scene>
	Stat 3 10


	XREnemy 2
	XRMystery 1
	XRBadThing 5

	hour <if= S101 1 else GoCheckHint ifG S103 75 else GoLoadEpisode XRanPlot .xend S= 101 0 S+ 103 d10>
	GoLoadEpisode <XRanPlot .xplot S= 101 0 ifG S102 S104 S+ 103 10 S+ 103 d10 S= 104 S102 NPCLevel N1 S103 ifFaction N2 PCFEnemy N2>
	GoCheckHint <if= d30 1 ifG 76 S103 StoryLine .xhint>
	.xplot <TS_XRAN_a###_*.txt>
	.xend <TS_XRAN_b###_*.txt>
	.xhint <TS_XRAN_Hint_*.txt>

inv
	NPC Soldier
	mecha <Chimentero.txt>
	equipChar 25000

	Plot 0
	% Note that I am hotloading this plot- DO NOT
	% DO THIS YOURSELF!!! I can get away with it because
	% I'm the programmer. Note that because this plot is
	% getting sneaked into the adventure riding under a
	% story gear, it will not be initialized by the
	% MATCH_PLOT_TO_ADVENTURE procedure. In this case
	% it shouldn't matter because the story is loaded at
	% the game's setup, and all the elements are starting
	% initialized. However, in general, I think this is
	% very bad form...
	name <PLOT: Temporary Personas>

	Init_Start <ifNPCOK E2 else GoDelete>
	start <ifNPCOK E2 else GoDelete>
	GoDelete <S= 101 1 AdvancePlot 0>

	% Element 1 is Hyolee.
	Element1 <Character>
	Stat 1 1

	% Element 2 is Megi.
	Element2 <Character>
	Stat 2 17
	sub
		Persona 1
		% Hyolee will greet the PC and tell him to go
		% speak with Megi.
		greeting <NewChat if= V1 0 else GoBeenBefore V= 1 1 Say 1 AddChat 1 AddChat 2 AddChat 3>
		GoBeenBefore <Say 9 AddChat 7 AddCHat 8>

		result1 <NewChat Say 2  AddReact d8  Reputation 3 d10 AddChat 4 AddChat 5 AddChat 6>
		result2 <NewChat Say 3  Reputation 3 d10 Reputation 2 d8 AddChat 7>
		result3 <NewChat Say 4 AddChat 4 AddChat 5 AddChat 6>
		result4 <NewChat Say 5  Reputation 1 d6 Reputation 2 d5 Reputation 3 d3 Memo 7>
		result5 <NewChat Say 6  Reputation 3 -d10 Memo 7>
		result6 <NewChat Say 8 Memo 7 Reputation 2 -d5>
		result7 <NewChat Say 10 Memo 7>
		result8 <NewChat Say 11 Reputation 3 -d8 Reputation 4 -d8 Reputation 6 -1 S= 101 1 AdvancePlot 0>

		% Msg1 <Hi. I haven't seen you around before. My name is Hyolee; welcome to Hogye.>
		Msg1 <こんにちは。このあたりでは見ない顔ね。私は Hyolee よ。Hogye へようこそ。>
		% Msg2 <Nice to meet you too. It's refreshing to see a new face in town. We don't get a lot of visitors here, which is good for my studies but can be awful boring sometimes. So, tell me about yourself.>
		Msg2 <こちらこそ。この村じゃ新しい人と会うのは新鮮なことよ。この村を訪れる人はあまり多くないの。それは私の研究のためにはいいことなんだけど、ときどきひどく退屈に思うこともあるわ。ところで、あなたのことを教えてくれる？>
		% Msg3 <Er... That's good, I guess... Though maybe you'll want to keep that to yourself. Aegis Overlord Luna isn't too popular around here. Look, if you need some help fitting in, maybe you should go talk to Megi.>
		Msg3 <あら、そうなの…。でもそれは秘密にしておいたほうがいいわ。この辺りじゃ Aegis Overlord Luna の評判はあまりよくないから。そうね、ここの暮らしに馴れるのに誰かの手を借りたいなら、Megi をたずねるといいわ。>
		% Msg4 <Not much to say. It's a small town. Years ago there used to be a mine, but these days the big businesses are farming and tourism. We have a mecha arena. That's about it. What's your business in town?>
		Msg4 <ここには大したものはないわ。ただの小さな村よ。昔は鉱山があったけど、今日では主な収入は農業と観光ね。この村にはメックの闘技場があるわ。そんなところね。この村へは何をしに来たの？>
		% Msg5 <Luna? You're not one of those Aegis Overlord guys, are you? Better keep it to yourself if you are... you won't be very popular around here. You should go speak with Megi. She's our mayor... she can help you out a lot.>
		Msg5 <月？ Aegis Overlord Luna の人じゃないよね？ もしそうなら、それは秘密にしておいたほうがいいわ…この辺りじゃあなたたちの評判はあまりよくないから。Megi と話しにいくといいよ。彼女はこの村の村長なの…彼女なら十分にあなたの手助けをしてくれるわ。>
		% Msg6 <Ooh, mysterious. Well, if there's anything you need in town, you should probably speak with Megi. She's the mayor of Hogye. She lives in that white house over there.>
		Msg6 <あら、何かわけがありそうね。まあ、この村で何か困ったことがあれば、Megi と話してみるといいわ。彼女は Hogye の村長なの。あそこの白い家に住んでいるよ。>
		% Msg7 <Hyolee in Hogye told you to go speak with Megi.>
		Msg7 <Hogye の Hyolee から Megi を訪ねるよう言われた。>
		% Msg8 <If there's anything you need in town, you should go talk with Megi. She's the mayor.>
		Msg8 <この村で何か困ったことがあれば、Megi と話してみるといいわ。彼女は村長なの。>
		% Msg9 <Hello again. Have you spoken with Megi yet?>
		Msg9 <こんにちは。もう Megi とは話した？>
		% Msg10 <See that white-colored building over there? That's her house. It's the only one like it in town. You can't miss it.>
		Msg10 <あそこの白い建物が見える？ あれが彼女の家よ。あんな家は村に一つしかないから、絶対見つかるわ。>
		% Msg11 <If you don't want to, you don't have to. It was just a suggestion.>
		Msg11 <話したくないなら、話さなくても構わないわ。言ってみただけだから。>

		% Prompt1 <My name is \PC . Nice to meet you.>
		Prompt1 <%JFは \PC 。よろしく。>
		% Prompt2 <I am from Luna. I come in peace.>
		Prompt2 <%JFは月から来た%JG。仲良くしよう。>
		% Prompt3 <Hi. Tell me about this place.>
		Prompt3 <こんにちは。この村のことを教えて。>
		% Prompt4 <I'm a refugee from Luna.>
		Prompt4 <%JFは月から亡命してきた%JG。>
		% Prompt5 <That's private.>
		Prompt5 <それは言えない%JG。>
		% Prompt6 <I'm just a traveller.>
		Prompt6 <%JFはただの旅行者だよ。>
		% Prompt7 <How can I find her?>
		Prompt7 <彼女はどこに？>
		% Prompt8 <No, I don't want to.>
		Prompt8 <いや、話したくない%JG。>

		Persona 2
		% Megi will speak with the PC and then allow
		% conversation branches to load the various job
		% plots, or the tutorial plot.
		greeting <NewChat Say 1 AddChat 1 AddChat 2 AddChat 3 AddChat 4>

		result1 <NewChat Say 2 S= 101 1 StoryLine .Tutorial AdvancePlot 0>
		result2 <NewChat Say 3 S= 101 1 StoryLine .JobStory AdvancePlot 0>
		result3 <NewChat Say 4 S= 101 1 History 6 AdvancePlot 0>
		result4 <NewChat Say 5 S= 101 1 Reputation 2 -10 AddReact -30 StoryLine .CrimeStory AdvancePlot 0>

		.JobStory <ARC_TS_JobStory.txt>
		.CrimeStory <ARC_TS_CrimeStory.txt>
		.Tutorial <TS_PLOT_Tutorial.txt>

		% Msg1 <Greetings, stranger. Is there anything I can do for you?>
		Msg1 <ごきげんよう、初めてお目にかかる方ですね。何の用ですか？>
		% Msg2 <Quentin, our shopkeeper, would be the best one to ask about that. You'll find him in the building with the stone floor.>
		Msg2 <それなら店主の Quentin に聞くのが一番でしょう。彼は石の床の建物にいますよ。>
		% Msg3 <I think that Doctor Kim needs some help over at the clinic... You can ask about a job there.>
		Msg3 <Doctor Kim が医院で人手を借りたいようです…。そこへ行って仕事のことを聞くといいでしょう。>
		% Msg4 <As you wish. Enjoy your stay in Hogye.>
		Msg4 <お好きなように。Hogye にいるあいだ楽しんでください。>
		% Msg5 <We have nothing in this town worth stealing. Please leave here before you cause any trouble.>
		Msg5 <この村には盗むほどのものはありませんよ。厄介事を起こす前に、この村から出て行きなさい。>
		% Msg6 <You did not request any help from Megi.>
		Msg6 <Megi に協力を求めなかった。>

		% Prompt1 <Better give me the tutorial.>
		Prompt1 <チュートリアルを受けたい%JG。>
		% Prompt2 <I'm looking for a job.>
		Prompt2 <仕事を探している%JG。>
		% Prompt3 <Thanks, but I don't need anything.>
		Prompt3 <ありがとう、でも何も要らない%JG。>
		% Prompt4 <Thought I'd rob this town blind.>
		Prompt4 <この村で強盗をしまくろうかな。>

	end

end
