Plot 0
	% This is the big ending! Yay!
	%
	% OUTLINE SPOILERS...
	%
	%  PHASE 1 - "The Attack"
	%   - town the PC is currently in will be attacked
	%   - bombs fall every five minutes
	%   - advance to phase 2 when PC exits town
	%   - First time entering world map, print desc of enemy mecha
	%
	%  PHASE 2 - "The Excavation"
	%   - Move E2 and E3 to their scenes
	%   - When entering attacked scene, prompt for entry to combat zone
	%   - News: ENEMY has captured SCENE; military unable to proceed.
	%   - Speak with general E2 to learn more or enter combat zone
	%   - Speak with professor E3 to learn how to enter site (Clue1)
	%   - Combat Zone encounters:
	%       - First fight mecha to gain access
	%       - First time, fight encounter against GARU supersoldiers
	%       - Enter maze to find enemy or jump to last level (if Clue1)
	%   - Enemy reveals plot (if spoken to) or awakens Typhon (if killed)
	%   - Typhon awakens, cave is destroyed, PC escapes, goto Phase 3
	%
	%  PHASE 3 - "Segue to the Apocalypse"
	%   - Set PC HP to 1, SP and MP to 0
	%   - Send PC to town, force conversation with E2 (if alive)
	%   - E2 informs PC where Typhon has gone
	%   - Reveal ENEMY BASE on map
	%   - Goto phase 4
	%
	%  PHASE 4 - "Apocalypse"
	%   - if the PC enters ENEMY BASE, start the encounter
	%   - at first start of encounter, forcechat with ENEMY
	%   - ENEMY now inside Typhon, wants to control FedTer

	% E1 is the scene where the professor lives.
	Element1 <Scene Town Target>

	% E2 is the mecha pilot who appears after the attack.
	Element2 <Prefab>

	% E3 is the professor who located the weapon.
	Element3 <Prefab>

	% E4 is TYPHON
	Element4 <Prefab>

	% E5 is a spare enemy in case the PC's current enemy is dead.
	Element5 <Prefab>

	% E6 is the "attacked scene"; the value chosen here will be
	%   replaced based on what scene the PC is in.
	Element6 <Scene>


	% PHASE 1 START
	% V1 = Initialization Counter; if V1=2 bombing has started

	% At the start, check to see whether or not to advance.
	Init_Start <goto GoCheckInit>
	start <if= V1 2 else GoCheckInit if# SceneID E6 Goto GoAlertEnemy>
	GoCheckInit <if= V1 0 V= 1 1 FreezeChar E2 FreezeChar E3 FreezeChar E4 ifNPCOK N1 else GoReplaceEnemy DeleteChar E5 E= 5 N1>
	GoReplaceEnemy <FreezeChar E5>

	% Every half hour, check the location.
	% If it matches our requirements then start the bombing!
	halfhour <ifScene .scenedesc if= V1 1 if# SceneID E1 E= 6 SceneID P= 1 2 N= 3 SceneID Alert 2 AirRaidSiren Bomb>
	.scenedesc <TOWN TARGET>

	% Every 5 minutes, check to see whether or not to bomb.
	5Min <if= P1 2 if= SceneID E6 BOMB>

	% Depending on who the PC's enemy is, print a different message.
	GoAlertEnemy <if= XRE NAV_XRECharacter else GoCheckFaction Alert 101 AdvancePlot 2>
	GoCheckFaction <ifFaction N2 else GoMisc ifNPCOK N1 else GoFactionNoEnemy Alert 102 AdvancePlot 2>
	GoFactionNoEnemy <Alert 103 AdvancePlot 2>
	GoMisc <Alert 104 AdvancePlot 2>

	% Msg2 <Suddenly there is a huge explosion! In the distance you hear the sound of mecha fighting.>
	Msg2 <突然大爆発が巻き起こった！遠方にメックが戦う音を聞いた。>
	% Msg101 <As you flee town you get a look at the mecha who attacked. From among the crowd you manage to recognize \ELEMENT 5 .>
	Msg101 <町から避難すると町を襲ったメックが見えた。目を凝らすとメックの群れの中に \ELEMENT 5 を見つけた。>
	% Msg102 <As you flee town you get a look at the mecha who attacked. They bear \NARRATIVE 2 insignia, and among them you recognize \ELEMENT 5 .>
	Msg102 <町から避難すると町を襲ったメックが見えた。奴らは \NARRATIVE 2 の記章を付けており、その中に \ELEMENT 5 が確認できた。>
	% Msg103 <As you flee town you get a look at the mecha who attacked. They are marked with \NARRATIVE 2 insignia.>
	Msg103 <町から避難すると町を襲ったメックが見えた。奴らには \NARRATIVE 2 の記章が付されていた。>
	% Msg104 <As you flee town you get a look at the mecha who attacked. You have no idea who they are but it's clear that something big is about to go down.>
	Msg104 <町から避難すると町を襲ったメックが見えた。奴らが何者であるかは分からなかったが、何か大事件が起きようとしているのは明白だった。>

