Plot 0
	name <Last Will>

	% Before they died, your parents left a message for you...
	% Now, a banker will contact you. When you arrive, he will
	% inform you that his office was robbed. You'll be able to
	% track the thief to E1, where you can recover the will through
	% charm, subterfuge, or force. Upon leaving town you'll be
	% attacked by mecha who demand that you turn over the will.

	% - Edited to v0.901 "light" standard

	% E1 is the scene with the bandit
	element1 <Grab 3>
	% E2 is the scene where the banker resides
	element2 <Scene Town City Target !Far 1>
	% E3 is the scene for the next episode
	element3 <Scene Town Target !Far 1 !Far 2>

	% E4 is the banker
	element4 <Prefab>

	% E5 is the bandit
	element5 <Prefab>

	% E6 is the document
	element6 <Prefab>

	% E7 is the guardian
	element7 <Character Guardian !Near 2>

	% E8 is the enemy
	element8 <Prefab>

	% V1 = Initialization Counter


	% start <ifNPCOK E4 else GoDelete if= V1 0 V= 1 1 EMail d5>
	Init_Start <ifNPCOK E4 else GoDelete if= V1 0 V= 1 1 SetNPC E4 EMail d5>
	start <ifNPCOK E4 else GoDelete if= V1 0 V= 1 1 SetNPC E4 EMail d5>
	GoDelete <S= 101 1 N= 3 E3 S= 105 -1 AdvancePlot 0>

	%Msg1 <\ELEMENT 4 @ \ELEMENT 2 :// Your parents left something for you. Come see me at the Bank of \ELEMENT 2 .>
	Msg1 <\ELEMENT 4 @ \ELEMENT 2 :// ご両親があなた宛に残された物があります。 \ELEMENT 2 の銀行までお越しください。>
	%Msg2 <\ELEMENT 4 @ \ELEMENT 2 :// You have inherited a safety deposit box from your parents. Meet me in \ELEMENT 2 to settle the estate.>
	Msg2 <\ELEMENT 4 @ \ELEMENT 2 :// あなたはご両親から貸し金庫を相続しています。遺産整理のため \ELEMENT 2 までお越しください。>
	%Msg3 <\ELEMENT 4 @ \ELEMENT 2 :// A safety deposit box left by your parents has now become yours. Collect your inheritance at the Bank of \ELEMENT 2 .>
	Msg3 <\ELEMENT 4 @ \ELEMENT 2 :// ご両親が遺された貸し金庫は現在あなたの所有となっています。 \ELEMENT 2 の銀行で相続手続きを行ってください。>
	%Msg4 <\ELEMENT 4 @ \ELEMENT 2 :// Your family's estate needs to be settled. Meet me at the Bank of \ELEMENT 2 to discuss your inheritance.>
	Msg4 <\ELEMENT 4 @ \ELEMENT 2 :// あなたのご家族の財産を整理する必要があります。相続手続きのお話がありますので \ELEMENT 2 の銀行までお越しください。>
	%Msg5 <\ELEMENT 4 @ \ELEMENT 2 :// As the executor of your parents estate I must request that you meet me in \ELEMENT 2 to discuss your inheritance.>
	Msg5 <\ELEMENT 4 @ \ELEMENT 2 :// ご両親の遺言を執り行いますので相続手続きのお話をしに \ELEMENT 2 までお越しください。>

