Plot 0
	name <Member One>

	% Member One is "The Dragon", a combat expert who fights to
	% the death in order to prove who's stronger. If the PC defeats
	% him, he leaves behind a wallet which the PC can investigate
	% to discover bus ticked stubs from E2, which will lead the PC
	% into the next part of the adventure.

	% E1 is the scene for this episode; E2 the scene for the next
	element1 <Grab 2>
	element2 <Scene Town !Far 1 !Member 11>

	% E3 is the guardian who will give the PC a reward
	element3 <Character Guardian !Near 1>

	% E4 is the murderer, E5 is his wallet.
	element4 <Prefab>
	element5 <Prefab>

	% V1 = Initialization Counter / NPC Defeated Counter
	% V2 = Clue Number
	% V3 = Have been accosted by E4 / Fight has started

	Init_Start <V= 1 1 goto GoInitNPC>
	start <if= V1 0 else GoCheckClue V= 1 1 Goto GoInitNPC>
	GoInitNPC <S= 6 E4 Compose UTD E4 .e4dies NPCLevel E4 S2 NPCSkill+ E4 9 3 NPCSkill+ E4 10 2 Goto GoInitItem>
	GoInitItem <Compose KEY E5 .usekey ItemVar= E5 1 E2 V= 2 S202 V+ 2 1 ItemVar= E5 2 V2 MoveChar E4 E1>
	% .e4dies <if= V1 1 S= 201 0 S+ 202 1 S= 5 ComTime S+ 5 13800 N= 2 E2 V= 1 2 Email d5>
	.e4dies <if= V1 1 S= 201 0 S+ 202 1 S= 5 ComTime S+ 5 13800 N= 2 E2 V= 1 2 SetNPC E3 Email d5>
	.usekey <ifG V2 S203 S= 203 V2 FacXP+ N1 1 AdvancePlot 0>
	% If the PC has discovered clues so as to make this plot worthless,
	% erase it now, so long as the NPC has already been defeated.
	GoCheckClue <if= V1 2 else GoCheckRevenge ifG V2 S203 else GoDelete>
	GoDelete <AdvancePlot 0>

	% If the PC has defeated any other members of the club, this
	% member will challenge the PC to combat.
	GoCheckRevenge <ifG S202 0 ifNPCInPlay E4 NPCGoPC E4>
	TM1 <if= SceneID E1 ifNPCinPlay E4 ifG S202 0 if= V3 0 ifG 6 Range PCUID NPCUID E4 V= 3 1 Print 101 ForceChat E4>

	cleanup <DeleteChar E4 AdvancePlot 0>

	% Msg1 <\ELEMENT 3 @ \SCENE ESCENE 3 :// You helped stop one of the "Murder Club". Come see me for a reward.>
	Msg1 <\ELEMENT 3 @ \SCENE ESCENE 3 :// あなたは「殺人クラブ」の一人を止めるのに協力してくれました。報酬を受け取りに来てください。>
	% Msg2 <\ELEMENT 3 @ \SCENE ESCENE 3 :// That was a member of the "Murder Club" you just fought with. Come see me for a reward.>
	Msg2 <\ELEMENT 3 @ \SCENE ESCENE 3 :// 先ほどあなたが戦ったのは「殺人クラブ」のメンバーでした。報酬を受け取りに来てください。>
	% Msg3 <\ELEMENT 3 @ \SCENE ESCENE 3 :// You just defeated a member of the "Murder Club". You do know there's a reward for that, don't you?>
	Msg3 <\ELEMENT 3 @ \SCENE ESCENE 3 :// 先ほどあなたは「殺人クラブ」のメンバーを倒しました。奴に賞金がかかっているのは知っているでしょう？>
	% Msg4 <\ELEMENT 3 @ \SCENE ESCENE 3 :// We've been trying to stop that killer ourselves. Come see me about it.>
	Msg4 <\ELEMENT 3 @ \SCENE ESCENE 3 :// 我々はあの殺人鬼たちを止めようとしています。それについて私に会いに来てください。>
	% Msg5 <\ELEMENT 3 @ \SCENE ESCENE 3 :// Good job in \ELEMENT 1 . There was a reward for that killer... come talk to me.>
	Msg5 <\ELEMENT 3 @ \SCENE ESCENE 3 :// \ELEMENT 1 ではよくやってくれました。あの殺人鬼には賞金がかけられていました…私と話をしに来てください。>

	% Msg101 <\ELEMENT 4 shouts at you!>
	Msg101 <\ELEMENT 4 があなたに向かって叫んだ！>