sub

Plot 2
	% PHASE 2 - "The Excavation"

	% V1 = Initialization Counter
	% G1003 = CLUE-1; E3 tells PC where to find E5

	Init_Start <Goto GoCheckInit>
	start <Goto GoCheckInit>
	GoCheckInit <if= V1 0 MoveChar E2 E6 MoveChar E3 E1 Compose UTD E5 .EnemyDies Compose EWM E6 .EnterScene V= 1 1 G= 1001 E6 G= 1002 E5 Goto GoSetNews>

	% If the enemy dies, better freeze him and awaken Typhon...
	.EnemyDies <FreezeChar E5 History 6 Alert 2 Alert 3 Alert 4 Exit E6 AdvancePlot 3>

	% When entering E6, prompt for entry to combat zone.
	.EnterScene <ifYesNo 201 202 203 Block Goto GoEnterCombat>

	% First the PC must fight mecha. Then he enters the ruins and
	% must first fight the GARU guards, then descend into the cave.
	GoEnterCombat <Print 1 SavePos  Dynamic 2 Threat S103 140 .NU1 .NU2>
	.NU1 <if= T1 0 Return>
	.NU2 <if= T2 0 if= V1 0 V= 1 1 Exit 46 SeekGate 1>

	GoSetNews <ifFaction N2 else GoNewsNoFaction News 101>
	GoNewsNoFaction <News 102>

	% Msg1 <As you approach the combat site, you are attacked by mecha!>
	Msg1 <戦闘地域に接近するとメックに襲われた！>

	% Msg2 <Just as you defeat \ELEMENT 5 , the ground begins to shake and the earth rips asunder!>
	Msg2 <\ELEMENT 5 を倒すと同時に地震が起こり、地面は裂けて崩れ落ちた！>
	% Msg3 <You catch a brief glimpse of something enormous rising from the depths as the cave collapses around you, then everything goes black...>
	Msg3 <周囲の洞窟が崩れている間、深淵から昇ってくる何か巨大なものがちらりと見えた。そしてすべては闇に包まれた…>
	% Msg4 <The crushing darkness surrounds you.>
	Msg4 <真っ暗闇に包まれた。>

	% Msg6 <You defeated \ELEMENT 5 in the \ELEMENT 6 ruin.>
	Msg6 < \ELEMENT 6 の廃墟で \ELEMENT 5 を倒した。>

	% Msg101 <Mecha from \NARRATIVE 2 under the command of \ELEMENT 5 have taken over part of \ELEMENT 6 . Military response hampered by presence of civilian hostages.>
	Msg101 <\ELEMENT 5 指揮下の \NARRATIVE 2 のメックは \ELEMENT 6 の一部を占拠している。市民が人質にとられているため軍は反撃できない。>
	% Msg102 <Mecha team under the command of renegade \ELEMENT 5 have taken over part of \ELEMENT 6 . Military response hampered by presence of civilian hostages.>
	Msg102 <裏切り者 \ELEMENT 5 指揮下のメック一味は \ELEMENT 6 の一部を占拠している。市民が人質にとられているため軍は反撃できない。>

	% Msg201 <Do you want to enter the city, or go to the combat zone?>
	Msg201 <町に入りますか？戦闘地域に向かいますか？>
	% Msg202 <Enter combat zone.>
	Msg202 <戦闘地域に向かう。>
	% Msg203 <Enter city.>
	Msg203 <町に入る。>

