Plot 0
	name <Promotion Reward>
	% The PC has gone up a rank in the military, and will
	% now get a reward for it.

	% Element 1 is the calling faction
	% Element 2 is the character who'll give the PC the reward
	Element2 <Character !Comrade 1>

	% These are faction rewards...
	Element3 <Prefab>
	Element4 <Prefab>
	Element5 <Prefab>

	% V1 = Email Indicator

	% This plot will remain active until the PC collects his
	% reward, until the NPC dies, or until the PC is no longer
	% a member of the calling faction.
	% start <ifNPCOK E2 else GoReschedule if= PCFac E1 else GoDelete if= V1 0 Email d5 V= 1 1>
	Init_Start <ifNPCOK E2 else GoReschedule if= PCFac E1 else GoDelete if= V1 0 SetNPC E2 Email d5 V= 1 1>
	start <ifNPCOK E2 else GoReschedule if= PCFac E1 else GoDelete if= V1 0 SetNPC E2 Email d5 V= 1 1>
	GoReschedule <FacVar+ E1 1 1 AdvancePlot 0>
	GoDelete <AdvancePlot 0>

	% Msg1 <\ELEMENT 2 @ \SCENE EScene 2 :// You've earned a promotion. Come see me to accept your reward.>
	Msg1 <\ELEMENT 2 @ \SCENE EScene 2 :// 貴官は昇進した。報酬を受け取りに来たまえ。>
	% Msg2 <\ELEMENT 2 @ \SCENE EScene 2 :// I have urgent business which requires your attention at once.>
	Msg2 <\ELEMENT 2 @ \SCENE EScene 2 :// 貴官の手が直ちに必要な急を要する任務がある。>
	% Msg3 <\ELEMENT 2 @ \SCENE EScene 2 :// Report here for debriefing at once, soldier.>
	Msg3 <\ELEMENT 2 @ \SCENE EScene 2 :// 直ちに報告に来たまえ、兵士よ。>
	% Msg4 <\ELEMENT 2 @ \SCENE EScene 2 :// You have been promoted. Report here to receive your comission.>
	Msg4 <\ELEMENT 2 @ \SCENE EScene 2 :// 貴官は昇進した。任務を受けに来たまえ。>
	% Msg5 <\ELEMENT 2 @ \SCENE EScene 2 :// Your presence is required at headquarters immediately.>
	Msg5 <\ELEMENT 2 @ \SCENE EScene 2 :// 速やかに司令部へ来たまえ。>

