Plot 0
	name <Member Two>

	% Member One is "Rich Brat", who just joined the club out
	% of boredom. This member is EXTREMELY well equipped but
	% not particularly motivated; the PC can probably talk him
	% into surrendering.

	% E1 is the scene for this episode; E2 the scene for the next
	element1 <Grab 2>
	element2 <Scene Town !Far 1 !Member 11>

	% E3 is the guardian who will give the PC a reward
	element3 <Character Guardian !Near 1>

	% E4 is the murderer, E5 is his designer scarf.
	element4 <Prefab>
	element5 <Prefab>

	% V1 = Initialization Counter / NPC Defeated Counter
	% V2 = Clue Number
	% V3 = Have been accosted by E4 / Fight has started

	Init_Start <V= 1 1 goto GoInitNPC>
	start <if= V1 0 else GoCheckClue V= 1 1 Goto GoInitNPC>
	GoInitNPC <S= 6 E4 Compose UTD E4 .e4dies NPCLevel E4 S2 NPCSkill+ E4 7 1 NPCSkill+ E4 33 10 Goto GoInitItem>
	GoInitItem <Compose KEY E5 .usekey ItemVar= E5 1 E2 V= 2 S202 V+ 2 1 ItemVar= E5 2 V2 MoveChar E4 E1>
	% .e4dies <if= V1 1 S= 201 0 S+ 202 1 S= 5 ComTime S+ 5 13800 N= 2 E2 V= 1 2 Email d5>
	.e4dies <if= V1 1 S= 201 0 S+ 202 1 S= 5 ComTime S+ 5 13800 N= 2 E2 V= 1 2 SetNPC E3 Email d5>
	.usekey <ifG V2 S203 S= 203 V2 FacXP+ N1 1 AdvancePlot 0>
	% If the PC has discovered clues so as to make this plot worthless,
	% erase it now, so long as the NPC has already been defeated.
	GoCheckClue <if= V1 2 else GoCheckRevenge ifG V2 S203 else GoDelete>
	GoDelete <AdvancePlot 0>

	% If the PC is ugly, this NPC will attack.
	GoCheckRevenge <ifG 10 PCCharm ifNPCInPlay E4 NPCGoPC E4>
	TM1 <if= SceneID E1 ifNPCinPlay E4 ifG 10 PCCharm if= V3 0 ifG 6 Range PCUID NPCUID E4 V= 3 1 Print 101 ForceChat E4>

	cleanup <DeleteChar E4 AdvancePlot 0>

	% Msg1 <\ELEMENT 3 @ \SCENE ESCENE 3 :// You helped stop one of the "Murder Club". Come see me for a reward.>
	Msg1 <\ELEMENT 3 @ \SCENE ESCENE 3 :// あなたは「殺人クラブ」の一人を止めるのに協力してくれました。報酬を受け取りに来てください。>
	% Msg2 <\ELEMENT 3 @ \SCENE ESCENE 3 :// That was a member of the "Murder Club" you just fought with. Come see me for a reward.>
	Msg2 <\ELEMENT 3 @ \SCENE ESCENE 3 :// 先ほどあなたが戦ったのは「殺人クラブ」のメンバーでした。報酬を受け取りに来てください。>
	% Msg3 <\ELEMENT 3 @ \SCENE ESCENE 3 :// You just defeated a member of the "Murder Club". You do know there's a reward for that, don't you?>
	Msg3 <\ELEMENT 3 @ \SCENE ESCENE 3 :// 先ほどあなたは「殺人クラブ」のメンバーを倒しました。奴に賞金がかかっているのは知っているでしょう？>
	% Msg4 <\ELEMENT 3 @ \SCENE ESCENE 3 :// We've been trying to stop that killer ourselves. Come see me about it.>
	Msg4 <\ELEMENT 3 @ \SCENE ESCENE 3 :// 我々はあの殺人鬼たちを止めようとしています。それについて私に会いに来てください。>
	% Msg5 <\ELEMENT 3 @ \SCENE ESCENE 3 :// Good job in \ELEMENT 1 . There was a reward for that killer... come talk to me.>
	Msg5 <\ELEMENT 3 @ \SCENE ESCENE 3 :// \ELEMENT 1 ではよくやってくれました。あの殺人鬼には賞金がかけられていました…私と話をしに来てください。>

	% Msg101 <\ELEMENT 4 calls to you.>
	Msg101 < \ELEMENT 4 が呼んでいる。>