sub
	Persona 2
	% Can tell the PC the raiders came from E1,
	% and can also let the PC enter combat from here.
	% rumor <!2 has been sent to defend our town against those raiders.>
	rumor <!2 は侵略者からこの町を守るために送られてきた>
	greeting <NewChat Say 1 AddChat 1 AddChat 2 AddChat 3>
	result1 <NewChat Say 2 AddChat 2 AddChat 3>
	result2 <NewChat AddChat 1 AddCHat 3 if= XRE NAV_XREFaction else GoR2NoFac Say 3>
	GoR2NoFac <Say 4>
	result3 <NewChat Say 5 AddChat 4 AddChat 5>
	result4 <EndChat Say 6 Goto GoStartCombat>
	GoStartCombat <SavePos  Dynamic 2 Threat S103 100 .NU1 .NU2>
	.NU1 <if= T1 0 Return>
	.NU2 <if= T2 0 if= V1 0 V= 1 1 Exit 46 SeekGate 1>
	result5 <NewChat Say 7>
	% Msg1 <The raiders have been contained in the west side of town, but we can't risk the civilian casulties that would result if we tried to drive them out. They're quiet for now... best to just wait and see what they're going to do.>
	Msg1 <侵略者は町の西側で食い止めているが、もし奴らを追い出そうとするなら市民に犠牲者が出るだろう。そのような危険を冒すことはできない%JG。奴らは今は沈黙している%JG…奴らがこれからすることを眺めながらただ待つほかない%JG。>
	% Msg2 <That's something we've all been wondering. \ELEMENT 5 hasn't made any demands so far. They've stopped fighting and no reinforcements seem to be coming. They've settled into their defensive position, but for what purpose?>
	Msg2 <それこそ皆が不思議に思っていることなんだ。これまで \ELEMENT 5 は何の要求もしていない%JG。奴らは戦闘を中止したが増援も来る気配がない%JG。奴らは防衛線を張ったまま動きを見せないが、一体何が目的なんだろうか？>
	% Msg3 <Well, we believe them to be allied with \NARRATIVE 2 , but other than that we don't know a whole lot about them. Before attacking \ELEMENT 6 they came from \ELEMENT 1 , but they don't seem to have had a base there.>
	Msg3 <そうだな、奴らは \NARRATIVE 2 所属の部隊だと思う%JG。 だけどそれ以上は全く分からない%JG。奴らは \ELEMENT 6 を攻撃する前 \ELEMENT 1 からやってきたが、そこには奴らの基地はないようだね。>
	% Msg4 <Well, we don't know a whole lot about them. Before attacking \ELEMENT 6 they came from \ELEMENT 1 , but they don't seem to have had a base there.>
	Msg4 <そうだね、奴らについては皆目見当がつかない%JG。奴らは \ELEMENT 6 を攻撃する前 \ELEMENT 1 からやってきたが、そこには奴らの基地はないようだね。>
	% Msg5 <You think you could? A lone mecha could maybe break through their defenses without risking the hostages... You want to try it?>
	Msg5 <そんなことができるのか？確かに単独行動をすれば人質を危険にさらすことなく奴らの防衛線を突破できるかもしれないが…行くのか？>
	% Msg6 <I can share some of our information with you, show you where their defense is weakest... That should give you a better chance of actually breaking through. Good luck.>
	Msg6 <%JFたちの情報の一部を提供しよう。奴らの守りのどこが最も薄いか教えよう…そうすれば%JSが防衛網を突破できる可能性は少しでも高まるはず。グッド・ラック。>
	% Msg7 <If you're thinking of taking them on, you better make sure you're in top shape first. \ELEMENT 5 and the other raiders are pretty tough.>
	Msg7 <奴らを相手にしようというのなら、まず自分のコンディションがベストかどうか確かめることだ。 \ELEMENT 5 ほか侵略者たちは強敵だからね。>
	% Prompt1 <Why did they come here?>
	Prompt1 <奴らの目的は？>
	% Prompt2 <Where did they come from?>
	Prompt2 <奴らはどこから？>
	% Prompt3 <I could get them out.>
	Prompt3 <奴らを追い出してみせよう。>
	% Prompt4 <I'm ready to go.>
	Prompt4 <準備万端だ。>
	% Prompt5 <Maybe I'll try it later.>
	Prompt5 <後で取りかかろう。>

	Persona 3
	% Can tell the PC what E5 is after, and also how to get there.
	% rumor <!3 had his research files stolen.>
	rumor <!3 は研究文書を盗まれた>
	greeting <NewChat Say 1 AddChat 1 AddChat 2>
	result1 <NewChat Say 2 AddChat 3 AddChat 4>
	result2 <NewChat Say 3 AddChat 5 AddChat 6>
	result3 <NewChat Say 4 AddChat 7>
	result4 <NewChat Say 5 AddChat 7>
	result5 <NewChat Say 6 AddChat 7>
	result6 <NewChat Say 7 AddChat 7>
	result7 <NewChat Say 8 Memo 9 G= 1003 1>
	% Msg1 <My computer has been plundered and my precious research stolen! Those no-good thieving bastards took everything... No doubt they're planning to use it for no good, I bet.>
	Msg1 <コンピューターが盗まれ、貴重な研究文書が奪われてしまいました！悪どい盗っ人野郎どもは何もかもを取っていきました…奴らはきっと私の研究成果を悪用するに違いありません。>
	% Msg2 <I'm an archeologist. I was researching some PreZero ruins near \ELEMENT 6 , searching for information about the last days before the Night of Fire. Most of the records from that time were destroyed, you know. Any new data would be very helpful.>
	Msg2 <私は考古学者です。炎の夜以前で最も新しい時代についての情報を求め、 \ELEMENT 6 近くの旧紀の遺跡を調べていました。当時の記録のほとんどは失われてしまいましたから、何か新しい資料が見つかれば非常に役立つはずです。>
	% Msg3 <I can't be entirely sure, you know... this isn't exactly scientific, but... but I think it was \ELEMENT 5 who did it.>
	Msg3 <完全に確証が持てるというわけではありませんが…必ずしも科学者の仕業ではなく…犯人は \ELEMENT 5 だと思われます。>
	% Msg4 <Aside from its academic value? Oh, who am I kidding... The site I am investigating was a military complex. They may have ancient weapons there, possibly even nuclear arms, or worse...>
	Msg4 <学術的な価値を別にしてですか？おっと、冗談です…私の調査している場所は過去には軍事基地でした。当時はそこに古代兵器があったでしょう。あるいは核兵器やもっと恐ろしい兵器さえも…>
	% Msg5 <Yes, many things... nothing that you'd find interesting, I suppose, but fascinating to an expert in the field. Oh, and there were probably ancient weapons stored at the site. Maybe nuclear missiles. I guess those could be valuable.>
	Msg5 <はい、関心を惹くものがたくさん…あなたが面白いと思うものは無いかもしれませんが、考古畑の専門家には魅力的なものが見つかりますよ。あ、その場所にはおそらく古代兵器が蓄えられています。核ミサイルもあるかもしれません。そうしたものは役に立つのでは。>
	% Msg6 <Well, before my office was ransacked, \ELEMENT 5 kept coming around asking lots of questions. Now I heard about the ruckus in \ELEMENT 6 , and I worry that they're trying to access my site...>
	Msg6 <はい、私の研究室が荒らされる前、 \ELEMENT 5 がたびたび私に接触してたくさんの質問をしていたからです。今や \ELEMENT 6 での騒動のことを聞いて、彼らが例の場所に立ち入ろうとしているのではないかと気がかりです。>
	% Msg7 <Of course! But they've got their hands full right now. \ELEMENT 5 has a gang doing something horrible in \ELEMENT 6 , and I think they're trying to access my precious ruin!>
	Msg7 <もちろんですとも！しかしGuardiansは今や手一杯です。 \ELEMENT 5 は一味を \ELEMENT 6 で暴れまわらせているからです。彼らは私の大切な遺跡に立ち入ろうとしているのでしょう！>
	% Msg8 <You're in luck. Not all of my research notes were entered into the computer when my data was stolen... I can show you a shortcut through the ruins, and maybe you can beat \ELEMENT 5 to the weapons...>
	Msg8 <あなたは幸運です。資料は盗まれましたが研究文書がすべてコンピューターに入っていたわけではありません…遺跡への近道をご案内しましょう。 \ELEMENT 5 が遺跡にある兵器を手にする前に倒すことができるかもしれません…。>
	% Msg9 <\ELEMENT 3 showed you a shortcut through the \ELEMENT 6 ruins.>
	Msg9 < \ELEMENT 3 が \ELEMENT 6 の遺跡への近道を案内してくれた。>
	% Prompt1 <What kind of research?>
	Prompt1 <どんな研究？>
	% Prompt2 <Who stole it?>
	Prompt2 <誰が研究文書を盗んだ？>
	% Prompt3 <Why would anyone want to steal that?>
	Prompt3 <犯人は何のために研究文書を盗んだ？>
	% Prompt4 <Find anything interesting?>
	Prompt4 <その遺跡に何か面白いものはある？>
	% Prompt5 <Why do you think that?>
	Prompt5 <どうしてそう思うんだ？>
	% Prompt6 <Have you called the guardians?>
	Prompt6 <Guardiansを呼んだ？>
	% Prompt7 <Tell me about the research site.>
	Prompt7 <%JSが調査していた場所を教えてくれ。>

	Persona 5
	% Speaking with E5 will lead to the next phase. Killing him will
	% also work, just in case the PC is a bit trigger-happy...
	greeting <NewChat Say 1 SoloAttack E5 AddChat 1 ifG G1003 0 AddChat 2>
	result1 <EndChat Say 2>
	result2 <EndChat Say 3>
	% Msg1 <Hello, \PC . I thought you would make it here eventually... It's nice to see you one last time, but I'm afraid that you're far too late to stop us.>
	Msg1 <やあ、 \PC 。最後にはここに辿りつくと思っていたよ…最後に%JSに会えたのは嬉しいことだが、残念ながら%JFたちを止めるには遅すぎたようだね。>
	% Msg2 <What the plan is? It should be clear by now. The Federated Territories is the most powerful nation on Earth... in all of space, even... Whoever rules here shall determine the future history of the human race. That will be us!>
	Msg2 <どんな計画かって？それはこれから明らかになるさ。連邦はこの地球上で…全宇宙でさえ最も大きな権力を持つ機構だ…誰であれ連邦を支配する者は人類の未来を決定する%JG。%JFたちがそれになる%JG！>
	% Msg3 <Nuclear weapons? No, I have found something far more powerful than that. The Federated Territories is the most powerful nation on Earth. Whoever rules here shall determine the future history of the human race. That will be us!>
	Msg3 <核兵器？いや、%JFはそんなものよりずっと強力なものを見つけた%JG。連邦はこの地球上で…全宇宙でさえ最も大きな権力を持つ組織だ…誰であれ連邦を支配する者は人類の未来を決定する%JG。%JFたちがそれになる%JG！>
	% Prompt1 <Tell me what your plan is.>
	Prompt1 <%JSたちの計画とは何だ？>
	% Prompt2 <So, you've found the nuclear weapons?>
	Prompt2 <それでは、%JSは核兵器を見つけたと？>

