Story
	name <STORY: Adopted>

	% V1 = Initialization Counter
	% S101 = Load new episode when S101 = 1
	% S102 = # PC Wins
	% S103 = Difficulcy Level, load ending when S103>75
	% S104 = # Wins when level last increased
	% S105 = Location Clue

	% The first START, force a conversation with Hyolee.
	Init_Start <>
	Start <if= V1 0 else GoCheckClue  V= 1 1  MoreText .intro  S= 103 7  Print 1 ForceChat 1 History 2 History 3 Goto GoSetOps>
	GoSetOps <N= 2 0  NPCLevel N1 S103>
	.intro <TS_TEXT_Entry_UFU_Adopted.txt>
	% Msg1 <Hyolee strikes up a conversation with you.>
	Msg1 <Hyolee が話しかけてきた。>
	% Msg2 <You were orphaned as a small child and never knew your parents.>
	Msg2 <幼い頃から親がなく、両親を知らない。>
	% Msg3 <You were raised in Hogye.>
	Msg3 <Hogye で育った。>

	GoCheckClue <ifG S105 0 else GoNoClue Memo 5 S= 105 0>
	GoNoClue <ifG 0 S105 Memo 0 S= 105 0>
	%Msg5 <Your personal quest has so far led to \NARRATIVE 3 .>
	Msg5 <これまでの旅で得た手がかりが示す次なる目的地は \NARRATIVE 3 だ。>

	Element1 <Prefab>
	Element2 <Faction GoodEnemy>
	Element3 <Scene>
	Stat 3 10

	XREnemy 0
	XRMystery 2
	XRBadThing 1

	hour <if= S101 1 else GoCheckHint ifG S103 75 else GoLoadEpisode XRanPlot .xend S= 101 0 S+ 103 d10>
	GoLoadEpisode <XRanPlot .xplot S= 101 0 ifG S102 S104 S+ 103 10 S+ 103 d10 S= 104 S102 NPCLevel N1 S103 ifFaction N2 PCFEnemy N2>
	GoCheckHint <if= d30 1 ifG 76 S103 StoryLine .xhint>
	.xplot <TS_XRAN_a###_*.txt>
	.xend <TS_XRAN_b###_*.txt>
	.xhint <TS_XRAN_Hint_*.txt>

