Plot 0
	name <Sick Mission>

	% Based off the leader mission template. An NPC is injured and unable to
	% complete a mission; if the PC is willing to do so, they will get half
	% pay, salvage, and some valuable bonding with the NPC.

	% Element1 is a miscellaneous cavalier.
	element1 <Character HasMecha>

	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	%  V1 = Time Limit
	%  V2 = Combat Indicator, if V2=1 combat has been entered
	%  V3 = Email sent indicator.

	% Time limit. This plot will conclude in one day, or immediately
	% if NPC E1 is killed.
	Init_start <ifNPCOK E1 else GoDelete if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	start <ifNPCOK E1 else GoDelete if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	GoCheckTime <if= V2 0 ifG ComTime V1 AdvancePlot 0>
	GoDelete <AdvancePlot 0>

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	nu1 <if= T1 0 if= V2 1  V= 2 2  LoseRenown>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 50>

sub
	Persona 1
	% rumor <!1 was injured in battle and can't go to work.>
	rumor <!1 が戦いで怪我をして仕事に行けないらしいよ。>

	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	%  V1 = Job offer counter, V1=1 is job offered, V1=-1 if job denied
	%  V2 = Message Randomizer
	%  V3 = Threat value of enemy mecha
	%  V4 = Reward offered to PC for the mission
	%  V5 = React threshold for mission

	greeting <NewChat if= P2 3 else GoCheckLoss Say d5 BondWithChatNPC CashPrize V4 AdvancePlot 0>
	GoCheckLoss <if= P2 2 else GoCheckMission V= 2 5 V+ 2 d5 Say V2 AddReact 1 AdvancePlot 0>
	GoCheckMission <if= V1 1 else GoCheckFirst Say 101 Goto GoAddComOps>

	% The first time the PC speaks to the NPC, initialize everything.
	GoCheckFirst <if= V1 0 else GoDenied V= 1 -1 V= 3 Threat PCRep 6 100 V= 4 Reward V3 50 Goto GoMakeOffer>
	% If the PC has "the right stuff", an offer will be made immediately.
	% If not, no offer will be made at all. In the example provided
	% below, "the right stuff" is a Lawful reputation + being liked.
	GoMakeOffer  <V= 5 10 V+ 5 d20 ifG React V5 else GoNoOffer V= 2 15 V+ 2 d5 Say V2 Goto GoAddAcceptOps>

	GoAddAcceptOps <AddChat d3 V= 2 3 V+ 2 d3 AddChat V2>
	GoAddComOps <V= 2 6 V+ 2 d2 AddChat V2 V= 2 8 V+ 2 d2 AddChat V2 V= 2 10 V+ 2 d2 AddChat V2>

	GoNoOffer <Say 102 AdvancePlot 0>
	% If the mission was denied but not previously cleaned up, do
	% that now.
	GoDenied <SayAnything AdvancePlot 0>

	% PC will accept the job. Descibe the mission.
	result1 <NewChat V= 1 1 V= 2 20 V+ 2 d5 Say V2 Memo 103 Goto GoAddComOps>
	result2 <Goto Result1>
	result3 <Goto Result1>

	% PC refuses the job.
	result4 <NewChat Say 104 AdvancePlot 0>
	result5 <Goto Result4>
	result6 <Goto Result4>

	% PC will enter combat now.
	result7 <EndChat V= 2 25 V+ 2 d5 Say V2 Goto GoStartCombat>
	GoStartCombat <SavePos P= 2 1 Dynamic 2 V3 .nu1 .nu2>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Salvage Return>
	result8 <Goto result7>

	% PC will ask how many points the enemy has.
	result9 <NewChat V= 2 30 V+ 2 d5 Say V2 AddChat 7 AddChat 11>
	result10 <Goto result9>

	% PC needs some time to get ready.
	result11 <NewChat Say 105>
	result12 <Goto result11>

	% *********************
	% *** MESSAGE BLOCK ***
	% *********************

	% 01 - 05 :  Player has won the battle and is being paid.
	% Msg1 <Thanks for your help. Maybe someday I'll be able to repay you the favor.>
	Msg1 <助けてくれてありがとう。いつかこの恩返しができるといいな。>
	% Msg2 <You did it! And I'm feeling better now, too.>
	Msg2 <やったね！%JFの具合も良くなってきたよ。>
	% Msg3 <Good going, \PC .>
	Msg3 <いい感じだったよ、\PC。>
	% Msg4 <Thanks, \PC . You saved my job and maybe my life.>
	Msg4 <ありがとう、\PC。%JFのクビと、きっと命も救ってくれたね。>
	% Msg5 <Thank you! I'm starting to feel better now.>
	Msg5 <ありがとう！これで具合も良くなってきたよ。>

	% 06 - 10 :  Player has lost the battle.
	% Msg6 <Too bad... but hey, at least you made it back.>
	Msg6 <残念…でもほら、少なくとも%JSは帰ってこれたし。>
	% Msg7 <Tough luck out there, but thanks for trying.>
	Msg7 <不運だったね、でも助けようとしてくれてありがとう。>
	% Msg8 <Thanks for trying.>
	Msg8 <助けようとしてくれてありがとう。>
	% Msg9 <Wow. If you couldn't beat them, imagine how badly I would have done.>
	Msg9 <わあ。%JSでも勝てないのなら、%JFだったらどんな酷い結果になっていたことか。>
	% Msg10 <That could have went better... though it probably did go better than if I had gone myself.>
	Msg10 <もう少し何とかなれば…でも、%JFが自分でやるよりはマシな結果だったんだろうね。>

	% 16 - 20 :  Player has "the right stuff"; will be offered mission.
	% Msg16 <I've got to do a mission soon, but I got wounded in the last one and don't think I'm ready yet. I can offer you $ \VAL V4 and salvage to do this mission for me.>
	Msg16 <もうすぐ取り掛からなきゃいけない任務があるんだけど、この前ので怪我をしてまだ無理なんだ。$ \VAL V4 とサルベージ権で、%JFの代わりに引き受けてくれないか。>
	% Msg17 <I feel absolutely terrible... Could you do this mission instead of me? There's $ \VAL V4 and salvage in it for you.>
	Msg17 <本当にひどく申し訳ない…%JFの代わりにこの任務をやってくれないか？$ \VAL V4 とサルベージ権が出せるよ。>
	% Msg18 <They say these regen pills will fix you up instantly... they lie. I'm in no shape for this upcoming mission; if you'll do it for me, I can offer $ \VAL V4 and salvage.>
	Msg18 <この再生薬ですぐに直ると言われたけど…嘘だった。こんな状態では次の任務は無理だ。もし代わりに引き受けてくれたら、$ \VAL V4 とサルベージ権を出すよ。>
	% Msg19 <My doctor says I need rest, but I have to complete this mission. Can you take it instead? You can have $ \VAL V4 and salvage.>
	Msg19 <医者には安静が必要と言われたけど、この任務は達成しないといけないんだ。代わりに引き受けてくれないか？$ \VAL V4 とサルベージ権を出すよ。>
	% Msg20 <They say I shouldn't pilot anything until I stop bleeding. Could you do a mission for me? It's worth $ \VAL V4 plus salvage.>
	Msg20 <出血が止まるまで何にも乗っちゃいけないと言われたんだ。%JFの代わりにある任務を引き受けてくれないか？$ \VAL V4 とサルベージ権が得られるよ。>

	% 21 - 25 :  PC has accepted; describe the mission.
	% Msg21 <Alright, you're just gonna have to fight the enemy mecha, and that's about it, I think...>
	Msg21 <よし。単に敵のメックと戦わないといけないだけで、それだけで終わりのはずだ。たぶん…。>
	% Msg22 <There are some enemy mecha, whatever, you know how this works...>
	Msg22 <敵のメックか何かが出てくるから、どうすれば良いかは知ってるよね…。>
	% Msg23 <I think... I don't remember who you're fighting, but they're bad guys, right?>
	Msg23 <確か…どこの誰が相手なのか覚えてないな、でもきっと悪い奴らだ。そうだろう？>
	% Msg24 <Here, the details are on my phone, I'll forward them to you...>
	Msg24 <ほら、詳細は%JFの端末に入ってるから、そっちに転送しよう…。>
	% Msg25 <Uh, here's the info, you can figure it out yourself...>
	Msg25 <うん、これが詳細だから、あとは自分で把握できるよね…。>

	% 26 - 30 :  Combat is starting
	% Msg26 <Good luck. Try not to get hurt.>
	Msg26 <幸運を。怪我をしないようにね。>
	% Msg27 <I'm going to go take a nap. Wake me when you get back.>
	Msg27 <%JFは一眠りするよ。戻ってきたら起こしてくれ。>
	% Msg28 <Bye bye...>
	Msg28 <バイバイ…>
	% Msg29 <Be careful out there...>
	Msg29 <気をつけて行ってね…>
	% Msg30 <Good night... I mean good luck.>
	Msg30 <おやすみ…じゃなくて幸運を。>

	% 31 - 35 :  Describe enemy point value
	% Msg31 <I think they have \val v3 points worth of equipment? I'm not sure, I may have passed out during the briefing.>
	Msg31 <そいつらの装備は\val v3ポイント分くらいかな？自信はないよ、ブリーフィング中に気絶してたのかも。>
	% Msg32 <As far as I know you'll be facing \val v3 points worth of enemies, so you can see why you need to be in a good condition for it.>
	Msg32 <知ってる限りでは\val v3ポイント相当の敵かな、しっかり準備しないといけないって分かるだろう？>
	% Msg33 <Maybe \val v3 threat points? I'm pretty out of it on medicine right now.>
	Msg33 <たぶん\val v3ポイントくらいの脅威？今は薬で頭がはっきりしないんだ。>
	% Msg34 <The number \val v3 seems familiar... either that's their threat rating or a wild fever hallucination.>
	Msg34 <\val v3という数字に覚えが…奴らの脅威度評価か、それか熱のせいで見た幻覚かも。>
	% Msg35 <They've got \val v3 points worth of equipment.>
	Msg35 <奴らは\val v3ポイント相当の装備を持ってるよ。>


	% 101 :  Player is back from repairs, time to start mission.
	% Msg101 <Are you ready?>
	Msg101 <準備はいい？>
	% 102 :  Player doesn't have "the right stuff" for this mission.
	% Msg102 <I wish I could go back to bed... but this mecha isn't going to pilot itself.>
	Msg102 <ベッドに戻れたらなとは思うけど…メックは自分で動いてはくれないからね。>
	% 103 :  Memo
	% Msg103 <\ELEMENT 1 in \SCENE EScene 1 offered you a mission.>
	Msg103 <\SCENE EScene 1 の \ELEMENT 1 から任務を提示された。>
	% 104 :  PC didn't want the job.
	% Msg104 <That's too bad. I hope I don't pass out and die in the cockpit.>
	Msg104 <それは残念だ。コクピットの中で気絶して死なないことを期待しておこう。>
	% 105 :  PC needs time to get ready.
	% Msg105 <Do whatever you need to do, then come back here and we'll start.>
	Msg105 <必要なことを済ませて戻ってきてくれ。そしたら取り掛かろう。>

	% 01 - 03 :  PC will accept the mission.
	% Prompt1 <Sure, I can do that.>
	Prompt1 <もちろん、できるよ。>
	% Prompt2 <No problem.>
	Prompt2 <問題ない。>
	% Prompt3 <Alright, I can help you.>
	Prompt3 <分かった、手伝おう。>

	% 04 - 06 :  PC doesn't want this mission.
	% Prompt4 <Sorry, I've got my own problems.>
	Prompt4 <悪いが、%JFも問題を抱えてるんだ。>
	% Prompt5 <That's your problem, not mine.>
	Prompt5 <自分の問題だろう、%JFのじゃない。>
	% Prompt6 <Maybe someone else can do it?>
	Prompt6 <他の誰かがやってくれるかも？>

	% 07 - 08 :  Combat is starting.
	% prompt7 <I'll start that mission now.>
	prompt7 <今から任務にかかろう。>
	% prompt8 <Be back when I'm finished.>
	prompt8 <片付けたら戻ってくる。>

	% 09 - 10 :  How many points?
	% prompt9 <How many points do they have?>
	prompt9 <そいつらの戦力値は？>
	% prompt10 <What exactly am I up against?>
	prompt10 <具体的にはどんな相手と？>

	% 11 - 12 :  Just a minute...
	% prompt11 <Give me a minute to get ready.>
	prompt11 <少しだけ準備に時間が欲しい。>
	% prompt12 <I need some time first.>
	prompt12 <まずは少し時間がいる。>

end