Plot 3
	%  PHASE 3 - "Segue to the Apocalypse"
	Init_Start <>
	start <if= V1 0 else GoErrorCheck V= 1 1 Time 7200 Alert 1 ifNPCOK E2 else GoNoE2 ForceChat E2>
	GoErrorCheck <AdvancePlot 4  G= 1004 1>
	GoNoE2 <AdvancePlot 4  G= 1004 1>
	% Msg1 <You awake some time later in \ELEMENT 6 . Your body is bruised and sore but your wounds have been tended.>
	Msg1 <しばらくして \ELEMENT 6 で目が覚めた。身体は傷だらけでひりひりするが、負傷は手当てされているようだ。>

sub
	Persona 2
	greeting <NewChat Say 1 AddChat 1 AddChat 2>
	result1 <NewChat Say 2 AddChat 3 AddChat 4>
	result2 <Goto result1>
	result3 <NewChat Say 3 AdvancePlot 4 G= 1004 1>
	result4 <Goto result3>
	% Msg1 <So, you're awake, \PC . I thought we might have lost you.>
	Msg1 <ああ、目覚めたか、 \PC 。亡くなってしまったかと心配した%JG。>
	% Msg2 <A gigantic mecha or something came out of the ground. There was a cave-in and the west side of town was seriously damaged. You were found by a rescue team... You're lucky to be alive.>
	Msg2 <巨大なメックのようなものが大地から現れた%JG。地面が陥没して、町の西側はひどく被害を受けた%JG。%JSは救急隊に発見され…九死に一生を得た%JG。>
	% Msg3 <\ELEMENT 5 and the other raiders haven't been found, but the mysterious mecha was last seen heading towards Snake Lake City.>
	Msg3 < \ELEMENT 5 とその一味は見つかっていないが、最後に謎のメックが Snake Lake City に向かっているのが目撃された%JG。>
	% Prompt1 <What happened?>
	Prompt1 <何が起こったんだ？>
	% Prompt2 <I've lived through worse.>
	Prompt2 <%JFは最悪の事態を生き延びたようだな。>
	% Prompt3 <Where did the mecha go?>
	Prompt3 <そのメックはどこへ？>
	% prompt4 <What happened to \ELEMENT 5 ?>
	prompt4 < \ELEMENT 5 はどうなったんだ？>