sub
	Persona 3
	% V1 = Have given reward
	% V2 = Message Randomizer
	greeting <NewChat if= P1 2 else GoNothing if= V1 0 else GoNothing V= 1 1 CashPrize Reward Threat PCRep 6 100 100 ifNPCOK S7 else GoNoS7 ifG React d30 else GoNoS7 Say d3 S+ 103 1 Memo 7>
	GoNoS7 <V= 2 3 V+ 2 d3 Say V2>
	GoNothing <SayAnything>
	% Msg1 <You've done well in protecting the city. If you're interested in helping more, contact \PERSONA S7 in \SCENE S8 . Here's a reward for you.>
	Msg1 <あなたは町を守るのに成功しました。もしもっと協力してくれる気があるのなら、 \SCENE S8 の \PERSONA S7 と連絡を取ってください。こちらが報酬です。>
	% Msg2 <Here's your reward. Let me tell you something... if you'd like to help us defeat this murder club once and for all, go see \PERSONA S7 in \SCENE S8 .>
	Msg2 <こちらが報酬です。あなたに伝えたいことがあります…もしこの殺人クラブを永久に打倒するのに手を貸したいのなら、 \SCENE S8 の \PERSONA S7 に会いに行ってください。>
	% Msg3 <You've helped to defend our city. Here's a reward for you... If you'd like to continue working on this murder club case, you should contact \PERSONA S7 in \SCENE S8 .>
	Msg3 <あなたはこの町を守ってくれました。こちらが報酬です…。もしこの殺人事件の調査を続けたいのなら、 \SCENE S8 の \PERSONA S7 と連絡を取ってください。>
	% Msg4 <Here's your reward for helping out.>
	Msg4 <こちらがあなたの協力に対する報酬です。>
	% Msg5 <Here's a reward for your heroic deeds.>
	Msg5 <こちらがあなたの英雄的な行いに対する報酬です。>
	% Msg6 <You did well in protecting our city. Here's a reward.>
	Msg6 <あなたはこの町を守るのに成功しました。こちらが報酬です。>
	% Msg7 <\ELEMENT 3 in \SCENE EScene 3 told you to contact \PERSONA S7 in \SCENE S8 about the murder club investigation.>
	Msg7 < \SCENE EScene 3 の \ELEMENT 3 から殺人クラブの捜査について \SCENE S8 の \PERSONA S7 と連絡を取るように言われた。>

	Persona 4
	% rumor <!4 is always looking for someone new to fight.>
	rumor <!4 は常に戦う相手を探している>
	% To start with, the PC will be prevented from starting combat
	% at a safe distance by using the telephone...
	greeting <ifG Range PCUID NPCUID E4 6 else GoRealStart EndChat Say 1>

	% Next, if combat has already started, E4 won't say anything new.
	GoRealStart <if= P3 2 else GoRealFirst Say 2>

	GoRealFirst <if= P3 1 else GoCheckRep V= 2 2 V+ 2 d3 Say V2 Goto GoStartCombat>
	GoCheckRep <ifG PCRep 6 S2 else GoNoChance V= 2 5 V+ 2 d3 Say V2 Goto GoStartCombat>
	GoNoChance <V= 2 8 V+ 2 d3 Say V2 ifG S103 0 AddChat 9>

	GoStartCombat <P= 3 2 SoloAttack E4 AddChat d3 V= 2 3 V+ 2 d3 AddChat V2>
	% GoSurrender <Print 30 FacXP+ N1 1 XPV 100 if= P1 1 S= 201 0 S+ 202 1 S= 5 ComTime S+ 5 13800 N= 2 E2 P= 1 2 Email 29 DeleteChar E4>
	GoSurrender <Print 30 FacXP+ N1 1 XPV 100 if= P1 1 S= 201 0 S+ 202 1 S= 5 ComTime S+ 5 13800 N= 2 E2 P= 1 2 SetNPC E3 Email 29 DeleteChar E4>

	result1 <EndChat V= 2 16 V+ 2 d2 Say V2 V= 2 9 V+ 2 d2 AddChat V2 V= 2 11 V+ 2 d2 AddChat V2 ifG PCSkillVal 28 0 V= 2 6 V+ 2 d2 AddChat V2>
	result2 <Goto result1>
	result3 <Goto result1>

	result4 <EndChat V= 2 14 V+ 2 d2 Say V2>
	result5 <Goto result4>
	result6 <Goto result4>

	result7 <EndChat Mental ifG Intimidation 15 else GoR7Fail V= 2 24 V+ 2 d2 Say V2 Goto GoSurrender>
	GoR7Fail <V= 2 26 V+ 2 d2 Say V2>
	result8 <goto result7>

	result9 <EndChat V= 2 11 V+ 2 d3 Say V2 goto GoStartCombat>

	result10 <ENdChat Reputation 1 1 ifG PCRep 1 d65 else GoR10Fail ifG PCRep 6 dS2 else GoR10Fail V= 2 22 V+ 2 d2 Say V2 Goto GoSurrender>
	GoR10Fail <V= 2 20 V+ 2 d2 Say V2>
	result11 <Goto result10>

	result12 <EndChat V= 2 18 V+ 2 d2 Say V2 Reputation 5 -d6>
	result13 <Goto result12>

	% Msg1 <I don't like using the phone. Come over here if you've got something to say to me.>
	Msg1 <%JFは電話を使いたくない%JG。言うことがあるならここへ来てくれ。>
	% Msg2 <Let's see who is stronger!!!>
	Msg2 <どちらが強いか確かめようぜ！！！>

	%  03 - 05 :  PC has defeated other member of murder club.
	% Msg3 <Ah, you're \PC , aren't you? I heard you defeated another member of our club... They call me "The Dragon", and I will prove to the world how strong I am by killing you now!>
	Msg3 <やあ、%JSは \PC だね？ %JSは%JFたちのクラブのメンバーを倒したそうだな…。%JFはクラブ内で「ドラゴン」と呼ばれている%JG。今こそ%JSを殺して%JFの強さを世界に知らしめるとしよう！>
	% Msg4 <Allow me to introduce myself. I'm known as "Kong Rex" of the murder club. You've had some luck against our weaker members, but you have no chance at all against me. I will show you which of us is the stronger!>
	Msg4 <自己紹介させて頂きたい。%JFは殺人クラブの「コング・レックス」と呼ばれている%JG。%JSは弱いメンバー相手に幸運にも勝利したようだが、%JFが相手では%JSに勝ち目は全くあるまい。%JFたちのどちらが強いか見せてやろう！>
	% Msg5 <It's you! It will be a great honor for me to kill you with my own hands. I am \PERSONA E4 of the murder club, but everyone calls me "Walking Weapon"! You've defeated one of our weaker members. Now it's time to meet your end!>
	Msg5 <%JSか！ %JSをこの手で殺せるのはとても名誉なことだね。%JFは殺人クラブの \PERSONA E4 だが、皆は%JFを「人間兵器」と呼んでいる%JG！ %JSは弱いメンバーを倒したようだな。今こそ%JSの人生が終わるときだ！>

	%  06 - 08 :  PC is renowned; will be challenged by this character.
	% Msg6 <Wow, it's \PC ! I've heard of you... you're famous as a warrior. I hope to be famous too, someday, as the world's greatest killer... In the murder club I'm known as "The Dragon". Now it's time for you to be my next victim!>
	Msg6 <おお、 \PC じゃないか！噂は聞いている%JG…%JSは戦士として有名だからね。%JFもいつかは有名になりたい%JG、世界一の殺し屋としてね…。殺人クラブでは「ドラゴン」と呼ばれている%JG。今こそ%JSが%JFの次なる犠牲者となるときだ！>
	% Msg7 <I've been hoping to meet you. My name is \PERSONA E4 of the murder club, but my nickname is "Ultimate Dragon". I'm out to prove that I'm the best fighter in the world and I'll start by killing the famous adventurer \PC !>
	msg7 <%JSに会いたかった%JG。%JFは殺人クラブの \PERSONA E4 だが、ニックネームは「究極ドラゴン」さ。%JFは世界一の戦士であることを証明しようとしている%JG。その手始めに有名な冒険者である \PC を殺すことにしよう！>
	% Msg8 <Now the predator meets the prey... I've been looking for you. In the murder club I'm known as "Psycho Monk". It's my goal to prove myself as the deadliest fighter in the world. I'll start by defeating the adventurer \PC in mortal combat!>
	Msg8 <たった今、捕食者が獲物と出会ったわけだ…。%JFは%JSを探していた%JG。%JFは殺人クラブ内で「狂人修道士」と呼ばれている%JG。自分を世界一危険な戦士であると証明するのが目標だ。その手始めに冒険者 \PC を死闘で倒す事にしよう！>

	%  09 - 11 :  PC isn't renowned; will be ignored by this character.
	% Msg9 <You look weak.>
	Msg9 <%JSは弱そうだな。>
	% Msg10 <I think you probably aren't very strong.>
	Msg10 <%JSはたぶんあまり強くないだろう。>
	% Msg11 <You don't look very interesting.>
	Msg11 <%JSにはあまり興味が湧かない%JG。>

	%  12 - 14 :  PC has asked about the murder club.
	% Msg12 <If you're looking for the murder club, you must have heard of me. My nickname is "Black Dragon"; I want to be the deadliest fighter in the whole world. It will be a simple thing for me to kill you now...>
	Msg12 <殺人クラブを探しているなら、%JFの噂は聞いたことがあるはずだ。%JFのニックネームは「ブラック・ドラゴン」だ。%JFは全世界で一番危険な戦士になりたい%JG。今すぐ%JSを殺すのは%JFにとって朝飯前のことさ…。>
	% Msg13 <You're asking dangerous questions... my club-mates wouldn't be happy if I allowed you to live. They call me "Jet Gi Reum"; it may be boring to kill someone as weak as you, but it's a nessecary chore.>
	Msg13 <%JSは危険な質問をしている%JG…%JFが%JSを殺し損ねれば%JFの仲間は喜ばないだろう。%JFは仲間から「ジェット・ジー・ルム」と呼ばれている%JG。%JSのような弱い奴を殺すのはつまらないだろうが、必要な仕事だからな。>
	% Msg14 <So, you've heard of us? Good. My name is \PERSONA E4 but I'm known as "Red Tiger". I want the entire world to know how dangerous I am... You'll learn that soon, but won't live long enough to tell anyone else.>
	Msg14 <%JSは%JFたちの噂を聞いたのか？%JFの名は \PERSONA E4 だが「レッド・タイガー」と呼ばれている%JG。%JFは全世界に%JFの強さを知らしめたい%JG…。%JSもすぐにそれを知るが、生きて誰かに伝えることはできないだろうね。>

	%  15 - 16 :  PC wants to start the fight immediately.
	% Msg15 <If you think you can defeat me, I'll soon show you that you're wrong!>
	Msg15 <もし%JFを倒せると思っているのなら、それが勘違いであることを今すぐ教えてやろう！>
	% Msg16 <I hope you're not too weak. I'd hate for this to be a boring fight.>
	Msg16 <%JSが弱すぎなければいいんだが。%JFはこの戦いをつまらないものにしたくない%JG。>

	%  17 - 18 :  PC doesn't want to fight.
	% Msg17 <So, you're afraid to die, is that why you don't want to fight?>
	Msg17 <では、%JSは死ぬのが怖くて、それで戦いたくないというわけだな？>
	% Msg18 <Why do you not want to fight? Are you afraid to die? You know that I can defeat you...>
	Msg18 <どうして戦いたくないんだ？ 死ぬのが怖いのか？ %JFにかなわないことは分かっているようだね…。>

	%  19 - 20 :  PC has given the wimpy answer.
	% Msg19 <Your cowardace disgusts me. Show some courage in the face of your death!!!>
	msg19 <%JSの臆病さには反吐が出る。せめて死に顔には勇気を見せてくれ！！！>
	% Msg20 <Don't be afraid, your death will come very quickly!>
	Msg20 <怖がることはない%JG。あっという間に殺してやるからな！>

	%  21 - 22 :  Plan "A" has failed.
	% Msg21 <I think your kind words just disguise a lack of courage. At least you should try to face death like a warrior!>
	Msg21 <%JSは単に死ぬのが怖いからそんな優しい言葉でごまかそうとしているのだろう。せめて戦士らしく死と向き合え！>
	% Msg22 <I can't believe in your words... You're just afraid to die, yourself.>
	Msg22 <%JFは%JSの言葉など信じない%JG…。%JSは死ぬのが怖いだけだ。>

	%  23 - 24 :  Plan "A" has worked.
	% Msg23 <I have never seen such purity of spirit before... Your soul is stronger than my warrior nature. Perhaps there is something more important than being most powerful? Alright, let's not do battle. I will surrender to the police.>
	msg23 <%JFは今まで%JSのような清らかな人と出会ったことはなかった%JG…。%JSの心は%JFの戦いを求める心よりも強い。もしかして、最強であることよりも大切なことがあるというのか？ 分かった。戦うのは止そう。%JFは警察に自首するよ。>
	% Msg24 <You are truly unafraid of me, yet you do not attack... your peaceful nature is more powerful than my warrior spirit. I have been shown the error of my ways. I will turn myself in to the guardians, and attempt to reform my life by your example.>
	Msg24 <%JSは%JFを全く恐れないし、攻撃もしてこない…%JSの平和精神は%JFの戦いを求める心よりも強い。%JFの生きる道は間違っていたようだな。Guardiansに自首するよ。そして%JSに倣って人生をやり直そうと思うんだ。>

	%  25 - 26 :  Plan "B" has worked.
	% Msg25 <Ulp... well, I'm too young to die yet... I changed my mind... I don't want to be a warrior after all. I'm going to go turn myself in to the guardians... they'll protect me from you...>
	Msg25 <うっ…まあ、%JFはまだ死ぬには若すぎるし…。考えが変わったよ…%JFはもう戦士になろうとは思わない%JG。Guardiansに自首しに行くよ…%JFを%JSから守ってくれるだろうからね…。>
	% Msg26 <Thinking about it more carefully, I think you could be right... I'm just going to go turn myself in to the guardians now. I'm too young to die senselessly.>
	Msg26 <よく考えてみたら、%JSの言う通りかもしれない…。%JFは今すぐGuardiansに自首しに行くよ。%JFは無駄死にするには若すぎるからね。>

	%  27 - 28 :  Plan "B" has failed.
	% Msg27 <Ha, you have spirit! This should be a good fight!>
	Msg27 <ハッ、度胸はあるようだな！ 楽しい戦いになるだろう！>
	% Msg28 <You think you can intimidate me so easily? I have no fear of death! Let's do battle!>
	Msg28 <%JFがそんなに簡単にびびると思っているのか？ %JFは死など恐れない！ さあ戦おう！>

	% Msg29 <\ELEMENT 3 @ \SCENE ESCENE 3 :// You helped capture one of the members of the "Murder Club". Come see me for a reward.>
	Msg29 <\ELEMENT 3 @ \SCENE ESCENE 3 :// あなたは「殺人クラブ」のメンバーを捕らえるのに協力してくれました。報酬を受け取りに来てください。>
	% Msg30 <\ELEMENT 4 has surrendered.>
	Msg30 <\ELEMENT 4 は降伏した。>

	%  01 - 03 :  PC doesn't want to fight.
	% Prompt1 <I don't want to fight you.>
	Prompt1 <%JSとは戦いたくない%JG。>
	% Prompt2 <Why do we have to fight?>
	Prompt2 <戦う理由はないだろう？>
	% Prompt3 <I'm not going to fight you.>
	Prompt3 <%JSと戦うつもりはない%JG。>

	%  04 - 06 :  PC wants to start the fight now.
	% Prompt4 <Alright, let's get this over with.>
	Prompt4 <分かった。戦いを済ませよう。>
	% Prompt5 <Let's start this.>
	Prompt5 <戦いを始めよう。>
	% Prompt6 <If you want to die, I'll fight you.>
	Prompt6 <死にたいのなら、戦ってやろう。>

	%  07 - 08 :  PC will use intimidation to avoid fight.
	% Prompt7 <Your skill is beneath me.>
	Prompt7 <%JSの腕は%JFより下だ。>
	% Prompt8 <You'd be no challenge to me.>
	Prompt8 <%JSなど%JFの相手ではない%JG。>

	% Prompt9 <I'd like to ask you about the murder club.>
	Prompt9 <殺人クラブについて聞きたいんだが。>

	%  10 - 11 :  PC doesn't want to kill E4.
	% Prompt10 <Look, I don't want to kill you.>
	Prompt10 <なあ、%JFは%JSを殺したくない%JG。>
	% Prompt11 <I just don't want to kill you.>
	Prompt11 <%JFは%JSを殺したくないだけなんだ。>

	%  12 - 13 :  PC doesn't want to die.
	% Prompt12 <I don't want to die.>
	Prompt12 <%JFは死にたくない%JG。>
	% Prompt13 <Fighting is too dangerous...>
	Prompt13 <戦いは危険すぎる…。>

end
inv
	NPC Soldier
	job <Student>
	chardesc Young Villainous Spiritual
	EquipChar 10000

	Treasure 500
	name <Wallet>
	name_I18N <財布>
	place <4>
	% V1 = Location of next encounter
	% V2 = Clue number for this item
	% V3 = Investigation Indicator
	% V4 = PC Investigation skill when last tried
	use <if= V3 1 else GoNoSolve Print 1>
	GoNoSolve <Print 2>
	Clue37 <ifG PCSkillVal 37 V4 else GoDid Mental V= 4 PCSkillVal 37 ifG SkRoll 37 10 else GoNoSolve V= 3 1 Print 1 XPV 100 Trigger KEY SelfNID>
	GoDid <if= V3 1 else GoNoSolve Print 1>
	% Msg1 <Searching the wallet, you discover a bus ticket for \SCENE V1 .>
	Msg1 <財布の中を探り、 \SCENE V1 へのバス券を見つけた。>
	% Msg2 <It's a wallet. It's full of all kinds of personal things.>
	Msg2 <これは財布だ。さまざまな私物が一杯に入っている。>

end