sub
	Persona 4
	%rumor <!4 has been waiting for you.>
	rumor <!4 があなたを待っている>
	greeting <NewChat Say 1 AddCHat 1 AddChat 2>
	result1 <NewChat Say 2 N= 3 E3 History 3 XRBadThing NAV_XRBResolved FreezeChar E5 FreezeChar E8 AdvancePlot 1 AddChat 3>
	result2 <Reputation 2 -d10 Reputation 5 d10 Goto result1>
	result3 <NewChat Say 4>
	%Msg1 <Ah, \PC . It was so sad what happened to your parents. As the executor of their will it is my duty to present you with your inheritance, but I'm afraid there is a small problem...>
	Msg1 <ああ、 \PC 。あなたのご両親のことをお悔やみ申し上げます。ご両親の遺言執行者としてあなたに遺産をお渡しします。しかし、残念ながら少々問題があります…。>
	%Msg2 <Earlier today the bank was robbed by \ELEMENT 5 , famed international jewel thief. Your parent's safety deposit box was one of the items which was stolen.>
	Msg2 <今日の未明、銀行が有名な宝石泥棒 \ELEMENT 5 に襲われました。盗まれた物品の中にあなたの御両親の貸し金庫が含まれているのです。>
	%Msg3 <Your inheritance was stolen by famed theif \ELEMENT 5 .>
	Msg3 <遺産が有名な国際的盗賊 \ELEMENT 5 に盗まれた。>
	%Msg4 <The guardians are working on the case right now. Of course, since \ELEMENT 5 has never been caught, I'm not too hopeful that your goods will be recovered.>
	Msg4 <現在Guardiansがこの事件を捜査しています。 \ELEMENT 5 が逮捕されたことはもちろんありませんから、あなたの遺産が戻ってくるとはあまり考えられません。>
	%Prompt1 <What kind of problem?>
	Prompt1 <どういった問題が？>
	%Prompt2 <Where's my money!?>
	Prompt2 <%JFのお金はどこへ！？>
	%Prompt3 <I have to get that box back!>
	Prompt3 <取り返さなくては！>

Plot 1
	% The PC's stuff has been stolen. Now, the PC needs to locate
	% the thief and get his inheritance back...
	% V1 = Initialization Counter
	% V2 = Have spoken with E5

	Init_Start <ifitemOK E6 else GoDelete if= V1 0 V= 1 1 MoveChar E5 E1 ItemVar= E6 1 E3 Compose KEY E6 .usekey Memo 2 ifNPCOK N1 else GoN1Dead DeleteCHar E8 E= 8 N1>
	start <ifitemOK E6 else GoDelete if= V1 0 V= 1 1 MoveChar E5 E1 ItemVar= E6 1 E3 Compose KEY E6 .usekey Memo 2 ifNPCOK N1 else GoN1Dead DeleteCHar E8 E= 8 N1>
	GoN1Dead <N= 1 E8>
	.usekey <History 1 S= 101 1 N= 3 E3 S= 105 1 XRMystery NAV_XRMItem AdvancePlot 2>
	GoDelete <S= 101 1 N= 3 E3 S= 105 -1 AdvancePlot 0>

	%Msg1 <You learned that your family duty is to protect a dark secret.>
	Msg1 <自分が秘密の知識を守る一族であることを知った。>
	%Msg2 <Your parents safety deposit box was stolen by famed theif \ELEMENT 5 .>
	Msg2 <両親の貸し金庫が有名な盗賊の \ELEMENT 5 に盗まれた。>