sub
	Persona 3
	% V1 = Have given reward
	% V2 = Message Randomizer
	greeting <NewChat if= P1 2 else GoNothing if= V1 0 else GoNothing V= 1 1 CashPrize Reward Threat PCRep 6 100 100 ifNPCOK S7 else GoNoS7 ifG React d30 else GoNoS7 ifG PCRep 2 -1 else GoNoS7 Say d3 S+ 103 1 Memo 7>
	GoNoS7 <V= 2 3 V+ 2 d3 Say V2>
	GoNothing <SayAnything>
	% Msg1 <You've done well in protecting the city. If you're interested in helping more, contact \PERSONA S7 in \SCENE S8 . Here's a reward for you.>
	Msg1 <あなたは町を守るのに成功しました。もしもっと協力してくれる気があるのなら、 \SCENE S8 の \PERSONA S7 と連絡を取ってください。こちらが報酬です。>
	% Msg2 <Here's your reward. Let me tell you something... if you'd like to help us defeat this murder club once and for all, go see \PERSONA S7 in \SCENE S8 .>
	Msg2 <こちらが報酬です。あなたに伝えたいことがあります…もしこの殺人クラブを永久に打倒するのに手を貸したいのなら、 \SCENE S8 の \PERSONA S7 に会いに行ってください。>
	% Msg3 <You've helped to defend our city. Here's a reward for you... If you'd like to continue working on this murder club case, you should contact \PERSONA S7 in \SCENE S8 .>
	Msg3 <あなたはこの町を守ってくれました。こちらが報酬です…。もしこの殺人事件の調査を続けたいのなら、 \SCENE S8 の \PERSONA S7 と連絡を取ってください。>
	% Msg4 <Here's your reward for helping out.>
	Msg4 <こちらがあなたの協力に対する報酬です。>
	% Msg5 <Here's a reward for your heroic deeds.>
	Msg5 <こちらがあなたの英雄的な行いに対する報酬です。>
	% Msg6 <You did well in protecting our city. Here's a reward.>
	Msg6 <あなたはこの町を守るのに成功しました。こちらが報酬です。>
	% Msg7 <\ELEMENT 3 in \SCENE EScene 3 told you to contact \PERSONA S7 in \SCENE S8 about the murder club investigation.>
	Msg7 < \SCENE EScene 3 の \ELEMENT 3 から殺人クラブの捜査について \SCENE S8 の \PERSONA S7 と連絡を取るように言われた。>

	Persona 4
	% rumor <!4 has fallen in with a bad crowd of teenagers.>
	rumor <!4 は落ちこぼれて不良少年の集団に加わった>
	% To start with, the PC will be prevented from starting combat
	% at a safe distance by using the telephone...
	greeting <ifG Range PCUID NPCUID E4 6 else GoRealStart EndChat Say 1>

	% Next, if combat has already started, E4 won't say anything new.
	GoRealStart <if= P3 2 else GoRealFirst Say 2>

	GoRealFirst <if= P3 1 else GoCheckRep V= 2 2 V+ 2 d3 Say V2 Goto GoStartCombat>
	GoCheckRep <ifG S202 0 else GoNoChance V= 2 5 V+ 2 d3 Say V2 Goto GoStartCombat>
	GoNoChance <V= 2 8 V+ 2 d3 Say V2 ifG S103 0 AddChat 9>

	GoStartCombat <AddChat d3 V= 2 3 V+ 2 d3 AddChat V2 P= 3 2 SoloAttack E4>
	% GoSurrender <Print 30 FacXP+ N1 1 XPV 75 if= P1 1 S= 201 0 S+ 202 1 S= 5 ComTime S+ 5 13800 N= 2 E2 P= 1 2 Email 29 DeleteChar E4>
	GoSurrender <Print 30 FacXP+ N1 1 XPV 75 if= P1 1 S= 201 0 S+ 202 1 S= 5 ComTime S+ 5 13800 N= 2 E2 P= 1 2 SetNPC E3 Email 29 DeleteChar E4>

	result1 <EndChat ifG PCCharm 10 else GoR1Fail V= 2 16 V+ 2 d2 Say V2 V= 2 6 V+ 2 d2 AddCHat V2 V= 2 9 V+ 2 d2 AddChat V2>
	GoR1Fail <Say 21>
	result2 <Goto result1>
	result3 <Goto result1>

	result4 <EndChat ifG Intimidation 10 else GoR4Fail V= 2 18 V+ 2 d2 Say V2 goto GoSurrender>
	GoR4Fail <V= 2 14 V+ 2 d2 Say V2>
	result5 <Goto result4>
	result6 <Goto result4>

	result7 <EndChat Reputation 1 1 ifG NPCRep E4 1 -1 else GoR7Fail V= 2 23 V+ 2 d2 Say V2 Goto GoSurrender>
	GoR7Fail <V= 2 21 V+ 2 d2 Say V2>
	result8 <goto result7>

	result9 <EndChat V= 2 11 V+ 2 d3 Say V2 goto GoStartCombat>

	result10 <EndChat ifG Intimidation 7 else GoR10Fail V= 2 30 V+ 2 d2 Say V2 goto GoSurrender>
	GoR10Fail <V= 2 25 V+ 2 d2 Say V2>
	result11 <goto result10>

	% Msg1 <I don't like using the phone. Come over here if you've got something to say to me.>
	Msg1 <%JFは電話を使いたくない%JG。言うことがあるならここへ来てくれ。>
	% Msg2 <You'll be sorry you made me angry!>
	Msg2 <%JSは%JFを怒らせたことを後悔するだろう！>

	%  03 - 05 :  PC is ugly.
	% Msg3 <Eww! Ugly people like you shouldn't be allowed in public. Allow me to introduce myself... They call me "Rich Brat" in the murder club. I'll do a public service by removing you from the gene pool.>
	Msg3 <ゲッ！ %JSのような醜い奴は公衆の面前に出てくるんじゃねえ。%JFの自己紹介をさせてくれ…。%JFは殺人クラブで「リッチ・ボーイ」と呼ばれている%JG。%JFは%JSを遺伝子給源から取り除いて社会貢献するとしよう。>
	% Msg4 <How ugly! I can't stand unattractive people like you. My name is \ELEMENT 4 , but in the murder club they call me "Gold Killer". You've offended my aesthetics so now you must die!>
	Msg4 <何て醜い奴だ！ %JSのような気味の悪い人間は見るに耐えない%JG。%JFの名は \ELEMENT 4 というが、殺人クラブでは「ゴールド・キラー」と呼ばれている%JG。%JSは%JFの美的感覚にとって目障りだから、今すぐ死ね！>
	% Msg5 <I'm so glad that I wasn't born as ugly as you... the only cure for true ugliness is death, I'm afraid. I am "Lovely Knife" of the murder club. The world will be a much more beautiful place once I've removed you from it.>
	Msg5 <%JFが%JSぐらい醜く生まれなくてよかったよ…残念ながら、%JSがその真性の醜さを治すには死ぬしかない%JG。%JFは殺人クラブの「ラブリー・ナイフ」だ。%JFが%JSを取り除けば、この世は今よりはるかに美しい場所になるだろう。>

	%  06 - 08 :  PC has defeated other members of the club.
	% Msg6 <I thought you'd be coming for me sooner or later, \PC . I am "Rich Brat" of the murder club. I'm not afraid of you... with the best technology money can buy, I should be able to easily defeat you!>
	Msg6 <%JSは遅かれ早かれ%JFのところへやって来ると思っていた%JG、 \PC 。%JFは殺人クラブの「リッチ・ボーイ」だ。%JFは%JSなど怖くない%JG…金で買える最高のテクノロジーを以てすれば、%JSを殺すことなど簡単さ！>
	% Msg7 <Ah, \PC , you're smarter than you look. They said that you'd be hunting us down one by one. Well now the hunter becomes the hunted... In the murder club I'm known as "Gold Bug", and with my superior equipment I'll make short work of you!>
	Msg7 <おや、 \PC 。%JSは見た目より賢いな。%JFたちを次々倒しているらしいね。そして今度は%JSが倒される… %JFは殺人クラブで「ゴールド・バグ」と呼ばれている%JG。%JFの優れた装備を以てすれば%JSなどあっという間だ！>
	% Msg8 <So I've been found by the hunter who's taking out the murder club. Am I scared? Hardly. They call me "Rich Killer", and with my superior firepower I can easily defeat you.>
	Msg8 <なるほど%JFは殺人クラブを倒しているハンターに見つかったわけか。%JFが怖がっていると思うか？ 全然怖くないね。%JFは「リッチ・キラー」と呼ばれている%JG。%JFの優れた火力を以てすれば%JSなど簡単に倒せる%JG。>

	%  09 - 11 :  PC isn't renowned; will be ignored by this character.
	% Msg9 <Oh, how common.>
	Msg9 <何だい、凡人くん。>
	% Msg10 <I'm so glad that I'm not ugly like those other students.>
	Msg10 <%JFは他の生徒たちのように醜くなくてよかったと思う%JG。>
	% Msg11 <Die young and leave a beautiful corpse...>
	Msg11 <若くして死に、美しい屍を遺すのさ…。>

	%  12 - 14 :  PC has asked about the murder club.
	% Msg12 <You're looking for the murder club? People who do that end up dead... My nickname is "Deadly Brat"; I will defeat you for the glory of our club!>
	Msg12 <%JSは殺人クラブをお探しかな？ そんなことをする奴は死んで終わりだよ…。%JFのニックネームは「デンジャラス・ボーイ」だ。我がクラブの栄光のためにも、%JFは%JSを倒す！>
	% Msg13 <Why are you interested in the murder club? We're not accepting ugly old people as members... you may make a lovely target, though. My nickname is "Gold Hunter" and I'll be killing you today!>
	Msg13 <%JSはどうして殺人クラブに興味を持っているんだい？ 醜い年配の人間はメンバーに入れないんだけど…%JSは美しい獲物になりそうだ。%JFのニックネームは「ゴールド・ハンター」だ。今日こそ%JSを殺す！>
	% Msg14 <Are you a cop? This is exciting, I've always wanted to kill a police officer... In the murder club I'm known as "Cash Money". With my superior firepower I'll be serving you your death right now!>
	Msg14 <%JSはおまわりかい？それならわくわくする%JG。日頃から警官を殺したいと思っていたからね…。%JFは殺人クラブで「キャッシュ・マネー」と呼ばれている%JG。%JFの優れた火力を以て、今すぐ%JSに死をもたらしてやろう！>

	%  15 - 16 :  PC wants to start the fight immediately.
	% Msg15 <Don't worry, it'll all be over very quickly.>
	Msg15 <心配するな。すべてすぐに終わるから。>
	% Msg16 <I'll try to leave at least one part intact so your family can have something to bury.>
	Msg16 <埋めるものがないと%JSの遺族が困るだろうから、少なくとも一部はそのまま残してやろう。>

	%  17 - 18 :  PC doesn't want to fight.
	% Msg17 <Do you have any better suggestions?>
	msg17 <他にもっといい提案があるのか？>
	% Msg18 <You don't want to fight? Then, what else am I supposed to do?>
	Msg18 <戦いたくないって？ それなら、%JFは他に何をすればいいというんだ？>

	%  19 - 20 :  NPC chickens out from fight.
	% Msg19 <You're not afraid? That means you can probably beat me... Look, I don't really want to fight you. I'll just surrender to that guardian over there, okay?>
	Msg19 <%JSは怖くないのか？ それならたぶん%JFは%JSに勝てないだろうな…。おい、実は%JFは%JSと戦いたくない%JG。%JFはあそこにいるGuardian隊員に自首するよ。それでいいか？>
	% Msg20 <What, you're not going to run away? I don't want to fight anyone who's going to fight back... Look, this murder club was a bad idea. It wasn't my fault... all my friends joined... I'll just surrender to that guardian over there, okay?>
	Msg20 <何だと、%JSは逃げないのか？ %JFは抵抗する人間とは戦いたくない%JG…。そうだ、この殺人クラブが悪いんだよ。%JFは悪くない…%JFの友だちも皆入っている%JG…。%JFはあそこにいるGuardian隊員に自首するよ。それでいいか？>

	% Msg21 <But if we don't fight, that means an unattractive person like you gets to live. I can't accept that! I must kill you now!>
	Msg21 <しかし%JFたちが戦わなければ、%JSのような醜い人間を生かしておくことになる%JG。それはごめんだね！ 今すぐ%JSを殺してやる！>
	% Msg22 <I know you think I must just be some poor misguided little angel... but the truth is, I've come to enjoy killing... now I will enjoy killing you!>
	Msg22 <%JSは%JFを道を誤った哀れな幼い天使だとでも思っているのだろうが…しかし実際は、%JFは殺人を楽しむ悪魔になった%JG…さあ%JSを殺すのを楽しむとしよう！>
	% Msg23 <What, you think a few nice words and my entire life can turn around? I got news for you- I'm no angel. In fact, I'm a lot closer to a demon, as you're about to discover...>
	Msg23 <何か、%JSはきれい事を二、三言っただけで%JFの人生全部を変えられると思っているのか？ %JSに教えることがある。%JFは天使じゃない%JG。実際、%JFはそれよりずっと悪魔に近い%JG。%JSもすぐに分かるようにな…。>
	% Msg24 <You could be right... I never really wanted to be part of the murder club, you know, but all my friends were joining so I did too... I don't want to ruin the rest of my life... I'll turn myself in.>
	Msg24 <%JSの言う通りだよ…。%JFは本当は殺人クラブのメンバーになりたくなかった%JG。でも%JFの友だちが皆入ったから、%JFもそうしただけなんだ…。%JFは残りの人生を台無しにしたくない%JG…。%JFは自首するよ。>
	% Msg25 <I want to... this "Murder Club" thing has gone too far, really... I never wanted to be a killer but all my friends joined so I had to... I think the best thing would be for me to surrender to the guardians. I'll do it.>
	Msg25 <%JFはそうしたい%JG…この「殺人クラブ」は度が過ぎている%JG、実際ね…。%JFは殺人犯になりたくなかったけど、友だち皆が入ったから%JFもそうしなければと思って…。%JFにとって最もいいのはGuardiansに自首することだろうね。そうするよ。>
	% Msg26 <And spend the rest of my life in jail? That's not the kind of accomodation I'm used to. No, it's a much better idea for me to kill you instead...>
	Msg26 <そして残りの人生を刑務所で過ごせと？ 刑務所なんて%JFが住み慣れるような施設じゃない%JG。そう、そのかわりに%JSを殺すほうが%JFにとってはずっといい考えだね…。>
	% Msg27 <Are you nuts? I've heard what happens to people like me in jail. There's no way out but to kill you...>
	Msg27 <%JSはアホか？ %JFのような人間が刑務所内でどうなるかは聞いて知っている%JG。%JSを殺す以外に方法はない%JG…。>
	% Msg29 <\ELEMENT 3 @ \SCENE ESCENE 3 :// You helped capture one of the members of the "Murder Club". Come see me for a reward.>
	Msg29 <\ELEMENT 3 @ \SCENE ESCENE 3 :// あなたは「殺人クラブ」のメンバーを止めてくれました。報酬を受け取りに来てください。>
	% Msg30 <\ELEMENT 4 has surrendered.>
	Msg30 < \ELEMENT 4 は降参した。>
	% Msg31 <Now that you mention it, surrender does sound like a nice option... I quit...>
	Msg31 <%JSが言うからには、降参したほうがよさそうだ…%JFは降りるよ…。>
	% Msg32 <I don't want to get hurt... I only joined the murder club because of peer pressure... I surrender...>
	Msg32 <%JFは怪我したくない%JG…%JFは仲間から誘われて殺人クラブに入っただけなんだ…降参するよ…。>

	%  01 - 03 :  PC doesn't want to fight.
	% Prompt1 <We don't have to fight, you know.>
	Prompt1 <%JFたちは戦う必要はない%JG。>
	% Prompt2 <You don't have to fight me.>
	Prompt2 <%JSは%JFと戦う必要はない%JG。>
	% Prompt3 <There are better things to do than fight.>
	Prompt3 <戦うよりもいいことがある%JG。>

	%  04 - 06 :  PC wants to start the fight now.
	% Prompt4 <I can take you.>
	Prompt4 <%JFは%JSを倒せる%JG。>
	% Prompt5 <Sounds like fun. Let's rumble.>
	Prompt5 <面白そうだ。始めようか。>
	% Prompt6 <Let's start this fight.>
	Prompt6 <この戦いを始めよう。>

	% Prompt7 <You can reform your life.>
	Prompt7 <%JSは人生をやり直せる%JG。>
	% Prompt8 <Repent your crimes and go straight.>
	Prompt8 <%JSの罪を悔い、まっとうに生きなさい。>

	% Prompt9 <I need to ask you about the murder club.>
	Prompt9 <殺人クラブのことを聞きたいんだが。>

	% Prompt10 <Give up before you get hurt.>
	Prompt10 <怪我をしないうちに降参しろ。>
	% Prompt11 <Surrender now or I'll kill you.>
	Prompt11 <直ちに降参しろ。さもなくば殺す。>

end
inv
	NPC Soldier
	job <Student>
	chardesc Young Sociable Chaotic
	EquipChar 250000
	Charm 17

	Treasure 1500
	name <Bracelet>
	name_I18N <ブレスレット>
	place <4>
	% V1 = Location of next encounter
	% V2 = Clue number for this item
	% V3 = Investigation Indicator
	% V4 = PC Investigation skill when last tried
	use <if= V3 1 else GoNoSolve Print 1>
	GoNoSolve <Print 2>
	Clue37 <ifG PCSkillVal 37 V4 else GoDid Mental V= 4 PCSkillVal 37 ifG SkRoll 37 10 else GoNoSolve V= 3 1 Print 1 XPV 100 Trigger KEY SelfNID>
	GoDid <if= V3 1 else GoNoSolve Print 1>
	% Msg1 <There's still an anti-theft chip attached to this bracelet. It came from a department store in \SCENE V1 .>
	Msg1 <このブレスレットにはまだ万引き防止用チップが付いている。これは \SCENE V1 のデパートにあったものだ。>
	% Msg2 <It's a bracelet.>
	Msg2 <これはブレスレットだ。>

end
