Plot 0
	name <ARC: "Kidnapped" Conclusion 1>
	% VARIABLES USED IN PLOT
	% V2 = Combat Indicator

	% The kidnapped victim has been traced to this town.
	% They're being held in a hotel in the industrial district,
	% and are about to become a live organ donor. The PC has to
	% find the one person in town who knows where N3 is, then
	% travel to the hotel and do some rescuing action-hero style.
	%
	% Element 1 is the town this takes place in
	% Element 2 is the character who knows about N3
	% Element 3 is the girl being searched for
	% Element 4 is the prop used for E3
	Element1 <Grab 4>
	Element2 <Character !N 1>
	Element3 <Grab 3>
	Element4 <Prefab>

	% If the NPC with the clue gets killed, we're gonna need
	% a different conclusion.
	Init_Start <ifNPCOK E2 else GoDelete if= V1 0 Compose KEY E4 .usekey V= 1 1>
	start <ifNPCOK E2 else GoDelete if= V1 0 Compose KEY E4 .usekey V= 1 1>
	GoDelete <S= 101 1  AdvancePlot 0>

	.usekey <S= 201 1 V= 2 2 MoveChar E3 E1 AdvancePlot 1 DeleteKeyItem E4 Return>

	% A cleanup trigger means that the story has been deleted;
	% just get rid of this plot, then.
	CLEANUP <AdvancePlot 0>

	% Combat check. If combat has been entered, V2=1.
	NU1 <if= V2 1 if= t1 0 V= 2 2 S= 201 -1 LoseRenown AdvancePlot 2>

sub
	Persona 2
	% rumor <!2 may have seen this girl you're looking for.>
	rumor <!2 があなたの探しているこの少女を見たかもしれない>

	greeting <NewChat if= V1 0 else GoBeenBefore V= 1 d3 Say V1 AddChat 1>
	GoBeenBefore <Say V1 AddChat 1>
	result1 <EndChat Say 6 SavePos MStaged .hotelscene PCRep 6 .enemydesc  P= 2 1 DynaItemTeam E4 3 PassVar 3 E4>
	.hotelscene <TS_GSP_URB_Kidnapped_SCENE.txt>
	.enemydesc <CRIMINAL>
	% Msg1 <I think I saw the girl you're looking for! Some guy brought her to the "Golden Hotel", near the warehouse district. She didn't look too healthy. I hope she's going to be alright.>
	Msg1 <%JSが探している少女を見たことがある%JG！数人の連中がその娘を、倉庫地区近くの"Golden Hotel"に連れて行った%JG。彼女はあまり元気そうに見えなかった%JG。彼女の無事を祈っている%JG。>
	% Msg2 <You've been looking for a girl named \ELEMENT 3 , right? I think I saw her. She was brought to the "Golden Hotel" by a group of men earlier today. She looked like she was drunk or something.>
	Msg2 <%JSが探しているのは \ELEMENT 3 という名の少女だね？%JFはその娘を見たことがある%JG。今日の早い時間、彼女は男たちの集団に"Golden Hotel"へ連れて行かれた%JG。彼女は酔っているか何かしている風に見えた%JG。>
	% Msg3 <\ELEMENT 3 ? Yes, I think I may have seen this girl... She was with two men, one big muscular guy and a smaller one. I didn't get a good look at him. They were going to the "Golden Hotel".>
	Msg3 <\ELEMENT 3 ？ああ、この少女なら見たかもしれない%JG…。彼女は二人の男に付き添われていた%JG。大柄で筋肉質の男と、小柄な男。小柄な方はよく見えなかったけど。彼らは"Golden Hotel"に向かっていた%JG。>
	% Msg6 <It's over there. You can't miss it.>
	Msg6 <この向こうにある%JG。すぐに見つかるよ。>
	% Prompt1 <Show me where the hotel is.>
	Prompt1 <そのホテルの場所を教えてくれ。>

	Plot 1
		Init_Start <>
		start <if= V1 0 else GoCheckTime Time 10800  V= 1 ComTime V+ 1 86400 Print 1 ForceChat E3>
		GoCheckTime <ifG ComTime V1 AdvancePlot 0>
		% Msg1 <A few hours later, you have a chance to see how \ELEMENT 3 is recovering.>
		Msg1 <数時間経って、 \ELEMENT 3 がどのくらい回復したか見る機会を得た。>
	sub
		Persona 3
		greeting <NewChat AddReact 30 Say d3 AdvancePlot 0 XPV 100 Reputation 1 1>
		% Msg1 <Thank you for rescuing me! I'm still a bit dizzy from the drugs, but the hospital said I'm not missing anything, so I'm going to be fine.>
		Msg1 <助けてくれてありがとう！薬のせいでまだ少しめまいがするけど、病院は別状はないと言っていたから、今によくなると思う%JG。>
		% Msg2 <I thought I was going to die for sure... I'm so lucky that you came along when you did! You're a real hero.>
		Msg2 <絶対殺されると思っていた%JG…。%JSがあの時現れたのは%JFにとって幸運なことだった%JG。%JSは本当の英雄だね。>
		% Msg3 <That was terrifying... I am so grateful to you for saving my life. I'm sure that my family will be very grateful as well.>
		Msg3 <怖かった%JG…。%JFの命を救ってくれて本当に感謝している%JG。%JFの家族も本当に感謝しているはずだよ。>
	end

	Plot 2
		Init_Start <>
		start <if= V1 0 else GoCheckTime  V= 1 ComTime V+ 1 156400 News 1>
		GoCheckTime <ifG ComTime V1 AdvancePlot 0>
		% Msg1 <\PERSONA E3 , a relative of noted politician \NARRATIVE 2 , has been found murdered in \ELEMENT 1 . Evidence suggests that this is the work of organ thieves.>
		Msg1 <有名な政治家 \NARRATIVE 2 の親戚 \PERSONA E3 が \ELEMENT 1 で殺害されているのが発見された。証拠物件からするとこれは臓器泥棒のしわざのようだ。>

end
inv
	STC VICTIM-1
	use <ifG T2 0 else GoBanditsDead Print 1>
	Clue16 <Goto Use>
	Clue20 <Goto Use>
	GoCheckDie <>
	GoNoGood <>
	GoBanditsDead <Print 2 Trigger Key SelfNID>
	% Msg1 <On the bed is the body of a young woman, possibly alive, possibly not... You better deal with the rest of the kidnappers before you try to rescue her.>
	Msg1 <若い女性の身体がベッドに横たわっている。生きているかもしれないし、生きていないかもしれない…。彼女を助ける前に残りの誘拐犯を倒したほうがよさそうだ。>
	% Msg2 <You tend to the victim's wounds and call for help.>
	Msg2 <犠牲者の傷を手当てし助けを呼んだ。>
	Msg3 <>
	Msg4 <>
	Msg5 <>
	Msg6 <>
	Msg7 <>

end