Plot 4
	%  PHASE 3 - "Apocalypse"
	% V2 = Conversation Indicator
	% rumor <hostile mecha have set up a fortress south of Snake Lake.>
	rumor <敵対的なメック部隊が Snake Lake の南に要塞を構えている>

	Init_Start <if= G1004 0 G= 1004 1  News 3>
	start <if= G1004 0 else GoSecondStart G= 1004 1  News 3>
	GoSecondStart <ifNPCOK E4 else GoTyphonDead ifNPCInPlay E4 if= V2 0 ForceChat E5 V= 2 1>
	GoTyphonDead <Alert 1 History 2 Victory AdvancePlot 0>

	% if the PC tries to enter the enemy fortress, go to the fight instead.
	EWM47 <Block Staged .desc Threat S103 200 DynaNPC E4 3 Encounter 100 100 .x Encounter 75 100 .x Encounter 0 100 .x Encounter 0 100 .x>
	.x <ArchEnemy Villainous>
	.desc <TS_XRAN_SCENE_Ending.txt>

	% Msg1 <With Typhon and \ELEMENT 5 dead, the enemy forces were soon routed. Peace was restored to the territories.>
	Msg1 <Typhon と \ELEMENT 5 が倒れると、敵戦力はすぐに潰走した。連邦に再び平和が訪れた。>
	% Msg2 <You defeated \ELEMENT 5 and Typhon in combat.>
	Msg2 <\ELEMENT 5 と Typhon を倒した。>
	% Msg3 <A huge mecha base has appeared south of Snake Lake; all forces sent to counter this threat have been destroyed.>
	Msg3 <広大なメック基地が Snake Lake の南に現れた。この脅威に立ち向かうため送られた戦力はすべて灰燼に帰した。>