sub
	Persona 4
	greeting <NewChat Say 1>
	%Msg1 <The guardians are still trying to capture \ELEMENT 5 , but all of the stolen money has probably been spent by now...>
	Msg1 <Guardiansはいまだ \ELEMENT 5 の捜索を行っています。しかし、今となっては盗まれた金はすべて使われてしまったでしょう…。>

	Persona 5
	% V1 = Initialization Counter
	% V3 = Needed cash
	greeting <NewChat V= 3 Threat S103 15 ifItemOK E6 else GoDestroyed if= V1 2 else GoCheckHas SayAnything>
	GoCheckHas <ifKeyItem E6 else GoCheckDeal SayAnything>
	GoCheckDeal <if= V1 1 else GoFirstTime Say 10 AddChat 8 Memo 9 ifG PC$ V3 else GoNoMoney AddChat 10>
	GoDestroyed <SayAnything>
	GoFirstTime <P= 2 1 Say 1 AddChat 1 AddChat 2 AddChat 3>
	result1 <NewChat V= 1 1 AddReact d15 Say 2 AddChat 4 AddChat 5>
	result2 <NewChat V= 1 1 Say 3 AddChat 6 AddChat 7>
	result3 <NewChat V= 1 1 Reputation 4 -d10 Reputation 2 1 Say 4 AddChat 4 AddChat 5>
	result4 <NewChat Say 5 AddChat 6 AddChat 7>
	result5 <EndChat Print 7 Say 6 Reputation 4 -d8 RunAway E5>
	result6 <NewChat Say 8 Memo 9 AddChat 8 ifG PC$ V3 else GoNoMoney AddChat 10>
	GoNoMoney <AddChat 9>
	result7 <NewChat Say 11>
	result8 <EndChat Print 7 Say 12 Reputation 4 -d8 RunAway E5>
	result9 <NewChat Say 13>
	result10 <NewChat CASH+ -V3 Say 14 History 21 Memo 0 GiveKeyItem E6 V= 1 2 AddChat 11 AddChat 12 AddChat 13>
	result11 <NewChat Reputation 3 -d8 ifG 0 PCRep 3 else GoR11NoAlly Say 15 PCAlly E5>
	GoR11NoAlly <Say 16>
	result12 <NewChat Reputation 5 d8 ifG PCRep 5 0 else GoR12NoAlly Say 17 PCAlly E5>
	GoR12NoAlly <Say 18>
	result13 <NewChat Reputation 4 -d8 ifG 0 PCRep 4 else GoR13NoAlly Say 19 PCAlly E5>
	GoR13NoAlly <Say 20>
	%Msg1 <This is the life, enjoying the splendors of \ELEMENT 1 as only someone with copious amounts of money can... Still, it will soon be time to move on.>
	Msg1 <大金持ちしかできないような \ELEMENT 1 の贅沢を満喫するのは最高だね…。 でも、そろそろこの町を出ないとな。>
	%Msg2 <As a matter of fact, I am. And you might be, who, exactly? One of my adoring fans? No, I sense that you want something... Well, what is it?>
	Msg2 <実は、その通り。それで君は一体誰かな？ 私の熱烈なファン？ いや、何か私に用があるようだね…。さて、何の用だい？>
	%Msg3 <Honestly, just about everything I've ever stolen belonged to someone else at one point in time. I'll explain what I'm going to do... As a businessman, I need to cover my expenses. I'll sell you back whatever it is you want for market value.>
	Msg3 <本当のことを言えば、私がこれまで盗んできたものはほぼすべて、ある時点に於いては誰か他の人物の所有物だったね。私の要求を言おう…。私は商売人だから、経費をまかなわなければならない。市場価格で買ってくれるなら何でも売ってあげよう。>
	%Msg4 <Oh no, not this old game again... Is that why you're really here? You look like there's something else you're after. If you were really that concerned about law and order you'd be after a murderer or another violent criminal instead of me.>
	Msg4 <ふう、そんなのはもううんざりだよ…。君がここに来た本当の理由は何だい？ 他に目的があるようだね。本当に法や秩序に関心があるなら、私ではなく殺人犯やその他の凶悪犯を追うべきだろう。>
	%Msg5 <Well that's a simple matter to fix. I'm a businessman. Whatever it is that you want, I can sell it back to you at its market value. Not many thieves would be that fair, would they?>
	Msg5 <そうかい、それなら簡単なことさ。私は商売人だからね。君が欲しい物は何でも、市場価格で売ってあげよう。こんな公正な泥棒はあまりいないだろう？>
	%Msg6 <Not this time. Come back when you're ready to negotiate sensibly.>
	Msg6 <今回は無理だね。賢い交渉ができるようになってから来るんだな。>
	%Msg7 <\ELEMENT 5 drops a smoke bomb, and suddenly is gone!>
	Msg7 <\ELEMENT 5 は煙幕を張り、突如消え去った！>
	%Msg8 <I haven't looked inside your security deposit box to see what's in there, but a standard fee for this sort of item is $ \VAL V3 . That sounds reasonable, doesn't it?>
	Msg8 <私は君の貸し金庫の中身を見ていないけど、この類の物の標準価格は $ \VAL V3 になるね。妥当な値段だろう？>
	%Msg9 <\ELEMENT 5 in \ELEMENT 1 will sell you your parents security box for $ \VAL V3 .>
	Msg9 <\ELEMENT 1 の \ELEMENT 5 は \PC の両親の貸し金庫を $ \VAL V3 で売ると言っている。>
	%Msg10 <Are you ready to deal? I've got something you want, and it can be yours for the low low price of $ \VAL V3 .>
	Msg10 <取引きできるかい？ 私は君の望む物を持っていて、それがわずかたったの $ \VAL V3 で君の物になるんだよ。>
	% Msg11 <What choice do you have in the matter? I'm quite serious. Come back when you are too.>
	Msg11 <君はこの取引きをどうしたいんだ？ 私は真剣そのものだよ。君も真剣に取引きする気になったらまた来るんだな。>
	%Msg12 <You could try... but I don't think you could catch me.>
	Msg12 <そうしてくれても構わないよ…君は私を捕まえられないだろうがね。>
	%Msg13 <See you later, then.>
	Msg13 <それなら、またな。>
	%Msg14 <It's been a pleasure doing business with you. Tell me, since I'm curious... What's in the box? It must be pretty valuable for you to go through all this trouble, mustn't it?>
	Msg14 <君と取引きができて楽しかったよ。興味本位で聞くが…。箱の中身は何だい？ 君がここまでするからには、相当貴重な物なんだろうな？>
	%Msg15 <Ah, the mysterious type... Well, I appreciate your business. I might just see you around sometime.>
	Msg15 <おや、わけありだね…。まあ、君と取引きできて嬉しいよ。いつかは君と一緒に行こうかな。>
	%Msg16 <Ah, playing mysterious... Well, I hope you got your money's worth.>
	Msg16 <おや、わけありだね…。まあ、代金分の価値があるといいね。>
	%Msg17 <You mean, you did all that and you don't even know what's in the box!? Wow, and I thought I was a risk-taker. You seem like a fun sort... I might just see you around sometime.>
	Msg17 <つまり、君は箱の中身も知らないのにあれほどの金額を払ったのかい！？ 何とまあ、君は冒険家だね。面白い奴だな…。いつかは君と一緒に行こうかな。>
	%Msg18 <You mean, you did all that and you don't even know what's in the box!? I hope you got your money's worth...>
	Msg18 <つまり、君は箱の中身も知らないのにあれほどの金額を払ったのかい！？ 代金分の価値があるといいね…。>
	%Msg19 <You did all that just because of its personal significance? You certainly seem to be the spirited sort... I might just see you around sometime.>
	Msg19 <自分にとって深い意味があるものだからというだけであれほどの金額を払ったのかい？ 君は熱い人のようだね…。いつかは君と一緒に行こうかな。>
	%Msg20 <It better have deep significance, considering what you paid for it. I hope you got your money's worth...>
	Msg20 <君がそれに払った金額を考えると、それにはきっと深い意味があるんだろうね。代金分の価値があるといいね…。>
	%Msg21 <You bought your parents letter from \ELEMENT 5 for $ \VAL V3 .>
	Msg21 <\ELEMENT 5 から両親の手紙を $ \VAL V3 で買い取った。>
	%Prompt1 <Aren't you \ELEMENT 5 the famous thief?>
	Prompt1 <%JSは有名な盗賊の \ELEMENT 5 だな？>
	%Prompt2 <You have something that belongs to me.>
	Prompt2 <%JSは%JFの物を持っているはずだ。>
	%Prompt3 <I'm here to arrest you, you crook!>
	Prompt3 <逮捕しに来たぞ、悪党！>
	%Prompt4 <I need to get back something you stole.>
	Prompt4 <%JSが盗んだ物を取り戻したい%JG。>
	%Prompt5 <I will end your life of crime right now!>
	Prompt5 <今すぐ%JSの犯罪人生を終わらせてやる！>
	%Prompt6 <It's a deal.>
	Prompt6 <取引きしよう。>
	%Prompt7 <You've got to be joking...>
	Prompt7 <ご冗談を…。>
	%Prompt8 <Maybe I'll just take it back!>
	Prompt8 <ただ取り返すだけさ！>
	%Prompt9 <Be back when I have the money.>
	Prompt9 <お金ができたら戻って来るよ。>
	%Prompt10 <Here you go. [give cash]>
	Prompt10 <どうぞ。[金を渡す]>
	%Prompt11 <That's not for you to know.>
	Prompt11 <%JSの知ったことじゃない%JG。>
	%Prompt12 <I'll find out when I open the box!>
	Prompt12 <箱を開けてみないと分からないよ！>
	%Prompt13 <It has deep personal significance.>
	Prompt13 <%JFにとっては深い意味があるものなんだ。>


	Persona 7
	%rumor <!7 is investigating a bank robbery.>
	rumor <!7 は銀行強盗事件を捜査している>
	greeting <NewChat if= P2 1 else GoCheckIntro Say 5 AddChat 3>
	GoCheckIntro <if= V1 0 else GoBeenBefore Say 1 AddChat 1 AddChat 2>
	GoBeenBefore <SayAnything>
	result1 <NewChat V= 1 1 Memo 2 Say 3 Reputation 2 1>
	result2 <NewChat V= 1 1 Memo 2 Say 4>
	result3 <NewChat Say 6>
	%Msg1 <I heard you lost some money in that bank robbery... Well, so did a bunch of other people. I'll try hard to catch \ELEMENT 5 !>
	Msg1 <あなたは銀行強盗にお金を取られてしまったそうですね…。そう、他にも被害者はいます。私は全力で \ELEMENT 5 を逮捕するつもりです！>
	%Msg2 <\ELEMENT 5 is most likely hiding out in \ELEMENT 1 .>
	Msg2 <\ELEMENT 5 は \ELEMENT 1 に隠れている可能性が最も高い。>
	%Msg3 <No, not at the moment. The guardian office in \ELEMENT 1 is also working on the case, since we've gotten a lead that \ELEMENT 5 is taking a vacation there with \PPR E5 newfound riches.>
	Msg3 <いや、今は必要ありません。我々は \ELEMENT 5 が新たに見つけたお宝を携えて \ELEMENT 1 で休暇を取っているという手がかりをつかんだので、 \ELEMENT 1 のGuardian支部もこの事件に取り組んでいますから。>
	%Msg4 <It seems most likely that \SPR E5 is in \ELEMENT 1 ; we've gotten a tip saying that \SPR E5 's there enjoying the high life with \PPR E5 newfound riches.>
	Msg4 <\SPR E5 は \ELEMENT 1 にいる可能性が最も高いでしょう。我々は \SPR E5 が新たに見つけたお宝を携えて \ELEMENT 1 で贅沢な生活を満喫しているという情報を手に入れましたから。>
	%Msg5 <It's a busy life, being a guardian.>
	Msg5 <Guardian隊員というのは忙しい仕事です。>
	%Msg6 <You have? Well, it couldn't have happened at a worse time... We've got our hands full dealing with serious health code violations. Someone sold tainted sausages to a school cafeteria. \ELEMENT 5 will have to wait.>
	Msg6 <見つけたって？ はあ、こんな忙しいときに…。我々は重大な衛生法違反の捜査で手一杯なのです。学食に腐ったソーセージを納品した業者がありまして。 \ELEMENT 5 のことは後回しです。>
	%Prompt1 <Need any help on the case?>
	Prompt1 <この事件に協力は必要かい？>
	%Prompt2 <Any idea where \ELEMENT 5 is?>
	Prompt2 <\ELEMENT 5 の居場所は分かる？>
	%Prompt3 <I've found \ELEMENT 5 the thief!>
	Prompt3 <盗賊の \ELEMENT 5 を見つけた%JG！>

