plot 0
	name <PLOT: Ancestral Home>

	% - Edited to v0.901 "light" standard

	% E1 is the scene for the current episode.
	% E2 is the character who will give the PC a mission.
	% E3 is the scene to be used in the next episode.
	% E4 is the NPC who the PC must battle
	Element1 <Grab 3>
	Element2 <Prefab>
	Element3 <Scene Town Target !Far 1>
	Element4 <Prefab>

	% P1 = Conversation Counter
	% P2 = Combat Counter
	% P3 = Conversation with E4
	%     if P3=2, PC has resolved the matter peacefully

	% On a cleanup request just delete this plot.
	cleanup <AdvancePlot 0>

	% If Persona E2 dies, load a new plot.
	% Upon entering combat, force a conversation with the supposed enemy.
	% Init_Start <ifNPCOK E2 else GoDelete if= V1 0 if= SceneID E1 ifNPCInPlay E2 NPCGoPC E2>
	% start <ifNPCOK E2 else GoDelete if= V1 0 if= SceneID E1 ifNPCInPlay E2 NPCGoPC E2>
	Init_Start <ifNPCOK E2 else GoDelete ifNPCOK E4 else GoDelete if= V1 0 if= SceneID E1 ifNPCInPlay E2 NPCGoPC E2>
	start <ifNPCOK E2 else GoDelete ifNPCOK E4 else GoDelete if= V1 0 if= SceneID E1 ifNPCInPlay E2 NPCGoPC E2>
	GoDelete <S= 101 1 N= 3 E3 S= 105 -1  AdvancePlot 0>

	TM1 <if= SceneID E1 ifNPCinPlay E2 if= V1 0 ifG 6 Range PCUID NPCUID E2  Print 1 ForceChat E2>
	% Msg1 <\ELEMENT 2 strikes up a conversation with you.>
	Msg1 <\ELEMENT 2 が話しかけてきた。>


	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	nu1 <if= T1 0 if= V2 1  V= 2 2  LoseRenown>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  if# P3 2 XPV 100>

