Plot 0
	name <PLOT: Assassins!>
	% - Edited to v0.901 "light" standard

	% The PC has an unknown enemy... In this town he will meet an
	% assassin, and this will result in a new adventure.

	Element1 <Grab 3>
	Element2 <Scene Town Target !Far 1>
	Element3 <Prefab>
	Element4 <Character Guardian !Near 1>
	Element5 <Faction GoodEnemy>
	Element6 <Prefab>

	% On a cleanup request, just delete this plot.
	CleanUp <AdvancePlot 0>

	% V1 = Phase Counter

	Init_Start <ifNPCOK E3 else GoEndPlot ifNPCOK E4 else GoEndPlot if= V1 0 else GoSetOrder V= 1 1 Compose UTD E3 .killerdies FreezeItem E6 NPCLevel E3 S103>
	start <ifNPCOK E3 else GoEndPlot ifNPCOK E4 else GoEndPlot if= V1 0 else GoSetOrder V= 1 1 Compose UTD E3 .killerdies FreezeItem E6 NPCLevel E3 S103 Goto GoSetOrder>
	GoEndPlot <S= 101 1 AdvancePlot 0>
	.killerdies <Reputation 6 1 History 2 AdvancePlot 1>
	GoSetOrder <ifNPCInPlay E3 NPCGoPC E3>

	% TM1 <if= SceneID E1 ifNPCinPlay E3 if= V1 1 ifG 6 Range PCUID NPCUID E3 V= 1 2 Print 1 ForceChat E3>
	TM1 <if= SceneID E1 ifNPCinPlay E3 if= V1 1 ifG 6 Range PCUID NPCUID E3 Print 1 ForceChat E3>
	% Msg1 <\ELEMENT 3 strikes up a conversation with you.>
	Msg1 <\ELEMENT 3 が話しかけてきた。>

	% Msg2 <You survived an assassination attempt in \ELEMENT 1 .>
	Msg2 <\ELEMENT 1 で暗殺されそうになったが生き残った。>