inv
	NPC Mecha Pilot
	mecha <Vadel.txt>
	EquipChar 50000

	Plot 0
	% Note that I am hotloading this plot- DO NOT
	% DO THIS YOURSELF!!! I can get away with it because
	% I'm the programmer. Note that because this plot is
	% getting sneaked into the adventure riding under a
	% story gear, it will not be initialized by the
	% MATCH_PLOT_TO_ADVENTURE procedure. In this case
	% it shouldn't matter because the story is loaded at
	% the game's setup, and all the elements are starting
	% initialized. However, in general, I think this is
	% very bad form...
	name <PLOT: Temporary Personas>

	Init_Start <ifNPCOK E2 else GoDelete>
	start <ifNPCOK E2 else GoDelete>
	GoDelete <AdvancePlot 0>

	% Element 1 is Hyolee.
	Element1 <Character>
	Stat 1 1

	% Element 2 is Megi.
	Element2 <Character>
	Stat 2 17
	sub
		Persona 1
		% Hyolee will greet the PC and tell him to go
		% speak with Megi.
		greeting <NewChat if= V1 0 else GoBeenBefore AddReact d30 V= 1 1 Say 1 AddChat 1 AddChat 2 AddChat 3>
		result1 <NewChat Reputation 4 d8 Say 2 AddChat 4 AddChat 5>
		result2 <NewChat Reputation 4 -d8 Say 3 AddChat 4 AddChat 5>
		result3 <NewChat Reputation 3 d10 Say 4 AddChat 4 AddChat 5>
		result4 <NewChat Say 103>
		result5 <NewChat Say 6>
		% Msg1 <Hi \PC . I heard that you were planning to leave here soon. All ready for your trip?>
		Msg1 <こんにちは \PC 。もうすぐこの町を出ようと思っているそうね。旅の準備は出来た？>
		% Msg2 <Yeah, there isn't much here, unless you want to grow potatoes for the rest of your life... Oh, I heard that Megi wanted to see you before you leave. She probably has some advice or something. You know her...>
		Msg2 <まあ、残りの人生をジャガイモ作りで過ごしたいとでも思わない限り、ここにはあまり面白いものはないわね…。そうそう、Megi はあなたが町を出る前に会っておきたいそうよ。たぶん助言か何かをくれると思うわ。Megi のことだからね…。>
		% Msg3 <Who isn't? Yeah, it's dull... but it's home. Remember, you can always come back here. Oh, that reminds me... Megi said that she wants to speak with you before you go. I guess she's going to give you some advice or something.>
		Msg3 <みんなそうよ。 確かに、つまらない町だけど…ここは故郷よ。いつでも帰ってきていいわよ。そうそう、Megi はあなたが出発する前に話しをしたいと言っていたわ。あなたにアドバイスか何かをくれると思うよ。>
		% Msg4 <Sounds like fun, but I really can't. This is the best place for my research... no distractions. By the way, Megi said that she wants to see you before you leave. Maybe she wants to go with you herself? That's a scary thought...>
		Msg4 <面白そうだけど、私には無理ね。ここは研究するには最適な場所なの…他のことに気を取られることもないし。ところで、Megi はあなたが出発する前に会いたいと言っていたわ。あなたと一緒に行くとか言い出したりして。考えただけでもぞっとするわね…。>
		% Msg6 <In the same place you usually can, in her house, that white one over there with the red carpet... Hm, I hope that when you go exploring the world, you don't get lost. Your direction sense never was that good...>
		Msg6 <普段と同じ場所にいるわ。つまり、赤いカーペットの敷かれた白い家の自宅よ…。はあ、あなたが世界を探検中に行方不明にならないといいんだけど…。あなたは方向音痴だからね…。>
		% Prompt1 <I want to see the world.>
		Prompt1 <世界を見にいきたい%JG。>
		% Prompt2 <I'm bored with this town.>
		Prompt2 <この町には飽き飽きしている%JG。>
		% Prompt3 <Why don't you come with me?>
		Prompt3 <一緒に来ないか？>
		% Prompt4 <I'll go see her, then.>
		Prompt4 <それなら、会いに行こう。>
		% Prompt5 <Where can I find her?>
		Prompt5 <彼女はどこに？>
		GoBeenBefore <Say 101 AddChat 101 AddCHat 102>
		result101 <NewChat Say 102>
		result102 <NewChat Say 103>
		% Msg101 <Hi. Have you spoken with Megi yet? She wanted to see you before you head out.>
		Msg101 <こんにちは。もう Megi とは話した？ Megi はあなたが出発する前に会いたいそうよ。>
		% Msg102 <It's the white house with the red carpet. There's only one like it in town. Come to think of it, there aren't that many houses in Hogye, anyhow... You should be able to find it by trial and error if you had to.>
		Msg102 <赤いカーペットが敷かれた白い家よ。この町にそんな家は一軒しかないわ。考えてみれば、いずれにせよ、Hogye にある家はそれほど多くないわ…。どうしてもというなら試行錯誤を繰り返して探すのね。>
		% Msg103 <Good luck, and come back to visit sometime!>
		Msg103 <幸運を祈るわ。いつでもまた会いに来てね。>
		% Prompt101 <Where is Megi's house, again?>
		Prompt101 <Megi の家はどこだったっけ？>
		% Prompt102 <I'm on my way.>
		Prompt102 <今から行くところだ。>



		Persona 2
		% Megi will speak with the PC and then allow
		% conversation branches to load the various job
		% plots, or the tutorial plot.
		greeting <NewChat if= V1 1 else GoFirstTime Say 1 AddChat 1 AddChat 2 AddChat 3 AddChat 4>

		result1 <NewChat Say 2 S= 101 1 StoryLine .Tutorial AdvancePlot 0>
		result2 <NewChat Say 3 S= 101 1 StoryLine .JobStory AdvancePlot 0>
		result3 <NewChat Say 4 S= 101 1 History 6 AdvancePlot 0>
		result4 <NewChat Say 5 S= 101 1 Reputation 2 -10 AddReact -30 StoryLine .CrimeStory AdvancePlot 0>

		.JobStory <ARC_TS_JobStory.txt>
		.CrimeStory <ARC_TS_CrimeStory.txt>
		.Tutorial <TS_PLOT_Tutorial.txt>

		% Msg1 <So, \PC , is there anything I can do for you before you leave here?>
		Msg1 <それで、\PC 、あなたがここを発つ前に、私に何か手伝えることはあるかしら？>
		% Msg2 <You'll want to speak with Quentin in the general store about that.>
		Msg2 <それなら総合用品店の Quentin に聞くといいでしょう。>
		% Msg3 <I think that Doctor Kim needs some help over at the clinic... You can ask about a job there.>
		Msg3 <Doctor Kim が医院で人の手を借りたいと言っていたように思います…。そこで仕事がないか尋ねるといいでしょう。>
		% Msg4 <As you wish. I'll see you again when you return.>
		Msg4 <お好きなように。この町に帰ってきたらまた会いましょう。>
		% Msg5 <When you leave this town, please don't go ruining our good name. If anyone asks, tell them you're from Ipshil...>
		Msg5 <この町を発ったら、どうかこの町の良い評判を汚さないでくださいね。誰かに聞かれたら、Ipshil の出身だと答えなさい…。>
		% Msg6 <You did not request any help from Megi.>
		Msg6 <Megi に協力を頼まなかった。>

		% Prompt1 <Better give me the tutorial.>
		Prompt1 <チュートリアルをしてほしい。>
		% Prompt2 <I could use a first job.>
		Prompt2 <初仕事を受けたい。>
		% Prompt3 <Thanks, but I don't need any help.>
		Prompt3 <ありがとう、でも結構です。>
		% Prompt4 <Thought I'd rob a bank or something.>
		Prompt4 <銀行強盗か何かをしようかと思うんだが。>

		GoFirstTime <V= 1 1 Say 101 AddChat 101 AddChat 102>

		Result101 <NewChat Reputation 5 d8 Say 102 AddChat 103 AddChat 104 AddChat 105>
		Result102 <NewChat Reputation 7 -d8 Say 103 AddChat 103 AddChat 104 AddChat 105>
		result103 <NewChat Reputation 3 d8 Say 104 Goto GoAddJobOps>
		result104 <NewChat Reputation 5 -d8 Say 105 Goto GoAddJobOps>
		result105 <NewChat Reputation 3 -d8 Say 106 Goto GoAddJobOps>

		GoAddJobOps <AddCHat 1 AddCHat 2 AddCHat 3 AddChat 4>

		% Msg101 <Hello \PC . I heard that you're planning to go soon. Are you planning to search for your history?>
		Msg101 <こんにちは \PC 。もうすぐこの町を出発しようとしているそうね。自分のルーツを調べに行くのかしら？>
		% Msg102 <Many young people have been leaving town. I suppose there isn't much left here to keep them. Well, remember, you can always come back to your home anytime you like.>
		Msg102 <若い人たちの多くはこの町を出て行きました。ここには彼らを引き止めるようなものはあまりないのでしょうね。でも、いいですか、いつでも気が向いたときに戻ってきてかまいませんよ。>
		% Msg103 <Good luck, but remember that the question of who you are is one that can only be answered from inside. Also, whatever you discover in your journeys, you can always call Hogye your home.>
		Msg103 <幸運を祈ります。しかし、いいですか、自分が何者であるかという問いへの答は自分の中にしか見つかりませんよ。それと、旅の中で何が分かったとしても、いつでも Hogye をあなたの故郷だと思ってくれて構いませんからね。>
		% Msg104 <That's good to hear. I have one last thing to ask you... Do you require any help before you start your journey?>
		Msg104 <それはよかった。最後に一つ聞きたいことがあるのですが…。あなたが旅に出る前に私の助けは必要かしら？>
		% Msg105 <Is that how you truly feel? Well, I have one last thing to do for you before you go. If you require any help in preparation for your journey, all you have to do is ask.>
		Msg105 <それはあなたの本音ですか？ まあ、あなたが発つ前に一つ聞きたいことがあります。旅の準備を手伝ってほしいなら、どうぞ言ってください。>
		% Msg106 <I know, some things don't need to be said. Well, I have one more thing to say before you leave... Is there any way I can help you prepare for your journey?>
		Msg106 <そうですね、言うまでもありませんね。では、あなたが発つ前にもう一つ聞きたいことがあります…。旅の準備を手伝えることはないかしら？>

		% Prompt101 <No, I just want to travel.>
		Prompt101 <いや、ただ旅をしたいだけだ。>
		% Prompt102 <Yes, I need to find out who I am.>
		Prompt102 <そう、自分が何者なのかを知りたい。>
		% Prompt103 <Thank you. It means a lot to me.>
		Prompt103 <ありがとう。そう言ってもらえると嬉しいよ。>
		% Prompt104 <Why? This town did nothing for me.>
		Prompt104 <なぜ？この町は何のためにもならなかったのに。>
		% Prompt105 <You don't need to say; I know.>
		Prompt105 <言うまでもない%JG。分かっている%JG。>

	end

end