Plot 2
	% Now that the PC has read his parents last will and testament,
	% he will be attacked by those forces seeking to discover the
	% secret the next time he leaves town.

	% V1 = Forced conversation with E8
	% V2 = Combat Indicator

	Init_Start <>
	start <if= P2 1 else GoCheckWorld if= V1 0 ForceChat E8 V= 1 1>
	GoCheckWorld <if= SceneID 1 Alert 1 Block Dynamic 2 Threat S103 100 .nu1 .nu2 SavePos P= 2 1 Encounter 0 50 .nodesc History 2>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Return>

	nu1 <if= T1 0 if= V2 1  V= 2 2  LoseRenown S= 101 1 AdvancePlot 0>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 150 S= 101 1 S+ 102 1 AdvancePlot 0>

	%Msg1 <Without warning, you are attacked by mecha!>
	Msg1 <警告なしに、メックに襲われた！>
	%Msg2 <You were attacked by \ELEMENT 8 , who demanded the letter.>
	Msg2 <\ELEMENT 8 に手紙を要求され、襲われた。>

sub
	Persona 8
	% The PC's enemy.
	greeting <EndChat Say 1 AddChat 1 AddCHat 2 AddChat 3>
	result1 <EndChat Say 2 Reputation 5 d8>
	result2 <EndChat Say 3 Reputation 5 -d8>
	result3 <EndChat Say 4>
	%Msg1 <Hello \PC . You have something that belongs to me, and if you were smart you'd hand it over right now...>
	Msg1 <やあ、 \PC 。%JSは%JFの物を持っているはずだ。今すぐ%JFに渡すのが賢明だ…。>
	%Msg2 <You will pay for your insolence with your life! My men will take you to pieces!>
	Msg2 <%JSの無礼は%JSの命で償ってもらおう！ %JFの部下が%JSをバラバラにするだろう！>
	%Msg3 <That suits me perfectly well... After my men kill you, we can easily take it from your dead body.>
	Msg3 <それは%JFも同じだ…。%JFの部下が%JSを殺したら、%JSの死体から簡単に奪えるだろうよ。>
	%Msg4 <You'd do well to show more respect to your betters! Men, kill this fool, then bring his gear to me...>
	Msg4 <格上の人物にはもっと敬意を払え！ 部下たちよ、この馬鹿を殺して、奴の持ち物を取って来い…。>
	% Prompt1 <Good thing I'm not smart, then...>
	Prompt1 <それなら%JFが賢明でないのは好都合だね…。>
	%Prompt2 <I'd rather die than give it to you.>
	Prompt2 <%JSに渡すぐらいなら死んだほうがましだ。>
	%Prompt3 <Get out of my way. I have no time for you.>
	Prompt3 <どけ。%JSに構っている時間はない。>

% End PLOT 2 subs...
end

% End PLOT 1 subs...
end

% End PLOT 0 subs...
end
inv
	NPC Shopkeeper
	job <Banker>
	place <2 Pass Ally>

	NPC Soldier
	equipchar 30000
	job <Thief>
	mecha <Alba.txt>
	chardesc Chaotic Sociable Renowned
	Charm 17
	Perception 18
	Reflexes 15

	Treasure 10
	place <5>
	name <Letter from Parents>
	name_I18N <両親からの手紙>
	% V1 = Location for next episode; printed in message.
	use <TRIGGER KEY SelfNID Print 1 MoreText .text>
	.text <TS_TEXT_XRAN_LastWill.txt>
	%Msg1 <You read the letter.>
	Msg1 <手紙を読んだ。>

	NPC Mecha Pilot
	EquipChar 10000

end