sub
	Persona 3
	% rumor <!3 has been asking a lot of questions about you.>
	rumor <!3 はあなたに聞きたいことがたくさんある>
	greeting <NewChat Say d3 AddChat 1 AddChat 2 AddChat 3>
	% result1 <EndChat Say 4 Reputation 2  1 SoloAttack E3>
	% result2 <EndChat Say 5 Reputation 2 -1 SoloAttack E3>
	% result3 <EndChat Say 6 SoloAttack E3>
	result1 <EndChat Say 4 Reputation 2  1 P= 1 2 SoloAttack E3>
	result2 <EndChat Say 5 Reputation 2 -1 P= 1 2 SoloAttack E3>
	result3 <EndChat Say 6 P= 1 2 SoloAttack E3>
	% Msg1 <Are you \PC ?>
	Msg1 <%JSは \PC か？>
	% Msg2 <Aren't you \PC ? I have something that I need to discuss with you.>
	Msg2 <%JSは \PC じゃないか？%JSと話したいことがある%JG。>
	% Msg3 <Hey, just a minute... You're \PC , aren't you?>
	Msg3 <やあ、ちょっといいかな…。%JSは \PC だね？>
	% Msg4 <I am... your death!!!>
	Msg4 <%JFは…%JSの死神さ！！！>
	% Msg5 <Nice try, \PC , but you aren't getting away this time... Now you die!>
	Msg5 <いい悪あがきだな、 \PC 。だが今回ばかりは逃げられないぞ…さあ死ぬがいい！>
	% Msg6 <No, but I know you. You're the one I was sent here to kill. Now, it's time to finish the job!>
	Msg6 <会ったことはないが、%JFは%JSのことを知っている%JG。%JFは頼まれて%JSを殺しに来た%JG。さあ、仕事を終わらせるとするか！>
	% Prompt1 <Yes I am. Who are you?>
	Prompt1 <そうだけど、%JSは？>
	% Prompt2 <Sorry, you must be mistaken...>
	Prompt2 <申し訳ないが、人違いだ…。>
	% Prompt3 <Do I know you?>
	Prompt3 <どこかでお会いしたかな？>

	Plot 1
		% The PC has stopped the killer, and may now take a mission
		% from the local guardian.
		Init_Start <ifNPCOK E4 else GoEndPlot if= V1 0 Compose KEY E6 .usecomp>
		start <ifNPCOK E4 else GoEndPlot if= V1 0 Compose KEY E6 .usecomp>
		GoEndPlot <AdvancePlot 0 S= 101 1>
		.usecomp <if= P3 0 XPV 100 P= 3 1>

		% V2 = Combat Indicator; if V2=10 mecha, V=20 personal,
		%                              +1 = Win, +2 = Fail
		% V3 = Recovered computer file

		NU1 <if= V2 10 else GoP_NU1 if= T1 0 LoseRenown V= 2 11>
		GoP_NU1 <if= V2 20 if= T1 0 Return if= P3 1 else GoP_Fail V= 2 21  Reputation 6 1>
		GoP_Fail <V= 2 22>

		NU2 <if= V2 10 if= T2 0 Reputation 6 1 V= 2 12>

	sub
		Persona 4
		% rumor <!4 the guardian wants to talk with you.>
		rumor <Guardian隊員の !4 があなたと話したがっている>
		% V1 = Phase Counter
		% V2 = Message Picker
		% V3 = Recharge Time
		% V4 = XP award
		greeting <NewChat if= P2 12 else GoCheckPWin Say 20 AddChat 17 if= V4 0 XPV 200 V= 4 1 AddReact d8>
		GoCheckPWin <if= P3 1 else GoCheckLoss Say 19 AddChat 17 if= V4 0 XPV 1000 V= 4 1 AddReact d12>
		GoCheckLoss <ifG P2 0 else GoCheckRecharge P= 2 0 Say 17 V= 3 ComTime V+ 3 86400>
		GoCheckRecharge <ifG V3 ComTime else GoCheckContact Say 18>
		GoCheckContact <if= V1 1 else GoFirstTime Say 15 AddChat 7 AddChat 8>
		GoFirstTime <V= 1 1 Memo 13 Say 1 AddChat 1 AddChat 2 AddChat 3>

		result1 <NewChat Reputation 2 -1  Say 2  AddChat 4 AddChat 5>
		result2 <NewChat Reputation 1  1  Say 3  AddChat 4 AddChat 5>
		result3 <NewChat Reputation 3 -d6 Say 4  AddChat 4 AddChat 5>
		result4 <NewChat Reputation 2  1  Goto GoExposition>
		result5 <NewChat Reputation 2 -5  Say 6 AddChat 9 AddChat 10>

		result6 <NewChat Say 7 AddChat 11 AddChat 7 AddChat 8>
		result7 <NewChat Say 14 AddChat 14 AddChat 15>
		result8 <NewChat Say 8 AddChat 12 AddChat 13>
		result9 <NewChat Goto GoExposition>
		result10 <NewChat Say 9>
		result11 <NewChat Say 9>
		result12 <NewChat Say 10 AddChat 14 AddChat 15>
		result13 <NewChat Say 11 AddChat 16 AddChat 15>

		% Start mecha combat
		result14 <EndChat Say 21 SavePos P= 2 10 Dynamic 2 Threat S103 125 .nu1 .nu2>
		.nu1 <if= T1 0 Return>
		.nu2 <if= T2 0 Salvage Return>

		result15 <NewChat Say 12>

		% Start personal combat
		result16 <EndChat Say 16 SavePos P= 2 20 LoadD .scene PassVar 3 S102 DynaItem E6>
		.scene <TS_XRAN_SCENE_Assassin.txt>

		GoExposition <Say 5 AddChat 6 AddChat 7 AddChat 8>

		result17 <NewChat ifNPCOK N1 else GoR17NoEnemy Say 101 History 151 XREnemy NAV_XRECharacter Goto GoEndStory>
		% Msg101 <The assassin was hired by \NARRATIVE 1 . Does that name ring any bells? The deal was made in \ELEMENT 2 .>
		Msg101 <あの暗殺者は \NARRATIVE 1 に雇われていました。その名に思い当たることはありませんか？暗殺の依頼は \ELEMENT 2 で行われたようです。>
		% Msg151 <You discovered the assassin was hired by \NARRATIVE 1 .>
		Msg151 <暗殺者は \NARRATIVE 1 に雇われたことが分かった。>

		GoR17NoEnemy <ifFaction N2 else GoSetFaction Goto GoFinishFaction>
		GoSetFaction <N= 2 E5 Goto GoFinishFaction>
		GoFinishFaction <Say 201 History 251 XREnemy NAV_XREFaction Goto GoEndStory>
		% Msg201 <The assassin was hired by \NARRATIVE 2 . You apparently have some very powerful enemies... any idea why? The deal was made in \ELEMENT 2 .>
		Msg201 <あの暗殺者は \NARRATIVE 2 に雇われていました。あなたは強大な相手を敵に回しているようですが…心当たりはありますか？暗殺の依頼は \ELEMENT 2 で行われたようです。>
		% Msg251 <You discovered the assassin was hired by \NARRATIVE 2 .>
		Msg251 <暗殺者は \NARRATIVE 2 に雇われたことが分かった。>

		GoEndStory <S= 101 1 S+ 102 1 S= 105 1 N= 3 E2 AdvancePlot 0>

		% Msg1 <I saw what happened just then... I think the person who attacked you was a hired killer belonging to a gang that I'm investigating.>
		Msg1 <私はちょうどその時現場を目撃しました…。あなたを襲った人物は私が捜査中の一味に所属する殺し屋だと思われます。>
		% Msg2 <Don't be stupid. I saw it myself. This gang has done a number of contract killings in the past. I want to end their business, and hopefully find out who their boss is. I'd like for you to help me, if you can.>
		Msg2 <何を言っているのですか。私はこの目で見たのです。今回の一味は過去に多くの殺人依頼を果たしてきました。奴らの商売に終止符を打ち、できれば奴らの黒幕の正体をつかみたいと思っています。よければ私に協力してください。>
		% Msg3 <Yes, as a matter of fact I am. This gang has been offing people for money... I wouldn't call them "assassins", they aren't exactly subtle. I've got a plan to end their operation and hopefully find out who they're working for.>
		Msg3 <はい、実はその通りです。今回の一味は金のために何人も殺しています…。私は奴らを「暗殺団」とは呼びません。奴らの仕事ぶりは巧妙とは言えませんから。奴らの活動を終わらせ、できれば奴らが誰の下で働いているのかを明らかにしようと思います。>
		% Msg4 <Well, for starters, because someone hired them to kill you. Secondly because there's a reward available for stopping the gang. I'd like your help with stopping them, if you're able.>
		Msg4 <まあ、第一に、あなたを殺すため奴らを雇った人物がいるからです。第二に、その一味を止めてくれれば報酬が出るからです。できれば、奴らを止めるのに協力してください。>
		% Msg5 <Their base of operations is a ruin outside of town. In that base they've probably got records about who hired them and for what. The hideout is defended by mecha, though, so capturing it won't be easy.>
		Msg5 <奴らの活動基地は町の外にある遺跡です。その基地には誰が何のために奴らを雇ったのかに関する記録があると思われます。しかし、その隠れ家はメックで守られているため、そこを押さえるのは容易ではありません。>
		% Msg6 <It'd be to our mutual advantage to work together this time. I want to catch the killers, and you need to find out who wants you dead. Don't worry... I won't tell anyone you worked with me, if you don't tell that I worked with you.>
		Msg6 <今回力を合わせるのは双方にとって得になります。私はあの殺人集団を捕らえたいし、あなたは誰が自分を狙っているのかを知りたいでしょう。心配は要りません…。あなたさえ私が協力したのを言わなければ、私もあなたが協力してくれたのを言いません。>
		% Msg7 <We expect that there's about \VAL Threat N103 125 threat points worth of equipment guarding them.>
		Msg7 <奴らはおよそ \VAL Threat N103 125 ポイントの戦力を持つ軍備に守られていると思われます。>
		% Msg8 <I'm not sure that's such a good idea. First you'd need to sneak past the meks, then you'd have to avoid the guards and locate the records. Our informant said that they have a secret defense against intruders, but he didn't elaborate.>
		Msg8 <それはあまりいい考えとはいえません。まずメックの間を通り抜け、次に守衛を避けながら証拠のありかを突き止めなければなりません。情報提供者によれば、奴らは侵入対策に極秘の防御態勢を取っているそうですが、彼も詳しいことは言いませんでした。>
		% Msg9 <Suit yourself. I will continue working on the case by myself.>
		Msg9 <嫌なら結構です。私は独りでもこの事件に取り組み続けますから。>
		% Msg10 <That's a good idea. We can get the mission started right away, or you can go check your supplies before we begin.>
		Msg10 <それはいい考えです。すぐに作戦を開始しましょうか？それともその前に物資を確認しに行きますか？>
		% Msg11 <If you want to, you're welcome to try. I'd advise you to take the story of their security system very seriously though. Are you ready to head out?>
		Msg11 <あなたがそうしたいのなら、やってみても構いませんよ。しかし奴らの警備システムの話は真剣に受け止めてください。出発の準備はできましたか？>
		% Msg12 <Make sure your gear is in top condition, then head back here and we'll begin the mission.>
		Msg12 <装備を万全にしてから、ここへ戻ってきてください。そうすれば作戦を開始しましょう。>
		% Msg13 <\ELEMENT 4 in \SCENE EScene 4 is investigating the crime gang that was hired to kill you.>
		Msg13 <\SCENE EScene 4 の \ELEMENT 4 は \PC を殺すために雇われた犯罪集団を捜査している。>
		% Msg14 <Very good. Would you like to get started right away, or do you need to go check your gear first?>
		Msg14 <ありがとうございます。すぐに始めますか？それともまずは装備を確認しに行きますか？>
		% Msg15 <I'm still investigating that gang who tried to kill you... and I could still use some help.>
		Msg15 <今も私はあなたの命を狙っている一味を捜査しています…そして今も手を借りたいと思っています。>
		% Msg16 <Here are the coordinates of the hideout. You'll probably find the data we're after on a computer of some type.>
		Msg16 <こちらがその隠れ家の正確な位置です。我々の求める情報は何らかの型のコンピュータで見つかるでしょう。>
		% Msg17 <Wow, that didn't go as well as it could have. Good to see that you made it back in one piece, though... Go get some rest and we'll try again tomorrow.>
		Msg17 <はあ、期待通りにはいきませんでしたね。しかし、あなたが五体満足で帰ってきたことが分かっただけでもよしとしましょう…。休息を取ってきなさい。明日再挑戦しましょう。>
		% Msg18 <You can try your skill against the crime gang again tomorrow. Right now I've got paperwork to complete.>
		Msg18 <明日またあの犯罪集団に腕試しをしましょう。今は片付けなければならない書類仕事がありますので。>
		% Msg19 <Good work. Thanks to you, we didn't have to risk destroying evidence in a mecha battle. I've analyzed the file that you recovered... Want to hear what I've found?>
		Msg19 <よくやってくれました。あなたのおかげで、我々はメックによる戦闘中に証拠を破壊してしまう危険を冒さずに済みました。私はあなたの回収した資料を分析しています…。分かったことを聞きたいですか？>
		% Msg20 <Good work. With their mecha force disabled, our patrolmen managed to seize the compound and retrieve vital data files. Want to hear what we've learned?>
		Msg20 <よくやってくれました。敵メック部隊が倒され、警官隊は証拠品を押収し決定的な資料を回収できました。何が分かったか聞きたいですか？>
		% Msg21 <Here are the deployment coordinates. Smash their resistance, and our patrol troops can easily take the hideout. Good luck.>
		Msg21 <こちらが敵部隊の展開位置です。奴らの抵抗を打ち破ってください。そうすれば警官隊は容易にその隠れ家を押さえられます。幸運を祈ります。>

		% Prompt1 <I don't know what you're talking about...>
		Prompt1 <何の話だか分からないな…。>
		% Prompt2 <Are you looking for some help with the case?>
		Prompt2 <この事件への協力を求めているのかい？>
		% Prompt3 <Why should I care?>
		Prompt3 <なぜ%JFがそれを気にしないといけないのか？>
		% Prompt4 <Give me the details.>
		Prompt4 <詳細を聞こう。>
		% Prompt5 <Sorry, I don't work with cops.>
		Prompt5 <申し訳ないが、おまわりには協力しない%JG。>
		% Prompt6 <How many mecha do they have?>
		Prompt6 <奴らはどれだけのメックを持っている？>
		% Prompt7 <I can take out the meks for you.>
		Prompt7 <%JSのためにメックを追い払ってあげよう。>
		% Prompt8 <I could just sneak in and nab the records.>
		Prompt8 <%JFが基地に潜入して証拠を取って来よう。>
		% Prompt9 <Alright, tell me about your plan.>
		Prompt9 <よし、%JSの計画を教えてくれ。>
		% Prompt10 <Naah, I still don't feel like helping.>
		Prompt10 <いやいや、まだ協力する気にはなれない%JG。>

		% Prompt11 <Sounds too dangerous. Let me know if it works.>
		Prompt11 <危険すぎるよ。その戦力は実際に有効なのかい？>
		% Prompt12 <Maybe I'll just stick to the mecha action.>
		Prompt12 <%JFはメックの仕事に専念するとしよう。>
		% Prompt13 <That's a challenge! I'll do it!>
		Prompt13 <手ごたえがありそうだな！やってみよう！>
		% Prompt14 <I'm ready to go right now.>
		Prompt14 <今すぐ行ける%JG。>
		% Prompt15 <Wait, I need some time to get ready.>
		Prompt15 <待ってくれ。準備する時間が要る%JG。>
		% Prompt16 <No time like the present.>
		Prompt16 <思い立ったが吉日。早く始めよう。>
		% Prompt17 <Give me the info.>
		Prompt17 <詳しく聞こう。>

	end


end
inv
	NPC Citizen
	place <1 Ally SD>
	EquipChar 10000
	skill 1 1
	skill 2 1
	skill 3 1
	skill 4 1
	skill 5 1
	skill 6 1
	skill 7 1
	skill 8 1
	skill 9 1
	skill 10 1

	STC COMPUTER-2
	home <Data Center>
	use <Print 1 Trigger Key SELFNID>
	% Msg1 <You download the information from this computer.>
	Msg1 <このコンピュータから情報をダウンロードした。>

end