sub
	Persona 2
	% V1 = Faction level the PC is being rewarded for.
	greeting <NewChat XPV 100 V= 1 FacVar E1 2 V+ 1 1 FacVar= E1 2 V1 AdvancePlot 0 Goto GoL0>
	GoL0 <ifG 9 V1 else GoBigLevel ifG FXPNeeded V1 PCRep 6 else GoL1 CashPrize Reward Threat FXPNeeded V1 100 250 Say 10>
	GoL1 <if= V1 1 else GoL2 Say 1 GiveKeyItem E3>
	GoL2 <if= V1 2 else GoL3 Say 2 MechaPrize .mek1>
	.mek1 <Kojedo.txt>
	GoL3 <if= V1 3 else GoL4 Say 3 CashPrize 350000>
	GoL4 <if= V1 4 else GoL5 Say 4 MechaPrize .mek2>
	.mek2 <Zerosaiko.txt>
	GoL5 <if= V1 5 else GoL6 Say 5 GiveKeyItem E4>
	GoL6 <if= V1 6 else GoL7 Say 6 PCSkill+ 1 1  PCSkill+ 2 1  PCSkill+ 3 1  PCSkill+ 4 1  PCSkill+ 5 1>
	GoL7 <if= V1 7 else GoL8 Say 7 GiveKeyItem E5>
	GoL8 <if= V1 8 else GoBigLevel Say 8 MechaPrize .mek3>
	.mek3 <Ovaknight.txt>
	GoBigLevel <Say 9 CashPrize 500000>

	% Msg1 <You have been promoted to the rank of \FacRank E1 V1 . As such, you have earned the right to wear this dress uniform. Good work, \PC .>
	Msg1 <貴官は \FacRank E1 V1 に昇進した。そこで、この制服を着る権利を授けよう。よくやったな、 \PC 。>
	% Msg2 <As you have been promoted to the rank of \FacRank E1 V1 , you will need a spare mecha. The Kojedo forms the backbone of our border patrol forces. It should serve you well.>
	Msg2 <貴官は \FacRank E1 V1 に昇進した。貴官には予備のメックが必要になるだろう。Kojedo は国境警備隊の主力をなしている。十分役立つはずだ。>
	% Msg3 <You have been promoted to the rank of \FacRank E1 V1 . To mark your new status here is a cash bonus of $350,000.>
	Msg3 <貴官は \FacRank E1 V1 に昇進した。昇進の記念に $350,000 のボーナスを用意した。>
	% Msg4 <You have been promoted to the rank of \FacRank E1 V1 . An officer needs a better mecha than you've been given before... This new Zerosaiko should fit the bill nicely.>
	Msg4 <貴官は \FacRank E1 V1 に昇進した。士官にもなるとお前が以前与えられたものより優れたメックが必要になる…。この新品 Zerosaiko ならうまく要求に適うはずだ。>
	% Msg5 <You have been promoted to the rank of \FacRank E1 V1 . As a symbol of your new station, here is a ceremonial sabre. This is more than just an ornament... you'll find that its monomolecular edge is quite deadly.>
	Msg5 <貴官は \FacRank E1 V1 に昇進した。新しい地位の象徴として、儀式用のサーベルを用意した。これはただの飾りではない…。単分子からなるその刃が非常に危険であることが分かるだろう。>
	% Msg6 <You have been promoted to the rank of \FacRank E1 V1 . You should set an example for all of our troops, and so I present you with a course of special officers training. From this moment on you should be a better pilot than before.>
	Msg6 <貴官は \FacRank E1 V1 に昇進した。貴官は全ての隊員の手本とならねばならない。そこで特別士官訓練コースを贈ろう。これから貴官は以前よりも優れたパイロットにならねばならない。>
	% Msg7 <You have been promoted to the rank of \FacRank E1 V1 . Here is a new sidearm for you to use... it's a Nova Carbine, smaller than a regular laser rifle but considerably more powerful.>
	Msg7 <貴官は \FacRank E1 V1 に昇進した。貴官に使用してもらうために新しい武器を用意した…。Nova Carbine だ。一般的なレーザーライフルよりも小型かつ相当強力だ。>
	% Msg8 <You have been promoted to the rank of \FacRank E1 V1 . You will now pilot the greatest mecha produced in the Federated Territories, the OvaKnight.>
	Msg8 <貴官は \FacRank E1 V1 に昇進した。今や貴官は連邦で生産されている中で最も優れたメック、 OvaKnight を操縦できる。>
	% Msg9 <Here is a cash reward in recognition of your dedicated service to \ELEMENT 1 .>
	Msg9 <貴官の \ELEMENT 1 に対する献身的な奉仕を認め報酬を用意した。>
	% Msg10 <You have been promoted to the rank of \FacRank E1 V1 . Here is a small cash reward in recognition of your service.>
	Msg10 <貴官は \FacRank E1 V1 に昇進した。貴官の奉仕を認め小額の報酬を用意した。>

end
inv
	BodyArmor 7
	name <Military Uniform>
	name_I18N <軍服>
	mass -11

	Melee 18
	name <Command Sabre>
	name_I18N <指揮官のサーベル>
	mass -14
	type <ArmorPiercing>
	ACC 2
	Recharge 8

	BeamGun 10
	name <Nova Carbine>
	name_I18N <ノヴァ・カービン>
	Range 5
	ACC 3
	BV 4
	Recharge 7
	Mass -7
	type <ArmorPiercing>

end