sub
	Persona 5
	greeting <Say 1 AddChat 1 AddChat 2>

	result1 <EndChat Say 2 Memo 4>
	result2 <EndChat Say 3 Memo 4>

	% Msg1 <So \PC , you survived the cave-in... Now, you will witness the dawn of humanity's new empire!>
	Msg1 <へえ、 \PC 。%JSはあの落盤を生き延びたのか…さあ、人類の新たなる帝国の夜明けを目撃するがいい！>
	% Msg2 <Killed me? That was part of my plan... it was nessecary, you see, in order for my body to bond with this new one. The spillage of blood was needed to awaken Typhon from his slumber. Now, I am Typhon!!! You will feel my power!>
	Msg2 <%JFを倒したとでも？あれも計画の内だよ…%JFの体をこの新しい体に結合させるには必要なことだったからね。Typhon を眠りから目覚めさせるには血を流さなければならなかった%JG。今や、%JFは Typhon となった！！！%JFの力を味わうがいい！>
	% Msg3 <Yes, but this time I will waste no time in killing you... Last time we met, it was necessary for my blood to be spilled, in order to awaken Typhon from his slumber and bond with him. Now, we are one!!! You will feel my power!>
	Msg3 <そうだね、しかし今回は%JSを殺すのに何秒もかからない%JG…前回会ったときのことだが、Typhon を眠りから目覚めさせてそれと合体するには、%JFの血を流さなければならなかった%JG。今や、%JFは Typhon となった！！！%JFの力を味わうがいい！>
	% Msg4 <\ELEMENT 5 bonded with the biomonster Typhon.>
	Msg4 < \ELEMENT 5 はバイオ・モンスター Typhon と結合した。>

	% Prompt1 <I killed you already!>
	Prompt1 <%JSはすでに倒したはず！>
	% Prompt2 <I thought we'd meet again...>
	Prompt2 <また会うと思っていたよ…。>


