Plot 0
	% The player has requested a job. He will perform several tasks
	% for Hogye Hospital, earning some cash and XP, then be told to
	% report to Snake Lake to see how the hospital there is doing.

	% V1 = Job Stage

	% Nurse Park
	stat 1 2
	element1 <Character>

	% Doctor Kim
	stat 2 3
	element2 <Character>

	% Nurse at Snake Lake.
	stat 3 25
	element3 <Character>

sub
	Persona 1
	% V2 -> PC Skill Roll for jobs.
	greeting <NewChat if= P1 0 else GoStage1 ifG React 25 else GoMedReact Say 1>
	GoMedReact <ifG React 5 else GoLowReact Say 2>
	GoLowReact <Say 3>

	GoStage1 <if= P1 1 else GoStage2 Say 4 AddChat 1>
	GoStage2 <if= P1 2 else GoStage3 Say 9>
	GoStage3 <if= P1 3 else GoStage4 AddChat 2 P+ 1 1 ifG React 5 else GoLowS3 Say 10>
	GoLowS3 <Say 11>
	GoStage4 <Say 12>

	% Player is attempting the repair.
	Result1 <NewChat Time 3600 P= 1 2 V= 2 SkRoll 23 ifG V2 9 else GoGR2 AddReact 7 Say 5 CashPrize 200 XPV 25>
	GoGR2 <ifG V2 6 else GoGR3 Say 6 AddReact 5 CashPrize 150 XPV 50>
	GoGR3 <ifG V2 3 else GoGR4 Say 7 AddReact 3 CashPrize 100 XPV 75>
	GoGR4 <AddReact -10 Say 8 CashPrize 50 XPV 100>

	%Msg1 <I heard that you've been offered a job here. I can't wait to start working with you! Speak with Doctor Kim; he'll tell you what to do.>
	Msg1 <あなたはここの仕事を頼まれたそうですね。 あなたと一緒に仕事をしてみたいですね！ Doctor Kim と話してください、何をすればいいか教えてくれますよ。>
	%Msg2 <Welcome to Hogye Hospital. Ask Doctor Kim about the job you've been offered. He'll explain what your duties will be.>
	Msg2 <Hogye 病院にようこそ。 頼まれた仕事について Doctor Kim と話してください。 あなたがすべきことを説明してくれるでしょう。>
	%Msg3 <You want a job here? I don't know anything about that... talk to Doctor Kim.>
	Msg3 <ここの仕事をしたいと？ 私では何とも言えません…。 Doctor Kimと話してください。>
	%Msg4 <We do all kinds of diagnostic work here at the hospital. I'm supposed to do some blood analysis, but our centrifuge is busted. Maybe you could have a look at it. I think it's a simple electrical problem.>
	Msg4 <ここ病院では様々な診断を行っています。 私は血液分析をしなければならないのですが、遠心分離機が故障しています。 見てくれませんか？ 電気系統の単純な故障だと思います。>
	%Msg5 <Wow! That was fantastic! I think the centrifuge works better now than it did when we bought it... Good job! You've earned $200 for your efforts, but I guess this was so easy for you that you probably didn't learn much.>
	Msg5 <何と！素晴らしい！ この遠心分離機は買ったときよりも調子がいいような気がします…。 よくやってくれました！ この仕事には $200 を支払います。あなたにはこの仕事は簡単すぎて学ぶところは少なかったかもしれませんね。>
	%Msg6 <Very good. The centrifuge is working again, I can get back to analyzing blood samples. Go report to Doctor Kim.>
	Msg6 <よくやってくれました。 この遠心分離機がまた動くようになったので、私は血液サンプルの分析に戻りましょう。Doctor Kim に報告してください。>
	%Msg7 <You've repaired the centrifuge. It's working well enough for me to do this blood analysis, but I think I should bring it to Quentin later so he can take a look at it. Go report to Doctor Kim.>
	Msg7 <遠心分離機は修理してもらえましたね。 この血液サンプルの分析を終わらせるくらいには使えるでしょうが、後で Quentin のところに持っていこうと思います。 Doctor Kim に報告してください。>
	%Msg8 <Argh! Please, stop doing that to my poor delicate machine! Maybe you should study some general repair before trying something like this again. I certainly hope that taking my centrifuge apart was educational... Go report to Doctor Kim.>
	Msg8 <ああ！ 私のおんぼろで繊細な機械にそんなことをしないでください！ こんなことを繰り返さないうちに、あなたは修理を学んだほうがいいですよ！ 私の遠心分離機を分解するのは勉強になるとは思いますがね…。Doctor Kim に報告してください。>
	%Msg9 <I'm busy doing blood analysis. Doctor Kim might have another task for you.>
	Msg9 <私は血液分析で手が離せません。Doctor Kim があなたに仕事を用意してくれるかもしれません。>
	%Msg10 <I know that working in this hospital isn't very exciting. Maybe if we were a big city emergency center... But, I have a job for you that should be more interesting. Supplies need to be delivered to Snake Lake. Come back in a few minutes.>
	Msg10 <この病院で働くのはあまり刺激的でないとは思います。 もしここが大都市の救急救命センターだったらあるいは…。 しかし、あなたにもっと面白そうな仕事を用意しています。Snake Lake に届けなくてはいけない物資があります。数分経ったらここへ来てください。>
	%Msg11 <Oh, it's you again. How would you like to leave here and go someplace more exciting? We've got a package of medical supplies that needs to be delivered to Snake Lake. It'll be finished in a few minutes, you can take it then.>
	Msg11 <おや、またあなたですか。 ここを出てもっと面白い場所へ行きませんか？ Snake Lake まで届けなければならない医療品の荷物があります。荷作りはすぐに終わりますので、それから持っていってください。>
	%Msg12 <The package is ready. Doctor Kim will set you up with some transportation.>
	Msg12 <荷物の準備ができました。Doctor Kim があなたに移動手段を用意してくれるでしょう。>

	%Prompt1 <[Attempt Repair]>
	Prompt1 <[修理を試みる]>


	Persona 2
	% V1 = Has met before.
	% V2 = Skill Roll
	greeting <NewChat if= P1 0 else GoStage1 if= V1 0 else GoMetBefore Say 1 AddChat 1 AddChat 2 AddChat 3 AddChat 4 AddChat 5 AddChat 6>
	GoMetBefore <Say 2 AddChat 1 AddChat 2 AddChat 3 AddChat 4 AddChat 5 AddChat 6>

	GoStage1 <if= P1 1 else GoStage2 Say 7 Time 200 AddChat 8>
	GoStage2 <if= P1 2 else GoStage3 Say 8 AddChat 7 AddChat 6>
	GoStage3 <if= P1 3 else GoStage4 Say 13 AddChat 8>
	GoStage4 <AdvancePlot 1 Say 14 MechaPrize .DocWagon AddChat 8 AddChat 9>
	.DocWagon <Renegade.txt>

	result1 <Say 5 Goto GoStartMission>
	result2 <Say 5 Goto GoStartMission>
	result3 <Say 5 Goto GoStartMission>
	result4 <Say 6 Goto GoStartMission>
	result5 <Say 6 Goto GoStartMission>
	GoStartMission <NewChat AddReact 2 P= 1 1>

	result6 <Say 3 Shop NoWares EndChat Say 4>

	% Player is checking the mycotoxosis slides.
	Result7 <NewChat Time 3600 P+ 1 1 V= 2 SkRoll 11 ifG V2 9 else GoAw2 Say 9 AddReact 5 CashPrize 200 XPV 25>
	GoAw2 <ifG V2 6 else GoAw3 Say 10 AddReact 3 CashPrize 150 XPV 50>
	GoAw3 <ifG V2 3 else GoAw4 Say 11 AddReact 1 CashPrize 100 XPV 75>
	GoAw4 <Say 12 CashPrize 50 XPV 100>

	result8 <Say 3 Shop NoWares EndChat Say 4>
	result9 <NewChat AddChat 8 Say 15>

	%Msg1 <So, Megi tells me that you're looking for a job. Very good... We could use all kinds of help here at the hospital. To start with, what would you say your major skills are?>
	Msg1 <はい、あなたが仕事を探していることは Megi から聞きました。いいでしょう…。当院は様々な手助けを必要としています。初めに、あなたの特技は何ですか？>
	%Msg2 <You haven't started on your job yet... The position is still open if you're still interested. You can earn some money and gain some experience. First I need to know, what are your skills?>
	Msg2 <あなたはまだ仕事を始めていませんね…。 もしまだやる気があるのなら、仕事はまだ空いていますよ。それでいくらかのお金と経験を得られるでしょう。まず最初に知っておきたいのですが、あなたの特技は何ですか？>
	%Msg3 <Oh, sorry, I didn't notice that you were bleeding all over the place. Where does it hurt?>
	Msg3 <おっと、申し訳ありません、あちこちから出血しているのに気が付きませんでした。 どこを怪我しましたか？>
	%Msg4 <Take care out there. It's a dangerous world.>
	Msg4 <お気をつけて。物騒な世の中ですから。>
	%Msg5 <Well, you'll probably get a chance to use your talents here. Go talk to Nurse Park about the centrifuge. The stupid thing is broken again.>
	Msg5 <では、あなたはその才能をここで活かす機会があるかもしれません。 遠心分離機のことについて、Nurse Park と話してください。 おんぼろ機械がまた壊れてしまいました。>
	%Msg6 <You probably won't get a chance to do much of that here, but well, you never can tell. Life is sort of unpredictable. I believe that Nurse Park could use your help right about now; see what you can do.>
	Msg6 <ここではそんなことをする機会はあまりないでしょうが、そう決め付けることもできません。 人生は予測不能なものですから。今なら Nurse Park があなたの手を借りたいと言うかもしれません。できる限りやってみてください。>
	%Msg7 <Go speak to Nurse Park.>
	Msg7 <Nurse Park と話してください。>
	%Msg8 <Hello. I have another task for you. It's quite simple, really. Here are some mycotoxosis test slides. I need you to check each of them, and indicate any slides which have a blue spot.>
	Msg8 <こんにちは、あなたにまた仕事があります。 本当に、とても簡単なことです。 こちらにカビ毒の実験スライドがあります。 それぞれのスライドを調べて、青い斑点のあるものを選び出してください。>

	%Msg9 <Excellent work. You have really good eyesight. We used to have a robot for sorting these tests, but you know they just don't build help like they used to.>
	Msg9 <よくやってくれました。 実にいい視力をお持ちですね。 昔はこうした実験にはロボットを使っていたものですが、そのロボットも昔ほど役には立たないのです。>
	%Msg10 <Thank you very much. Your eyesight is quite good... I ruined mine by playing too many computer games in university.>
	Msg10 <本当にありがとう。あなたの視力はかなり優れていますね…。 私は大学でコンピューターゲームをしすぎて視力が落ちてしまいました。>
	%Msg11 <That's done. Now I can tell Hyolee that all of her mutant rabbits are perfectly healthy. Thanks for helping.>
	Msg11 <それでおしまいです。 これで Hyolee さんに彼女の変異ウサギは健康そのものだと伝えることができます。ご協力感謝します。>
	%Msg12 <Are you by any chance color blind? Here, I'll finish this up myself. You might want to think about practicing your Awareness skill some time, you know.>
	Msg12 <もしかするとあなたは色盲ですか？ では、これは私が終わらせることにしましょう。あなたはいつか\NAME2 SKILLMAN Awarenessスキルを鍛えることを考える必要があるかもしれませんよ。 >

	%Msg13 <I don't need any more help right now, but I might later. Go talk to Nurse Park.>
	Msg13 <今のところ手助けは必要ありませんが、後で必要になるかもしれません。Nurse Park に話してください。>

	%Msg14 <There's a crate of medical supplies which has to be delivered to Snake Lake Hospital. Here's a car for you to travel in... I know it's a generous gift, but us doctors are loaded. Come back after you've dropped off the goods.>
	Msg14 <Snake Lake 病院に届けなければならない医療品の箱があります。 こちらがあなたに乗ってもらう車です…。大げさな贈り物だとは思いますが、でも私たち医者はお金ならいくらでもありますからね。その品を降ろしたら戻ってきてください。>
	%Msg15 <I'm not entirely sure... I'd assume that it's somewhere next to a lake, but I could be completely wrong about that. I only know Nurse \ELEMENT 3 from internet, I'm afraid.>
	Msg15 <私もあまり分かりません…。湖沿いのどこかだとは思いますが、全くの勘違いかもしれません。残念ながら、私はインターネットの情報から看護師の \ELEMENT 3 を知っているだけです。>

	%prompt1 <I'm good at Medicine.>
	prompt1 <医療が得意だ。>
	%prompt2 <I'm good at First Aid.>
	prompt2 <応急手当が得意だ。>
	%prompt3 <I'm good at Science.>
	prompt3 <科学が得意だ。>
	%prompt4 <Fighting and killing, mostly.>
	prompt4 <主に、戦闘と殺戮だ。>
	%prompt5 <Piloting giant robots.>
	prompt5 <巨大ロボットの操縦だ。>
	%prompt6 <Before that, I could use some help.>
	prompt6 <その前に、助けてくれ。>
	%prompt7 <[Begin Analysis]>
	prompt7 <[分析を始める]>
	%prompt8 <Doctor, I need medical aid.>
	prompt8 <先生、治療してくれ。>
	%prompt9 <Where is Snake Lake?>
	prompt9 <Snake Lake とはどこ？>

	Plot 1
		% Player has the crate, and will travel to Snake Lake.
	sub
		Persona 3
		greeting <NewChat Say 1 AddChat 1 AddChat 2 AddChat 3>

		result1 <NewChat Say 2 AdvancePlot 2 AddChat 4 AddChat 5 AddChat 6>
		result2 <Say 7 Shop NoWares Say 8 EndChat>
		result3 <NewChat Say 6 AddChat 1 AddChat 2>
		result4 <NewChat Say 4 Reputation 1 3 AddReact 15 AddChat 2>
		result5 <NewChat Say 5 Reputation 1 -1 Reputation 2 -4 AddReact -3 CashPrize 500>
		result6 <NewChat Say 3 Reputation 5 1 AddReact 5 AddChat 2>

		%Msg1 <Welcome to Snake Lake Hospital. How may I help you?>
		Msg1 <Snake Lake 病院へようこそ。何の用ですか？>
		%Msg2 <Great! I've been waiting for this shipment to arrive! This will help us to deal with the recent outbreak of beaver fever.>
		Msg2 <素晴らしい！この荷物が届くのをずっと待っていました！ これは最近発生しているビーバー熱に対処するのに役立つでしょう。>
		%Msg3 <You wouldn't believe how often I get that question. Bever fever is caused by a protozoan called "giardia lamblia". The main symptom of this disease is diarrhea. Beaver fever is usually spread through contaminated water; be careful.>
		Msg3 <私はその質問を何度聞いたことでしょうか。ビーバー熱は"giardia lamblia"と呼ばれる原生動物が原因です。この病気の主な症状は下痢です。ビーバー熱はふつう水を媒介として感染します。お気をつけください。>
		%Msg4 <Believe me, your work is greatly appreciated. I'm sorry that I don't have anything to offer you as a reward.>
		Msg4 <本当に、あなたの働きには感謝しています。残念ながらお礼に差し上げられるものはありませんが。>
		%Msg5 <Here's your money.>
		Msg5 <こちらがお金です。>
		%Msg6 <Well, ever since Doctor Wiseman died I've had to run this hospital by myself. It's tough keeping everything running, and there's not a lot of either time or money to spread around.>
		Msg6 <まあ、Doctor Wiseman が亡くなってからというもの私一人でこの病院を運営せざるを得なくなってしまいました。すべてをこなしていくのは大変ですし、くつろぐ時間もお金もあまりありません。>
		%Msg7 <Let me take a look at your injuries.>
		Msg7 <傷をみせてください。>
		%Msg8 <Safe journeys.>
		Msg8 <ご無事で！>

		%prompt1 <I have your supplies from Hogye.>
		prompt1 <Hogye から荷物を持ってきた%JG。>
		%prompt2 <I need medical aid.>
		prompt2 <治療してくれ。>
		%prompt3 <Why is this hospital so dusty?>
		prompt3 <なぜこの病院はこんなに埃っぽいんだ？>
		%prompt4 <I'm just glad to help.>
		prompt4 <%JSを手伝えてよかった。>
		%prompt5 <That'll be $500 for delivery.>
		prompt5 <配達料は $500 になる%JG。>
		%prompt6 <Is that a real disease?>
		prompt6 <そんな病気が本当にあるのか？>


		Plot 2
			% The player has delivered the goods, and now will
			% return to Hogye for the reward.
		sub
			Persona 2
			greeting <NewChat AddChat 1 if= V1 0 else GoMetBefore V= 1 1 Say 1 CashPrize 5000 XPV 150 AddReact 5>
			GoMetBefore <ifG PCRep 1 50 else GoMedHero Say 4 AdvancePlot 0 CashPrize 300000 XPV 250 AddReact 15>
			GoMedHero <ifG PCRep 1 25 else GoLowHero Say 5>
			GoLowHero <ifG PCRep 1 10 else GoNoHero Say 6>
			GoNoHero <ifG PCRep 1 -1 else GoVillain Say 7>
			GoVillain <Say 8>

			Result1 <Say 2 Shop NoWares Say 3 EndChat>

			%Msg1 <Thank you very much for delivering the supplies to Snake Lake! I'm afraid that \ELEMENT 3 isn't well off like us, so I like to help whenever I can. Here's some pay for your good deed. Keep helping people and they'll help you.>
			Msg1 <Snake Lake に物資を届けてくれてありがとう！ 残念ながら \ELEMENT 3 は我々のように裕福ではありませんが、私は手を貸せるときにはいつでも助けたいのです。 こちらがあなたの善行への報酬です。「情けは人のためならず」ですよ。>
			%Msg2 <Allow me to examine your wounds, and I'll have you as good as new in no time.>
			Msg2 <負傷したところを調べさせてね。そしたらすぐに君を新品同様にしてあげるから。>
			%Msg3 <See you again!>
			Msg3 <また会いましょう！>
			%Msg4 <Everybody has been talking about your heroic deeds. I told you that if you help others then they'll help you... Allow me to do just that. Here's a small gift, in honor of your virtuous nature.>
			Msg4 <あなたの英雄的な行いは皆の話の種になっていますよ。言ったでしょう？「情けは人のためならず」と…。これだけさせてください。あなたの善き心に敬意を表して、ささやかな贈り物を用意しました。 >
			%Msg5 <You've been doing a lot of good in the world, just as I thought you would. How can I help you today?>
			Msg5 <私の思っていたとおり、あなたはこの世界で多くの善行をしていますね。今日は何の用ですか？>
			%Msg6 <You're starting to get a bit of a heroic reputation. Keep on helping people, and your good deeds will come back to you.>
			Msg6 <あなたの英雄的な評判が少しずつ広まり始めましたね。他人を助け続けなさい。そうすればあなたの善行は自分に返ってきますよ。>
			%Msg7 <How can I help you today?>
			Msg7 <今日は何の用ですか？>
			%Msg8 <It's important to help people, even those who might not be deserving of your aid. What can I do for you today?>
			Msg8 <他人を助けることは大切です。たとえ助けるに値しないと思われる人でさえも。今日は何の用ですか？>

			%Prompt1 <I've been wounded.>
			Prompt1 <負傷した%JG。>
		end
	end

end
