Plot 0
	name <Accused!>

	% - Edited to v0.901 "light" standard

	% The PC used to be a member of [ENEMY]. E2 thinks he still is, and
	% so is planning to hunt him down. The PC can fight with E2 and
	% pick up a new enemy, or can evade him and take on the secret
	% project in E3.

	% E1 is the scene for the current episode.
	% E2 is the character who will tell the PC where to go.
	% E3 is the scene to be used in the next episode.
	Element1 <Grab 3>
	Element2 <Prefab>
	Element3 <Scene Town Target !Far 1>
	Element4 <Scene Town Target !Far 1 !Far 3>
	Element5 <Prefab>

	% V1 = Combat Can Start
	% V2 = Combat Indicator
	% V3 = Forced conversation indicator

	% On a cleanup request just delete this plot.
	cleanup <AdvancePlot 0>

	% If the combat start counter has been set, and the PC enters the world map,
	% better start combat. At this point in time the NPC who starts the mission
	% becomes irrelevant.
	Init_Start <goto GoCheckPersona>
	start <if= V1 1 else GoCheckPersona if= SceneID 1 else GoCheckInTheMission Goto GoStartCombat>
	GoCheckInTheMission <if= V2 1 else GoCheckPersona if= V3 0 V= 3 1 ForceChat E2>

	% If Persona E2 dies, load a new plot.
	GoCheckPersona <ifNPCOK E2 else GoDelete>
	GoDelete <S= 101 1 AdvancePlot 0>

	GoStartCombat <Block Print 101 History 102 SavePos P= 2 1 Dynamic 2 Threat S103 140 .nu1 .nu2 NPCLevel E2 S103 DynaNPC E2 2>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Salvage Return>

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	nu1 <if= T1 0 if= V2 1  V= 2 2  LoseRenown  S= 105 -1 N= 3 E3 History 103 AdvancePlot 1>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 50 S= 101 1 S+ 102 1 S= 105 -1 N= 3 E3 PCEnemy E2 History 104 AdvancePlot 0>

	% Msg101 <While leaving town, you are attacked by \ELEMENT 2 !>
	Msg101 <町を出ようとすると、 \ELEMENT 2 が襲ってきた！>
	% Msg102 <\ELEMENT 2 confronted you because of your past affiliations.>
	Msg102 <\ELEMENT 2 が過去の因縁からあなたの行く手を阻んだ。>
	% Msg103 <You escaped from \ELEMENT 2 .>
	Msg103 <\ELEMENT 2 から逃げた。>
	% Msg104 <You defeated \ELEMENT 2 in combat.>
	Msg104 <\ELEMENT 2 を倒した。>