% end PHASE-4 SUB below...
end

% end PHASE-3 SUB below...
end

% end PHASE-2 SUB below...
end

% end PHASE-1 SUB below...
end
inv
	NPC Mecha Pilot
	EquipChar 50000
	chardesc Heroic

	NPC Professor
	CharDesc Old Male Shy Lawful

	Chara
	name <Typhon>
	name_I18N <Typhon>
	Scale 2
	SDL_SPRITE <monster_typhon.png>
	SDL_COLORS <240 190 170 170 112 89 0 255 0>
	statline 19 32 17 19 16 21 16 11
	% Typhon has the talent HARD AS NAILS
	NAtt 16 8 1
	% Typhon is _SERIOUSLY_ nasty... should be a really good challenge
	% for experienced players. Or so I hope. Typhon has an achilles
	% heel that Cetus didn't have... it has a body, making it possible
	% to kill Typhon by critical. The body is well-armored, though...
	% But still, aiming shots directly at the body will likely be a
	% good strategy for taking him out.
	skill 6 9
	skill 7 9
	skill 8 7
	skill 9 12
	skill 10 4
	skill 11 5
	skill 12 12
	skill 13 60
	skill 26 10
	skill 28 10
	skill 30 10
	skill 33 20
	skill 36 12
	mod Turret
	Name_I18N <砲塔>
	Armor 5
	sub
		BeamGun 3
		name <Death Wave>
		name_I18N <デスウェーブ>
		Range 9
		Acc -3
		type <HYPER OVERLOAD SWARM MYSTERY BRUTAL>
		BV 7
		recharge 3
	end
	inv
		TurretArmor 7
		Name_I18N <C7砲塔装甲>
		mass -14
	end
	Mod Body
	Name_I18N <胴部>
	Armor 10
	sub
		BeamGun 1
		name <Shining Beam>
		name_I18N <まばゆい光線>
		BV 9
		recharge 5
		range 4
		type <SWARM MYSTERY INTERCEPT>

		BeamGun 12
		name <Hellfire>
		name_I18N <地獄の劫火>
		range 6
		recharge 1
		type <BURN>
	end
	inv
		BodyArmor 10
		name <Typhon Breastplate>
		name_I18N <Typhon ブレストプレート>
		mass -20
	end
	Mod Arm
	name <Right Arm>
	name_I18N <右腕>
	Armor 7
	sub
		Hand
		Name_I18N <右手>
	end
	inv
		Shield 8
		name <Typhon Shield>
		name_I18N <Typhon シールド>
		DefBonus 2

		ArmArmor 7
		Name_I18N <C7腕部装甲>
		Mass -14
	end
	Mod Arm
	name <Left Arm>
	name_I18N <左腕>
	Armor 7
	sub
		Hand
		Name_I18N <左手>
		inv
			EMelee 14
			name <Plasma Spear>
			name_I18N <プラズマ・スピア>
			type <Thrown Return Overload Extend>
		end
	end
	inv
		ArmArmor 7
		Name_I18N <C7腕部装甲>
		Mass -14
	end
	Mod Wing
	Name_I18N <翼>
	Armor 5
	sub
		Flight 5
		Name_I18N <C5飛行ジェット>
	end
	inv
		WingArmor 7
		Name_I18N <C7翼部装甲>
		mass -14
		sub
			MLauncher 3
			range 12
			name <Acid Spore>
			name_I18N <酸の胞子>
			type <RUST SWARM>
			magazine 5
			sub
				Rockets 3
			end
		end
	end
	Mod Wing
	Name_I18N <翼>
	Armor 5
	sub
		Flight 5
		Name_I18N <C5飛行ジェット>
	end
	inv
		WingArmor 7
		Name_I18N <C7翼部装甲>
		mass -14
		sub
			MLauncher 3
			range 12
			name <Acid Spore>
			name_I18N <酸の胞子>
			type <RUST SWARM>
			magazine 5
			sub
				Rockets 3
			end
		end
	end
	Mod Wing
	Name_I18N <翼>
	Armor 5
	sub
		Flight 5
		Name_I18N <C5飛行ジェット>
	end
	inv
		WingArmor 7
		Name_I18N <C7翼部装甲>
		mass -14
		sub
			MLauncher 3
			range 12
			name <Acid Spore>
			name_I18N <酸の胞子>
			type <RUST SWARM>
			magazine 5
			sub
				Rockets 3
			end
		end
	end
	Mod Wing
	Name_I18N <翼>
	Armor 5
	sub
		Flight 5
		Name_I18N <C5飛行ジェット>
	end
	inv
		WingArmor 7
		Name_I18N <C7翼部装甲>
		mass -14
		sub
			MLauncher 3
			range 12
			name <Acid Spore>
			name_I18N <酸の胞子>
			type <RUST SWARM>
			magazine 5
			sub
				Rockets 3
			end
		end
	end
	Mod Tail
	name <Tendril>
	name_I18N <尾>
	Armor 5
	type <EXTEND ARMORPIERCING OVERLOAD FLAIL>

	end

	% The spare enemy
	NPC Mecha Pilot
	mecha <Longman.txt>
	EquipChar 35000
	CharDesc Villainous

end