sub
	Persona 2
	% rumor <!2 has been researching the families that lived in this area many years ago.>
	rumor <!2 はこの地域に昔住んでいた一族について調べている>
	% V1 = Have been offered mission

	% greeting <NewChat if= P2 3 else GoCheckLoss Say 19 AdvancePlot 1 if= P3 2 else GoNoP3 MoveChar E4 E1>
	greeting <ifNPCOK E4 else GoDelete NewChat if= P2 3 else GoCheckLoss Say 19 AdvancePlot 1 if= P3 2 else GoNoP3 MoveChar E4 E1>
	GoNoP3 <History 20 DeleteChar E4>
	GoCheckLoss <if# P2 0 else GoCheckMission Say 16 V= 2 ComTime V+ 2 80000 P= 2 0>
	GoCheckMission <ifG ComTime V2 else GoRecharge if= V1 1 else GoNoMission Say 14 AddChat 13 AddChat 6 AddChat 14>
	GoNoMission <if= P1 1 else GoFirstTime Say 2 AddChat 2 AddChat 3>
	GoFirstTime <P= 1 1 Say 1 AddChat 1 AddChat 2>
	GoRecharge <Say 15>
	GoDelete <S= 101 1 N= 3 E3 S= 105 -1 AdvancePlot 0>

	result1 <NewChat Say 3 V= 1 1 Memo 7 AddChat 4>
	result2 <NewChat Say 4 Reputation 3 -d8>
	result3 <NewChat Say 5 V= 1 1 Memo 7 AddChat 4>
	result4 <NewChat Say 6 AddChat 5 AddChat 6 AddChat 7>
	result5 <NewChat Say 8 addCHAT 8 AddChat 9 AddChat 10>
	result6 <NewChat Say 9 AddChat 11 AddChat 12 AddChat 10>
	result7 <NewChat Say 10 Reputation 5 -d4>
	% result8 <EndChat Say 17 SavePos P= 2 1  Dynamic 2 Threat S103 150 .nu1 .nu2 if= d3 1 if= P3 0 DynaNPC E4 2 NPCLevel E4 S103 ComposeD START .start PassVar 1 E4>
	result8 <EndChat Say 17 SavePos P= 2 1  Dynamic 2 Threat S103 150 .nu1 .nu2 ForceExit 0 if= d3 1 if= P3 0 DynaNPC E4 2 NPCLevel E4 S103 ComposeD START .start PassVar 1 E4>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Return>
	.start <if# L1 0 ForceChat L1 L= 1 0>
	result9 <NewChat Say 11 AddChat 8 AddChat 10>
	result10 <NewChat Say 12>
	% result11 <EndChat Say 18 Reputation 1 1 SavePos P= 2 1 Dynamic 0 Threat S103 3 .nu1 .nu2 if= P3 0 DynaNPC E4 2 NPCLevel E4 S103 ComposeD START .start PassVar 1 E4>
	result11 <EndChat Say 18 Reputation 1 1 SavePos P= 2 1 Dynamic 0 Threat S103 3 .nu1 .nu2 ForceExit 0 if= P3 0 DynaNPC E4 2 NPCLevel E4 S103 ComposeD START .start PassVar 1 E4>
	result12 <NewChat Say 13 AddChat 5 AddChat 7>
	result13 <Goto result8>
	result14 <NewChat Say 12>

	% Msg1 <Excuse me, are you \PC ? I've been looking for someone of that name... I have an important message.>
	Msg1 <すみません、 \PC さんですか？私はその名前の人を探しています…。大切な伝言があるのです。>
	% Msg2 <I'm looking for someone named \PC . I've heard that they're visiting town, but I can't find them... You wouldn't know where they are, would you?>
	Msg2 <私は \PC という名の人物を探しています。この町に来ているらしいのですが、見つかりません…。どこにいるか知りませんか？>
	% Msg3 <I've been researching your family. Many years ago during the Age of Superpowers your ancestors were quite influential, and they used to live in this area. I've discovered a ruin that once was their home, but have been unable to examine it.>
	Msg3 <私はあなたの一族について調べています。昔、超大国時代あなたの祖先はかなりの勢力を占めており、この地域に住んでいました。私はかつてその一族の住んでいた遺跡を発見しましたが、調査するまではできていません。>
	% Msg4 <That's too bad. Well, I'll have to keep looking.>
	Msg4 <残念です。まあ、探し続けます。>
	% Msg5 <Really? I thought I asked you that earlier... I must have been mistaken. Anyhow, many years ago your ancestors were very influential in this region. I've discovered an old house of theirs that I'm hoping to study, but haven't been able to yet.>
	Msg5 <本当ですか？しまった、もっと早くあなたに尋ねればよかった…。ともかく、昔あなたの祖先はこの地域で非常に優勢でした。私はその一族を研究したいと思い彼らの古い住処を発見しましたが、いまだ研究できていません。>
	% Msg6 <There's a ravager tribe living on the land. I've tried to get permission to enter, but they're quite unfriendly to outsiders.>
	Msg6 <その土地には略奪者が住んでいるのです。私はその土地に入る許可を得ようとしましたが、やつらはよそものに対して敵意をむき出しにしてきます。>
	% Msg7 <\ELEMENT 2 in \ELEMENT 1 has been researching the home of your ancestors.>
	Msg7 <\ELEMENT 1 の \ELEMENT 2 は \PC の祖先の住処を調べている。>
	% Msg8 <That would be a great help! Are you prepared to head out now, or do you need to get ready?>
	Msg8 <それはとても助かります！出発の準備はもうできていますか？それとも準備が必要ですか？>
	% Msg9 <I'm not sure that's a good idea. As I mentioned, they're not very friendly to outsiders. You'd probably be attacked as soon as you got near their camp. Do you really think you have a chance of reasoning with them?>
	Msg9 <それは賢明な考えとは思えません。言ったように、やつらはよそものに対して敵意をむき出しにしてくるのですよ。あなたがやつらの村に近づくやいなや、やつらはおそらくあなたに襲いかかるでしょう。やつらを説得できると本当に思いますか？>
	% Msg10 <I was afraid of that.>
	Msg10 <そうかもしれませんね。>
	% Msg11 <I'm not in the mecha business so I can't say for certain. From what I've heard you should be able to take them, I'm certain.>
	Msg11 <私はメックで食べているわけではないので正確なことは言えません。聞いた話から察するにやつらの戦力はあなたが相手にできるくらいだと思います。>
	% Msg12 <Alright. Whenever you're ready we can start then.>
	Msg12 <分かりました。あなたの準備が済んだらいつでも出発できますよ。>
	% Msg13 <I don't think it is... There must be a safer way to handle the problem...>
	Msg13 <そのとおり…。もっと安全に問題を解決する方法があるはずです…。>
	% Msg14 <I'm waiting to investigate your family home, but the ravagers still won't let me in. Think you can help me?>
	Msg14 <私はあなたの一族の住処を調べたいと思っているのですが、いまだ略奪者が私を中に入れようとしません。助けてくれますか？>
	% Msg15 <Come back tomorrow and we can try to engage the ravagers again.>
	Msg15 <明日お越しください。また略奪者と交戦しましょう。>
	% Msg16 <You didn't manage to drive them off... Come back tomorrow and we can try again.>
	Msg16 <やつらを追い払うことはできませんでしたか…。明日お越しください。再挑戦しましょう。>
	% Msg17 <Here are the coordinates you'll have to examine. Come back here when you're done and let me know how it went.>
	Msg17 <ここがあなたの調査すべき地点です。調査が済んだらここへ帰ってきて、私に結果を知らせてください。>
	% Msg18 <You're very brave, I'll say that much... Here are the coordinates of the ruin. If you can get close to the camp, you'll probably be brought to speak with their leader.>
	Msg18 <たいそう勇敢な人ですね。私にはそれしか言えません…。ここが遺跡の位置です。村に近づくことができたなら、おそらく彼らの長から話しかけてくるでしょう。>
	% Msg19 <You cleared out the ravagers! Now I'll be able to start my explorations... Come back tomorrow or sometime; I may have some interesting finds.>
	Msg19 <略奪者を追い払ってくれましたか！やっと探索を開始できます…。明日以降にお越しください。興味深い発見があるかもしれません。>
	% Msg20 <You reclaimed your ancestral home.>
	Msg20 <祖先の住処を取り戻した。>

	% Prompt1 <I'm \PC . What do you want?>
	Prompt1 <%JFが \PC だ。何か用か？>
	% Prompt2 <I don't know who you're looking for...>
	Prompt2 <%JSが探している人物は知らない%JG…。>
	% Prompt3 <Actually, I'm \PC .>
	Prompt3 <実は、%JFが \PC だ。>
	% Prompt4 <Why not?>
	Prompt4 <どうして？>
	% Prompt5 <I can remove them for you.>
	Prompt5 <%JFがやつらを駆逐しよう。>
	% Prompt6 <Let me speak with them.>
	Prompt6 <彼らと話をさせてくれ。>
	CPrompt6 <if= P3 0 Accept>
	% Prompt7 <I guess there's nothing we can do.>
	Prompt7 <どうしようもないね。>
	% Prompt8 <I'm ready to go now.>
	Prompt8 <準備はもうできている%JG。>
	% Prompt9 <How many mecha do they have?>
	Prompt9 <奴らはどれくらいのメックを持っている？>
	% Prompt10 <Give me some time to prepare first.>
	Prompt10 <まずは準備する時間をくれ。>
	% Prompt11 <I'll go speak with them now.>
	Prompt11 <今から彼らと話し合いに行ってくる。>
	% Prompt12 <Maybe this isn't a good idea...>
	Prompt12 <もしかしたらよい考えとは言えないのかも…。>
	% Prompt13 <All ready to drive out the ravagers...>
	Prompt13 <略奪者を追い払う準備はできた%JG…。>
	% Prompt14 <I'll be back later.>
	Prompt14 <後で戻ってくる。>


	Persona 4
	% The leader of the ravagers...
	greeting <NewChat P= 3 1 Say 1 AddChat 1 AddChat 2 AddChat 3>

	result1 <NewChat ifG PCRep 6 S103 else GoR1Fail Say 2 AddChat 4 AddChat 5>
	GoR1Fail <EndChat Say 4>
	result2 <NewChat ifG PCRep 2 d30 else GoR2Fail Say 3 AddChat 6 AddChat 7>
	GoR2Fail <EndChat Say 5>
	result3 <NewChat ifG PCRep 1 d10 else GoR3Fail Say 6 AddChat 4 AddChat 5>
	GoR3Fail <EndChat Say 17>
	result4 <NewChat ifG PCRep 3 0 else GoR4Fail Say 7 P= 3 2 XPV 150 Retreat 2 History 9 History 16 PCFamily E4>
	GoR4Fail <EndChat Say 8>
	result5 <NewChat ifG 0 PCRep 3 else GoR5Fail Say 10 P= 3 2 XPV 150 Retreat 2 History 9 History 16 PCFamily E4>
	GoR5Fail <EndChat Say 11>
	result6 <NewChat ifG PC$ Threat S103 10 else GoR6Fail Say 12 Retreat 2 Cash+ -Threat S103 10>
	GoR6Fail <EndChat Say 13>
	result7 <NewChat ifG React d60 else GoR7Fail Say 15 AddChat 4 AddChat 5>
	GoR7Fail <EndChat Say 14>

	% Msg1 <This is the land of my tribe. We will destroy any who come here without permission. State your purpose here, stranger.>
	Msg1 <ここは我が部族の土地だ。我々は許可なくここへ足を踏み入れる者は誰であっても粉砕する。よそ者よ、ここへ来た目的を言え。>
	% Msg2 <This is your land? Who are you to make such an outrageous claim!?>
	Msg2 <ここはお前の土地だと？そんなけしからんことを言い張るお前は誰だ？>
	% Msg3 <Negotiate? There was another recently who wanted to visit our land... If it is so important for you to enter here, you will agree to the small price of $ \VAL Threat S103 10 .>
	Msg3 <交渉？我々の土地に入りたいというやつが最近もう一人いたな…。ここへ入ることがお前にとってそれほど大事なことならば、たった $ \VAL Threat S103 10 だけでいいから払ってもらおう。>
	% Msg4 <Don't make me laugh. You've lived a soft life in the greenzone; I can tell just by looking at you. You have no place here... you will die!>
	Msg4 <笑わせるな。お前は緑の大地でなまぬるい生活を送ってきたのだろう。見ただけで分かる。お前にやる土地はない…。死ね！>
	% Msg5 <No, you're here to steal from us... I know your kind. We won't permit you to do that!>
	Msg5 <いや、お前はここへ盗みを働きにきた…。お前のようなやつはよくいるのだ。そうはさせるか！>
	% Msg6 <Talk? Who are you to think you can simply walk in here and expect to walk out alive again!?>
	Msg6 <話？ただここへ入ってきてまた生きて出られると思っているなんて、お前は何者だ？>
	% Msg7 <\PC ? Why, of course we know you! You are of the same blood as our tribe. This is our land... Put down your arms, you are welcome here.>
	Msg7 <\PC ？なんと！もちろん知っているぞ！お前は我々と同じ血を引いているのだ。ここはお前も含めた我々の土地だ…。武器を収めよ。歓迎しよう。>
	% Msg8 <Nope, never heard of you. Now you die!!!>
	Msg8 <いや、お前の名など聞いたことはない。死ね！！！>
	% Msg9 <You reclaimed your ancestral home, and met some distant relatives.>
	Msg9 <祖先の土地を取り戻し、遠縁にあたる親戚に出会った。>
	% Msg10 <Ah, very mysterious... You must be \PC . Your adventures are known to us... In fact, you are of the same blood as our tribe! Put down your arms, you are welcome in our camp.>
	Msg10 <おお、なんと不思議なことよ…。お前は \PC に違いない。お前の冒険談は我々も知っているぞ…。実は、お前は我々と同じ血を引いているのだ！武器を収めるのだ。この村では歓迎しよう。>
	% Msg11 <How can we trust you if you don't even give your name!? You have no honor! You will die here!>
	Msg11 <名前も名乗らぬ者をどう信用しろというのだ！？恥知らずめ！ここで果てるがよい！>
	% Msg12 <Ah, money opens all doors. You are now free to explore our land... our tribe will be moving on soon anyhow.>
	Msg12 <よし、「地獄の沙汰も金次第」だ。これでお前は我々の土地を自由に歩き回れる…。とにかく我々はすぐに移動しよう。>
	% Msg13 <You don't have that kind of money! Now you will pay for wasting our time and making us disappointed!>
	Msg13 <お前にはそんな金もないのか！ならば我々の時間を無駄にし、我々をがっかりさせてくれた代償を支払ってもらおう！>
	% Msg14 <If you aren't willing to pay, then you aren't welcome here!>
	Msg14 <金を払わないのなら、ここでは歓迎されんぞ！>
	% Msg15 <You aren't willing to pay? Who do you think you are that you can just come here and expect us to let you pass freely!?>
	Msg15 <金を払いたくないと？ただここへ入ってきて我々が無料で通らせてくれるだろうと思っているなんて、お前は何者だ？>
	% Msg16 <\ELEMENT 4 the ravager chieftan is related to you.>
	Msg16 <略奪者の長 \ELEMENT 4 を親戚に持っている。>
	% Msg17 <Why should I believe that? You've only come to take what's ours! And now you will die for trespassing where you don't belong!>
	Msg17 <どうしてそう信じられる？お前は我々の物を奪いに来ただけだろう！ならば他所の土地に侵入した罪で死刑だ！>

	% Prompt1 <This is my land, and I will take it!>
	Prompt1 <ここは%JFの土地だ。だから%JFが頂く！>
	% Prompt2 <I am here to negotiate.>
	Prompt2 <交渉に来た%JG。>
	% Prompt3 <Don't shoot, I just want to talk.>
	Prompt3 <撃たないでくれ。話をしたいだけなんだ。>
	% Prompt4 <Surely you've heard of \PC !>
	Prompt4 <\PC の名を聞いたことがあるはずだ！>
	% Prompt5 <My name isn't important.>
	Prompt5 <%JFの名はどうでもいい。>
	% Prompt6 <Alright, I can give you that.>
	Prompt6 <分かった。それだけ払うよ。>
	% Prompt7 <That's too much money!>
	Prompt7 <そんなに払えないよ！>


	Plot 1
	% P1 = Initialization Counter
	Init_Start <ifNPCOK E2 else GoDelete if= V1 0 Memo 1 V= 1 1>
	start <ifNPCOK E2 else GoDelete if= V1 0 Memo 1 V= 1 1>
	GoDelete <S= 101 1 N= 3 E3 S= 105 -1 AdvancePlot 0>
	cleanup <AdvancePlot 0>
	% Msg1 <\ELEMENT 2 in \ELEMENT 1 has some information about your family history.>
	Msg1 <\ELEMENT 1 の \ELEMENT 2 は \PC の一族の歴史について知っている。>

	sub

	Persona 2
	greeting <NewChat Say 1 AddChat 1 AddChat 2>

	result1 <NewChat if= d2 1 else GoR1_2 XRMystery NAV_XRMResolved V= 2 10 V+ 2 d3 Say V2 V+ 2 5 History V2 Goto GoEndPlot>
	GoR1_2 <if# d3 1 else GoR1_3 XRMystery NAV_XRMItem V= 2 20 V+ 2 d2 sAY V2 V+ 2 5 History V2 Goto GoEndPlot>
	GoR1_3 <Say 31 History 36 Goto GoEndPlot>
	GoEndPlot <S= 101 1 S+ 102 1 N= 3 E3 S= 105 -1  AdvancePlot 0>

	result2 <NewChat Say 2>

	% Msg1 <My research at your ancestral home has finally turned up some interesting results... Would you like to hear about it?>
	Msg1 <あなたの祖先の住処を調べた末、興味深い結果がついに出ましたよ…。聞きたいですか？>
	% Msg2 <Come back when you're less busy and I can explain it all to you then.>
	Msg2 <もう少し時間のあるときに来てください。調査結果を全部お教えしましょう。>

	% Msg11 <Long ago, your family was a powerful ninja clan... but they were almost entirely wiped out by a rival clan. It's possible that the rival clan still exists, and they may not even have forgotten of this centuries-old conflict.>
	Msg11 <昔、あなたの一族は強大な忍者の一門でした…。しかし彼らは敵対する一門によりほぼ滅亡してしまいました。敵一門がまだ存続している可能性はあります。やつらはこの何世紀にもわたる争いのことを忘れてさえいないかもしれません。>
	% Msg12 <You come from a noble line. During the Age of Superpowers your ancestors ruled this area. The site I investigated was a factory to produce "Cyclops" biosoldiers. Your family must have been very powerful. They probably had a lot of enemies...>
	Msg12 <あなたは名家の血を引いています。超大国の時代にあなたの祖先はこの地域を支配したのです。私が調査した場所は「Cyclops」というバイオ兵士の生産工場でした。あなたの一族はとても強大だったにちがいありません。おそらく敵も多かったでしょう…。>
	% Msg13 <Your ancestors practiced an ancient form of martial arts. However, they were destroyed by a rival clan and scattered across the world. It's possible that this rival clan still exists.>
	Msg13 <あなたの祖先はある古代の武術を修練していました。しかし彼らは敵対する一門により滅亡し、世界中に散らばりました。この敵一門が未だ存続している可能性はあります。>

	% Msg16 <Your ancestors were ninjas whose enemies still exist today.>
	Msg16 <自分の祖先は忍者一門で、その一族を滅ぼした敵一門は現在まだ存続している。>
	% Msg17 <Your ancestors were a noble house from the Age of Superpowers.>
	Msg17 <自分の祖先は超大国の時代から続く名家だ。>
	% Msg18 <Your ancestors were martial artists whose enemies still exist.>
	Msg18 <自分の祖先は武術家一門で、その一族を滅ぼした敵一門は現在まだ存続している。>

	% Msg21 <Your ancestors came from a noble house of the Age of Superpowers. Many of them were high placed officers in the army. It's possible that your family heirlooms hold much information about this period.>
	Msg21 <あなたの祖先は超大国時代の名家出身でした。彼らの多くは軍の要職に就いていました。あなたの一族の家宝はこの時代に関する情報の宝庫かもしれません。>
	% Msg22 <In PreZero times, your ancestors were laborers. The site used to be a factory for "Cyclops" biosoldiers. One peasant stole something from the factory and the nobles burnt down the entire village, scattering your family across the globe.>
	Msg22 <旧紀の時代、あなたの祖先は労働者でした。あの場所は「Cyclops」という生物兵士の工場だったのです。ある農民がその工場に盗みに入ったため、貴族たちは村全部を焼き尽くしました。それであなたの一族は世界中に散らばったのです。>

	% Msg26 <Your ancestors were nobles, who held items of great importance.>
	Msg26 <自分の祖先は名家で、非常に重要な物を保有していた。>
	% Msg27 <You discovered that an ancestor stole something of great value.>
	Msg27 <自分の先祖が何か非常に価値のあるものを盗んだことが分かった。>

	% Msg31 <Ever hear of "Idealist"? This was a genetic engineering project during the Age of Superpowers, seeking to create a better human being. Your ancestors were "Idealists", you perhaps contain some of their modified genes.>
	Msg31 <「理想人類」について聞いたことはありませんか？これは超大国時代の遺伝子工学計画で、より優れたヒトを創りだそうという試みでした。あなたの祖先はその「理想人類」だったのです。あなたは彼らが有していた操作済みの遺伝子を一部持っているかもしれません。>
	% Msg36 <Your ancestors were genetically enhanced "Idealists".>
	Msg36 <自分の祖先は遺伝子的に強化された「理想人類」だ。>

	% Prompt1 <Tell me what you've found.>
	Prompt1 <分かったことを教えてくれ。>
	% Prompt2 <I'll listen some other time.>
	Prompt2 <別の機会に聞かせてくれ。>


	Persona 4
	greeting <NewChat Say 1>
	% Msg1 <Well met, cousin! I hope we can fight alongside one another some day.>
	Msg1 <ごきげんよう、我が親族よ！いつか共に戦えるといいな。>

	end

end
inv
	NPC Professor
	job <Archaeologist>
	Place <1 Ally Pass>

	NPC Mercenary
	job <Chieftan>
	teamdata <SD Ally>
	EquipChar 10000
	Mecha <Kojedo.txt>

end