sub
	Persona 2
	% rumor <!2 has been looking all over for you.>
	rumor <!2 があなたを探している>
	greeting <ifG P2 0 else GoInTown EndChat Say 101 AddChat 101 AddChat 102>
	result101 <EndChat Say 102>
	result102 <EndChat Say 103>
	% Msg101 <I told you I'd be coming for you... Now that we're outside of town, we can settle things!>
	Msg101 <きっと%JSを追いつめてみせると言っていただろう…？町の外にいるからには、決着を付けようじゃないか！>
	% Msg102 <Then you had better start running, because there's no way I'm letting you escape!>
	Msg102 <それなら%JSは逃げたほうがいい。なぜなら%JFが%JSを逃がすわけはないからな！>
	% Msg103 <You will pay for all the evil you've done!>
	Msg103 <%JSはこれまで犯した悪行のつけを払うのだ！>
	% Prompt101 <I don't want to fight you.>
	Prompt101 <%JSとは戦いたくない%JG。>
	% Prompt102 <If you want to die, fine with me.>
	Prompt102 <%JSが死にたいのなら、%JFは構わない。>
	GoInTown <NewChat AddChat 1 AddChat 2 ifFaction N2 else GoCheckChara Say 1 AddChat 3>
	GoCheckChara <ifNPCOK N1 else GoUnknownEnemy Say 2 AddChat 4>
	GoUnknownEnemy <Say 3>
	result1 <NewChat Say 4  AddChat 5 AddChat 6>
	result2 <NewChat Say 5  AddChat 5 AddChat 6>
	result3 <NewChat Say 6  AddChat 5 AddChat 6>
	result4 <NewChat Say 7  AddChat 5 AddChat 6>
	result5 <EndChat Say 8 Reputation 3 -d8 Goto GoSetAmbush>
	result6 <EndChat Say 9 Reputation 3 d8  Goto GoSetAmbush>
	GoSetAmbush <FreezeChar E2 P= 1 1>
	% Msg1 <I've been looking for you, \PC ... I know what you and \NARRATIVE 2 have been planning for \ELEMENT 3 , and I won't let you get away with it!>
	Msg1 <%JSを探していた%JG、 \PC …。%JSと \NARRATIVE 2 が \ELEMENT 3 で何かをしでかそうとしていることは分かっている%JG。%JFはそれを見過ごすわけにはいかない%JG！>
	% Msg2 <I've been looking for you, \PC ... I know what you and \NARRATIVE 1 have been planning for \ELEMENT 3 , and I won't let you get away with it!>
	Msg2 <%JSを探していた%JG、 \PC …。%JSと \NARRATIVE 1 が \ELEMENT 3 で何かをしでかそうとしていることは分かっている%JG。%JFはそれを見過ごすわけにはいかない%JG！>
	% Msg3 <I've been looking for you, \PC ... I know what you and your gang have been planning for \ELEMENT 3 , and I won't let you get away with it!>
	Msg3 <%JSを探していた%JG、 \PC …。%JSと%JSの一味が \ELEMENT 3 で何かをしでかそうとしていることは分かっている%JG。%JFはそれを見過ごすわけにはいかない%JG！>
	% Msg4 <So, trying to find out how much I know, eh? It's not going to work. I'm on to you, and so are half the bounty hunters in the FedTer...>
	Msg4 <ほう、%JFがどれだけ知っているか確かめようというのか？そんなことをしても無駄だ。%JFも、連邦の賞金稼ぎの半数も%JSの企みに気づいている%JG…。>
	% Msg5 <Playing innocent isn't going to help. I'm on to you, and so are half the bounty hunters in the FedTer...>
	Msg5 <知らぬふりをしても無駄だ。%JFも、連邦の賞金稼ぎの半数も%JSの企みに気づいている%JG…。>
	% Msg6 <The wolf may change his coat but not his spots. Word on the underground is that you're deeply involved in this project. Now every bounty hunter in the FedTer is after you.>
	Msg6 <狼は毛皮を変えても模様は変わらない%JG。裏社会の話によれば、%JSはこの陰謀に深く関わっているそうだな。今や連邦中の賞金稼ぎが皆%JSを追っている%JG。>
	% Msg7 <That's not what I heard. Word on the underground is that you're very important to \NARRATIVE 1 . Now every bounty hunter in the FedTer is after you, hoping to get to your boss.>
	Msg7 <それは初耳だな。裏社会の話によれば、%JSは \NARRATIVE 1 にとって非常に重要な人物らしいが。今や連邦中の賞金稼ぎが皆、%JSの黒幕をとらえようと、%JSを追っている%JG。>
	% Msg8 <I know exactly who you are and what you've done. You'll be getting your justice soon enough, believe me on that.>
	Msg8 <%JFは%JSが何者で何をしてきたかを確かに知っている%JG。絶対に、%JSはまもなく裁きを受けるだろう。>
	% Msg9 <You're very good at lying; I almost want to believe you. You'll be getting your justice soon enough, though. If not from me then from someone else...>
	Msg9 <嘘をつくのが上手い奴だな。%JFはもう少しで%JSを信じたく思うところだったよ。しかし、%JSはまもなく裁きを受けるだろう。もし%JFがしくじっても、他の人間が裁きを下すだろう…。>
	% Prompt1 <We've been planning what?>
	Prompt1 <%JFたちが何を企んでいるって？>
	% Prompt2 <I don't know what you're talking about.>
	Prompt2 <%JSが何を言っているのか分からない%JG。>
	% Prompt3 <I left \NARRATIVE 2 a long time ago.>
	Prompt3 <%JFはずっと昔に \NARRATIVE 2 を抜けたよ。>
	% Prompt4 <\NARRATIVE 1 and I are enemies now.>
	Prompt4 <今は \NARRATIVE 1 と%JFは敵同士だ。>
	% Prompt5 <Think what you like. I don't care.>
	Prompt5 <お好きなように考えてくれ。%JFは構わない。>
	% Prompt6 <Please understand, you're wrong about me!>
	Prompt6 <分かってくれ、誤解だ！>


	Plot 1
	% PC refused to fight the hunter, and now has a chance to find the
	% secret project referred to by the hunter...
	name <Accused! Act 2>

	% V2 = Combat Indicator
	Init_Start <ifNPCOK E5 else GoDelete Memo 1>
	start <ifNPCOK E5 else GoDelete Memo 1>
	GoDelete <S= 101 1 AdvancePlot 0>
	% Msg1 <\ELEMENT 2 said that your old enemies were doing something in \ELEMENT 3 .>
	Msg1 <\ELEMENT 2 によると、%JSの昔の敵が \ELEMENT 3 で何かを企んでいるらしい。>

	nu1 <if= T1 0 if= V2 1 if= L2 1 else GoLose  V= 2 3>
	GoLose <V= 2 2 LoseRenown>

	sub
		Persona 5
		% rumor <!5 saw some weird mecha outside of town.>
		rumor <!5 は町の外で変なメックを見かけた>
		% V1 = Combat Recharge
		greeting <NewChat if= P2 3 else GoCheckLoss AddReact d30 Say 7 XPV 100 Reputation 1 1 S= 101 1 S+ 102 1 S= 105 1 N= 3 E4 XRBadThing NAV_XRBResolved AdvancePlot 2>
		% GoCheckLoss <if= P2 2 else GoMaybeFirst Say 5 V= 1 ComTime V+ 1 19800>
		GoCheckLoss <if= P2 2 else GoMaybeFirst Say 5 V= 1 ComTime V+ 1 19800 P= 2 0>
		GoMaybeFirst <if# V1 0 else GoFirstTime ifG ComTime V1 else GoWaitRecharge Say 6 AddChat 2>
		GoWaitRecharge <Say 4>
		GoFirstTime <AddChat 1 ifFaction N2 else GoCheckChara Say 1 Memo 8>
		GoCheckChara <ifNPCOK N1 else GoUnknownEnemy Say 2 Memo 9>
		GoUnknownEnemy <Say 3 Memo 10>
		result1 <EndChat Say 11 Goto GoStartCombat>
		result2 <Goto result1>
		GoStartCombat <P= 2 1 V= 3 Threat S103 225 SavePos Staged .scene V3>
		.scene <SCENE_DestroyTarget.txt>
		% Msg1 <I saw some mecha with \NARRATIVE 2 markings in the woods outside of town. I hope they aren't planning invade here...>
		Msg1 <%JFは町の外の森で \NARRATIVE 2 のシンボルマークを付けた何機かのメックを見かけた%JG。奴らがここへ侵入してこなければいいのだけれど…。>
		% Msg2 <A while back there was a mecha pilot named \NARRATIVE 1 in town. He said they had a big project going on in the woods, but from the look of things I don't think he was up to any good.>
		Msg2 <少し前に \NARRATIVE 1 という名のメックパイロットがこの町にいた%JG。彼は自分たちが森の中で大きな計画を進めていると言っていたけれど、あのようすでは良いことを考えているとは思えない%JG。>
		% Msg3 <There have been mysterious mecha going back and forth in the forest outside town. I don't know what's going on but I don't like it one bit.>
		Msg3 <町の外の森の中を行ったり来たりしている奇妙なメックがいた%JG。何をしていたのかは分からないけれど、全く嫌な感じだ。>
		% Msg4 <Come back in a few hours and I'll show you where I saw the mecha again.>
		Msg4 <数時間後にまた来てくれ。そうすれば%JFがメックを見かけた場所へ案内しよう。>
		% Msg5 <I hear things didn't go so well for you. Go rest up, then come back here in a few hours and maybe you can try again.>
		Msg5 <あまりうまくいかなかったそうだね。しっかり休んでからここへ戻って来るといい。そうすればまた挑戦できるよ。>
		% Msg6 <You want to go find that mecha base again?>
		Msg6 <また例のメック基地を探しに行くかい？>
		% Msg7 <Their base has been destroyed! Our town will be safe, for a while at least... I heard that some of the surviving pilots were headed for \ELEMENT 4 .>
		Msg7 <奴らの基地は破壊された%JG！これで%JFたちの町は安全になるだろう、少なくともしばらくの間は…。生き残りのパイロットたちの一部は \ELEMENT 4 へ向かったらしい%JG。>
		% Msg8 <\ELEMENT 5 in \ELEMENT 3 saw mecha from \NARRATIVE 2 near town.>
		Msg8 <\ELEMENT 3 の \ELEMENT 5 は町の近くで \NARRATIVE 2 のメックを見かけた。>
		% Msg9 <\ELEMENT 5 in \ELEMENT 3 saw \NARRATIVE 1 doing something near town.>
		Msg9 <\ELEMENT 3 の \ELEMENT 5 は \NARRATIVE 1 が町の近くで何かしているのを見かけた。>
		% Msg10 <\ELEMENT 5 in \ELEMENT 3 saw mysterious happenings in the woods.>
		Msg10 <\ELEMENT 3 の \ELEMENT 5 は森の中で奇妙な出来事に出くわした。>
		% Msg11 <I don't understand why they came here, but I know it's bad for \ELEMENT 3 . Please stop them.>
		Msg11 <奴らがなぜここへ来たのかは分からないけれど、その目的が \ELEMENT 3 にとって悪いことだということは分かる%JG。奴らを止めてくれ。>
		% Prompt1 <Can you show me where they went?>
		Prompt1 <奴らがどこへ行ったか教えてくれないか？>
		% Prompt2 <I'm ready to go.>
		Prompt2 <行ける%JG。>

	Plot 2
		name <Accused! Act 3>
		Init_Start <if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 864000 goto InitCheckE2>
		InitCheckE2 <ifNPCinPlay E2 else InitCheckFin print 10002 goto InitCheckFin>
		% Msg10002 <\ELEMENT 2 has left this area.>
		Msg10002 <\ELEMENT 2 はこのエリアを去った。>
		InitCheckFin <MoveChar E2 E1 ifFaction N2 else GoCheckPersona History 1>
		start <if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 864000 MoveChar E2 E1 ifFaction N2 else GoCheckPersona History 1>
		GoCheckPersona <ifNPCOK N1 else GoMisc History 2>
		GoMisc <History 3>
		GoCheckTime <ifG ComTime V1 AdvancePlot 0>
		% Msg1 <You destroyed a base belonging to \NARRATIVE 2 .>
		Msg1 <\NARRATIVE 2 に所属する基地を破壊した。>
		% Msg2 <You destroyed a base belonging to \NARRATIVE 1 .>
		Msg2 <\NARRATIVE 1 に所属する基地を破壊した。>
		% Msg3 <You destroyed a base belonging to your former employers.>
		Msg3 <元雇い主の組織に所属する基地を破壊した。>

	sub
		Persona 2
		% rumor <!2 wants to apologize to you.>
		rumor <!2 があなたに謝りたいと言っている>
		greeting <NewChat Say 1 PCAlly E2 XPV 100 AdvancePlot 0>
		% Msg1 <I have to apologize. I was wrong about you... You've really shown your true colors. It would be an honor to fight at your side, some day.>
		Msg1 <%JFは謝らなければならない%JG。%JFは%JSを誤解していた%JG…。%JSの本性はじゅうぶん分かった%JG。いつの日か%JSと共に戦えたら光栄に思う%JG。>

	end

	end

end
inv
	NPC Bounty Hunter
	chardesc Heroic Passionate
	EquipChar 25000
	place <1 ally>
	mecha <Neko.txt>

	NPC Citizen
	chardesc Young Heroic
	place <3 ally pass>

end
