Plot 0
	name <Iria Ruby Plot>

	% The PC will be asked by Eli Kettel to go to Nara and
	% recover the Iria Ruby from the Cyclops which inhabit
	% the area.

	% E1 is Elisha Kettel
	element1 <Character>
	stat 1 32

	% E2 is Praetor
	element2 <Character>
	stat 2 5001

	% E3 is the ruby itself
	element3 <Prefab>

	% V1  = Initialization Counter
	% V2  = Have picked up the ruby
	% V3  = Have accepted job from Elisha
	% V4  = Have agreed to help Praetor

	Init_Start <ifNPCOK E1 else GoDelete ifItemOK E3 else GoMaybeDelete if= V1 0 V= 1 1 MoveKeyItem E3 50 Compose GET E3 .getit>
	start <ifNPCOK E1 else GoDelete ifItemOK E3 else GoMaybeDelete if= V1 0 V= 1 1 MoveKeyItem E3 50 Compose GET E3 .getit>
	.getit <P= 2 1  P= 4 0  G= 3 -1  if= SCENEID 50 Reputation 1 -1 if# L2 1 Print 101 TeamAttack 2>
	GoDelete <AdvancePlot 0 if= V2 0 DeleteKeyItem E3>
	GoMaybeDelete <if= V3 0 AdvancePlot 0>

	%Msg101 <An alarm sounds! You better get out of this place quickly...>
	Msg101 <アラームが鳴り響いた！ ここから速やかに立ち去ったほうが良さそうだ…。>

sub
	Persona 1
	% Elisha Kettel
	% V2 = Message randomizer
	%rumor <!1 is constantly working to make sure that Kettel Industries remains the number one corporation!>
	rumor <Kettel Industries がＮＯ．１であり続けられるよう、 !1 は働き続けている>
	greeting <NewChat if= P3 1 else GoNoMission Say 1 AddChat 1 AddChat 2 AddChat 9 ifKeyItem E3 else GoNoKey AddChat 3 if= P4 1 AddChat 4>
	GoNoKey <ifItemOK E3 else GoNoRuby if= P4 1 AddChat 4>
	GoNoRuby <AddChat 4>
	% If the PC has not yet been given the mission, see if it
	% will be offered here.
	GoNoMission <if= PCFac 4 else GoNMNoMember Say 10 AddChat 5 AddChat 6>
	GoNMNoMember <ifG PCRep 6 10 else GoNMNoRenown Say 11 AddChat 5 AddChat 6>
	GoNMNoRenown <ifG React 30 else GoNMNoChance Say 12 AddChat 5 AddChat 6>
	% If the PC is not offered the mission, imply it anyhow.
	GoNMNoChance <V= 2 100 V+ 2 d5 Say V2>
	result1 <NewChat Say 2>
	result2 <NewChat Say 3>
	result3 <NewChat Say 4 DeleteKeyItem E3 Reputation 6 1 AddReact 20 CashPrize 500000 XPV 100 FacXP+ 4 500 History 13 AdvancePlot 0>
	result4 <NewChat ifG PCRep 6 50 else GoR4NoRenown Say 5 Goto GoR4End>
	GoR4NoRenown <ifG PCRep 2 25 else GoR4NoLaw Say 6 Goto GoR4End>
	GoR4NoLaw <ifG SkRoll 19 12 else GoR4NoCharm Say 7 Goto GoR4End>
	GoR4NoCharm <Say 8 PCEnemy E1 PCFEnemy 4 LoseRenown Reputation 2 -5  Goto GoR4End>
	GoR4End <AdvancePlot 0 if= P4 1 DeleteKeyItem E3 Reputation 1 1 XPV 100 History 14>
	result5 <NewChat Say 16 AddChat 7 AddChat 8>
	result6 <NewChat Say 15>
	result7 <NewChat Say 17 CashPrize 25000 P= 3 1 Memo 9>
	result8 <NewChat Say 18 DeleteKeyItem E3 AddReact -d8 AdvancePlot 0>
	result9 <NewChat PCEnemy E1 PCFEnemy 4 AdvancePlot 0 if= PCFac 4 else GoR9NoMember Say 19 AddReact -10 LoseRenown FacXP+ 4 -9999 Goto GoR9End>
	GoR9End <if= P4 1 DeleteKeyItem E3 XPV 200 Reputation 1 5 History 14>
	GoR9NoMember <Say 20 AddReact -30  if= P4 1 DeleteKeyItem E3 History 14 XPV 100 Reputation 1 1>
	%Msg1 <I've been waiting to hear of your progress. Have you found the Ruby yet?>
	Msg1 <報告を待っていました。例のルビーは見つかりましたか？>
	%Msg2 <Then you should try harder. When I hired you for this mission I expected results.>
	Msg2 <それなら、もっと頑張ってください。%JSをこの任務に雇用したのは、成果を期待したからなのですから。>
	%Msg3 <It is held by the Cyclops biosoldiers, who doubtlessly will use it to clone more of their kind. Many years ago they destroyed the village of Nara and set up a breeding colony deep underground. You will find the Ruby there.>
	Msg3 <それはCyclopsという生物兵士たちが保管しています。おそらく彼らは自分たちの種をクローン生成で増やすためにそれを利用しているのでしょう。昔、彼らは Nara 村を破壊し、地下深くに繁殖地を築きました。例のルビーはそこにあるはずです。>
	%Msg4 <Ah, this ruby will ensure the continuing dominance of Kettel Industries for the foreseeable future. Here's a reward, as you were promised.>
	Msg4 <すばらしい！ このルビーがあれば Kettel Industries はすぐに優勢を得ることができ、さらにそれを保ち続けられるでしょう。約束したとおり、こちらが報酬です。>
	%Msg5 <I know that if the Ruby was there, you would have been able to get it. I suppose the ruby must have been destroyed in the many years following the Night of Fire. Thank you for your efforts, but without the ruby there can be no reward.>
	Msg5 <あなたなら、もし当地に例のルビーがあれば手に入れることができたでしょうに。きっと例のルビーは炎の夜後の長い年月の内に壊れてしまったのでしょう。%JSの尽力には感謝いたしますが、例のルビーが無いのであれば報酬はお渡しできません。>
	%Msg6 <I know that you wouldn't lie about something like that... I suppose the ruby must have been destroyed in the many years following the Night of Fire. Thank you for your efforts, but without the ruby there can be no reward.>
	Msg6 <あなたならこのようなことについて嘘を言わないでしょうからね…。きっと例のルビーは炎の夜後の長い年月の内に壊れてしまったのでしょう。%JSの尽力には感謝いたしますが、例のルビーが無いのであれば報酬はお渡しできません。>
	%Msg7 <You appear to be telling the truth... I suppose the ruby must have been destroyed in the many years following the Night of Fire. Thank you for your efforts, but without the ruby there can be no reward.>
	Msg7 <嘘は言っていないようですね…。きっと例のルビーは炎の夜後の長い年月の内に壊れてしまったのでしょう。%JSの尽力には感謝いたしますが、例のルビーが無いのであれば報酬はお渡しできません。>
	%Msg8 <Were you too lazy to search the caves, or did those monsters pay you off to lie to me? No matter; we will continue our search for the Ruby, and we will find it!>
	Msg8 <あなたは洞窟探索に手を抜いたのですか？ それとも怪物たちから私に嘘を言うようお金を支払われたのですか？ まあ、そんなことはどうでもいいでしょう。当社は例のルビーの探索を継続し、それを見つけます！>
	%Msg9 <Elisha Kettel in The Factory has offered you $500000 to recover the Iria Ruby from the Nara Ruins.>
	Msg9 <Gyori \NAME The_Factory の Elisha Kettel は Nara 廃墟から Iriaルビーを取って来れば $500000 を払うと言っている。>
	%Msg10 <Hello \RANK \PC . Kettel Industries needs a dedicated employee such as yourself for a difficult mission of great importance. If you're interested, I can give you the details right now.>
	Msg10 <こんにちは、 \RANK  \PC 。Kettel Industries は重大で困難な任務に取り組んでくれる献身的な社員を必要としています。そう、あなたのような社員を。この仕事を引き受けてみたいなら、今すぐ詳細をお話しましょう。>
	%Msg11 <You've been making a good name for yourself, \PC . Kettel Industries needs a highly skilled cavalier for a difficult mission. If you're interested, I can give you the details.>
	Msg11 <あなたは高い名声を得ているようですね、 \PC 。Kettel Industries は困難な任務に取り組んでくれる高度に熟達した騎士を必要としています。この仕事を引き受けてみたいなら、詳細をお話しましょう。>
	%Msg12 <I believe that you have a bright future ahead of you. Kettel Industries needs a highly motivated cavalier for a dangerous mission. If you're interested, I can give you the details.>
	Msg12 <あなたの前途は明るいと思います。Kettel Industries は危険な任務に取り組んでくれる熱意にあふれた騎士を必要としています。この仕事を引き受けてみたいなら、詳細をお話しましょう。>
	%Msg13 <You retrieved the Iria Ruby for Elisha Kettel.>
	Msg13 <Iriaルビーを回収し Elisha Kettel に渡した。>
	%Msg14 <You protected the Iria Ruby from Elisha Kettel.>
	Msg14 <Iriaルビーを Elisha Kettel の手から守った。>
	%Msg15 <That's too bad. Come back later when you have time and the position may still be open.>
	Msg15 <それは残念です。時間ができたらまたお越しください。まだ仕事は空いているかもしれませんから。>
	%Msg16 <We have been researching a PreZero artifact known as the "Iria Ruby". This artifact is currently held by the Cyclops, leftover bioweapons from the Age of Superpowers. The reward for bringing me this ruby is $500,000.>
	Msg16 <当社は「Iriaルビー」という旧紀の人工物を研究しています。現在この人工物はCyclopsにより保管されています。Cyclopsとは超大国時代の遺産である生物兵器です。そのルビーを私のところへ持ってきてくれれば、報酬は $500,000 になります。>
	%Msg17 <The Cyclops live in the ruins of Nara, a village they destroyed many years ago. You can find them if you head north along the coast. Their cave is well hidden and heavily defended. Here's a cash allowance to help you prepare for the trip.>
	Msg17 <Cyclopsは、それらがその昔破壊した Nara 村の廃墟に生息しています。海岸に沿って北に向かえばその廃墟が見つかるでしょう。Cyclopsの洞窟は巧妙に隠されていて、強固に守られています。こちらが旅仕度を整えるための手当てです。>
	%Msg18 <Then I will find someone else to do the job. Thank you for your time.>
	Msg18 <それならこの任務には他の者を探すことにしましょう。ありがとうございました。>
	%Msg19 <I thought you had a future in this company. It appears that I was mistaken.>
	Msg19 <あなたには当社において明るい前途があると思っていましたが、私の思い違いだったようですね。>
	%Msg20 <You have disappointed me. Fine, I will locate another to do this task.>
	Msg20 <あなたには失望しました。結構です、この任務に取り組んでくれる他の方を探すことにしましょう。>
	%Msg101 <We must work hard to keep our company in the number one spot!>
	Msg101 <当社がＮＯ．１の座であり続けるため、我々は懸命に働かねばなりません！>
	%Msg102 <Those who serve Kettel Industries will be rewarded greatly.>
	Msg102 <Kettel Industries に貢献する者は大いに報われます。>
	%Msg103 <Kettel Industries sponsors research programs all over the globe.>
	Msg103 <Kettel Industries は世界中で研究計画を支援しています。>
	%Msg104 <We may soon require the services of a skilled adventurer. Preparations are underway...>
	Msg104 <まもなく我々には熟達した冒険者の力が必要になるかもしれません。手はずは進んでいます…。>
	%Msg105 <Have you driven a "Jos" today?>
	Msg105 <最近 "Jos" に乗りましたか？>
	%Prompt1 <I'm still working on it.>
	Prompt1 <まだ取り組んでいる最中だ。>
	%Prompt2 <Where did you say it was, again?>
	Prompt2 <例のルビーはどこにあるんだっけ？>
	%Prompt3 <Here it is. [Give Ruby]>
	Prompt3 <どうぞ。[ルビーを渡す]>
	%Prompt4 <Sorry, the Ruby no longer exists.>
	Prompt4 <申し訳ないが、例のルビーはもうなかった。>
	%Prompt5 <I'm interested. Tell me more.>
	Prompt5 <やってみよう。詳しく聞きたい。>
	%Prompt6 <Sorry, I'm not able to help right now.>
	Prompt6 <申し訳ないが、今すぐは手を貸せない%JG。>
	%Prompt7 <I'll do it!>
	Prompt7 <やってみよう！>
	%Prompt8 <No, I don't want this mission.>
	Prompt8 <いや、この仕事はやりたくない%JG。>
	%Prompt9 <I've decided to quit this mission.>
	Prompt9 <この仕事を降りることにした%JG。>

	Persona 2
	% Praetor
	%rumor <!2 needs to speak with you.>
	rumor <!2 があなたと話したがっている>
	greeting <NewChat if# P2 0 else GoCheckAgree Say 1>
	GoCheckAgree <if# P4 0 else GoCheckSpoken Say 2>
	GoCheckSpoken <if= V1 1 else GoFirstTime SayAnything>
	GoFirstTime <Say 3 AddChat 1 if= P3 1 AddChat 2 AddChat 3>
	result1 <NewChat Say 4 AddChat 4 if= P3 1 AddChat 5>
	result2 <NewChat Say 5 V= 1 1 AddChat 6 AddChat 7 AddChat 8>
	result3 <NewChat Say 6 V= 1 1 AddChat 9 AddChat 10 AddChat 11>
	result4 <NewChat Say 7>
	result5 <Goto Result3>
	result6 <NewChat ifG PCRep 1 d50 else GoR6NoHero Say 8 AddChat 11>
	GoR6NoHero <Say 9>
	result7 <Goto Result3>
	result8 <EndChat Say 10  Reputation 1 -5  G= 3 -1  TeamAttack 2>
	result9 <NewChat Say 11 AddChat 11 AddChat 12 AddChat 17>
	result10 <NewChat Say 12 AddChat 11 AddChat 13>
	result11 <NewChat Say 13 AddChat 13 AddChat 14>
	result12 <NewChat V= 1 1 if= PCFac 12 else GoR12NoMember Say 14 Reputation 1 -1 Reputation 2 -20 FacXP+ 12 -500 GiveKeyItem E3 P= 2 1>
	GoR12NoMember <ifG Conversation 9 else GoR12NoDice Say 15 Reputation 2 -5 GiveKeyItem E3 P= 2 1>
	GoR12NoDice <Say 16 AddReact -15 Reputation 2 -10 LoseRenown>
	result13 <EndChat Say 17  Reputation 4 -d10 G= 3 -1  TeamAttack 2>
	result14 <NewChat Say 18 AddChat 15 AddChat 16>
	result15 <NewChat Say 19 P= 4 1>
	result16 <NewChat Say 21>
	result17 <NewChat Say 22>
	%Msg1 <You should not do anything to abuse our trust while you stay here; otherwise the repercussions could be terrible.>
	Msg1 <ここにいる間は我々の信用を裏切るようなことはしないように。さもなくばその影響は恐ろしいものとなるだろう。>
	%Msg2 <Remember what we have spoken about; the Iria Ruby should remain where it is, for the good of all involved.>
	Msg2 <我々が話したことを覚えておけ。これに関わるすべてのもののため、Iriaルビーは今ある場所にあるべきなのだ。>
	%Msg3 <Humans do not generally come to this place unless they are invited. What purpose do you have to visit?>
	Msg3 <ふつう人間は招かれなければこの場所へ来ることはないのだが。ここへ来た目的は何だ？>
	%Msg4 <Truthfully?>
	Msg4 <本当か？>
	%Msg5 <They are known to us. They are a human faction which seeks wealth and control. Also, power... For what purpose have they sent you here?>
	Msg5 <彼らのことは我々も知っている。彼らは富と権力、そして力をも求める人間の派閥だ…。彼らがお前をここへ遣った目的は何だ？>
	%Msg6 <The Iria Ruby? Its existance is known to just a few... That is a very powerful and dark artifact. The secrets it contains could be very dangerous. Why do you seek such an accursed stone?>
	Msg6 <Iriaルビーを？ あれの存在はごく少数の者にしか知られていない…。あれはとても強力で邪悪な人工物だ。あれが秘める知識は非常に危険なものになりうる。どうしてあのような忌々しい石を求めるのだ？>
	%Msg7 <It may be so.>
	Msg7 <そうか。>
	%Msg8 <Investigate? I would assume that you were sent here to locate the Iria Ruby. It would be far better for yourself and all involved if your employer would simply forget that goal.>
	Msg8 <調査だと？ 彼らはお前を Iriaルビー探索に遣ったのだと思うが。もしお前の会社がその目的をただ忘れることになれば、お前やそれに関わる者すべてのためになるのだがな。>
	%Msg9 <You are free to investigate all you want, but take nothing from this cave. The consequences would be most severe.>
	Msg9 <勝手に調査してくれて構わないが、この洞窟から何も持ち出すことはならないぞ。その行いの結果は容赦ないものとなろう。>
	%Msg10 <Your shamelessness is admirable, but you have no chance to survive.>
	Msg10 <そこまで恥を知らないと逆に立派なものだが、生きては帰れないぞ。>
	%Msg11 <Historic research? Then you should visit Hwang-Sa Temple, and view their archives. They can assist you with all but the most dangerous knowledge contained within the ruby.>
	Msg11 <歴史研究？ それなら Hwang-Sa 寺院へ行き、そこの記録を見るといい。そこの記録は件のルビーが持つ最も危険な知識以外のことならすべてを網羅しているから、お前の役にも立つであろう。>
	%Msg12 <Hired to recover it? I can guess by who. I am sorry I cannot permit you to do that. The Ruby must remain where it is; it would be far too dangerous for the world were it permitted to leave.>
	Msg12 <あのルビーを回収しに？ 誰に雇われたか分かったぞ。悪いがそうはいかない。例のルビーは今ある場所にあるべきなのだ。それをここから出してしまうことは世界にとってあまりに危険すぎるからな。>
	%Msg13 <It is a computer from the last age containing knowledge of forbidden technology. It knows the location of nuclear stockpiles among other more sinister things. In the hands of an ambitious human, it could bring great sorrow to this world.>
	Msg13 <あれは禁断のテクノロジーの知識から成る前時代のコンピュータだ。その中には、備蓄された核兵器を含む様々な忌まわしいものの有りかを示す情報が入っている。それは野心を持つ人間の手に渡れば、世界に大きな悲劇をもたらしうる。>
	%Msg14 <The Ruby is needed at HwangSa? Strange, Kaema would normally have come himself for so dangerous an artifact... Still, you are a monk in good standing, so I must trust you. Here is the Ruby. Return it to us once you are finished with it.>
	Msg14 <HwangSa があのルビーを必要としていると？ 妙だな、あれほど危険な人工物であれば、ふつう Kaema 自身が取りに来るはずだが…。だが、お前は高位の僧だから、私はお前を信用すべきだろう。これが例のルビーだ。用が済んだら返してくれ。>
	%Msg15 <The Ruby is needed at HwangSa? Strange, we have not been informed of this need through the regular channels. Still, I must trust in Kaema's judgement. Here is the Ruby. Return it to us once you are finished with it.>
	Msg15 <HwangSa があのルビーを必要としていると？ 妙だな、正規のルートではそのような知らせを受けていないが。だが、私は Kaema の判断を信用すべきだろう。これがそのルビーだ。用が済んだら返してくれ。>
	%Msg16 <Please do not try so obvious a deception in my presence again. All you have succeeded in doing is to reveal your own ineptitude.>
	Msg16 <二度と私の前でそのような見え透いた詐欺を働こうとしないように。お前がそうした詐欺を成功させればさせるほど、お前の愚かさは明らかになるのだ。>
	%Msg17 <You are clearly serious. We cannot allow you to endanger this world.>
	Msg17 <本気だということか。我々はお前がこの世界を危機にさらすのを見逃すわけにはいかない。>
	%Msg18 <The Ruby must remain here, for the sake of all. It is our purpose to keep the mistakes of the past from ever happening again... to that end, it would be best for the Ruby's existance to remain a secret, and for it to remain in our protection.>
	Msg18 <すべてのために、あのルビーはここにあるべきなのだ。過去の過ちを二度と繰り返させないようにするのが我々の目的である…。そのためには、あのルビーの存在を秘密にしておき、我々の庇護のもとに置いておくのが最善であろう。>
	%Msg19 <The sins of the past must never be repeated. If you are truly concerned with the future of this world and both our species, you will do what you can to protect this knowledge.>
	Msg19 <過去の過ちは繰り返されてはならない。もしお前が本当にこの世界と我々両方の種の未来を案じるのであれば、この知識を守るためにできることをするがいい。>
	%Msg21 <To disagree is your right, as a free individual. However, if you attempt to take the Ruby, we will be forced to protect it.>
	Msg21 <自由な個人であるからには、お前には反対する権利がある。しかし、もしお前があのルビーを奪おうというのなら、我々はルビーを守らざるを得ないだろう。>
	%Msg22 <It is far to the south of here. You better set off soon... it's quite a long trip.>
	Msg22 <Hwang-Sa 寺院はここからはるか南方にある。すぐに出発するがいい…。とても長い旅になるだろう。>
	%Prompt1 <No reason.>
	Prompt1 <何となく%JG。>
	%Prompt2 <I was sent by Kettel Industries.>
	Prompt2 <%JFは Kettel Industries の遣いだ。>
	%Prompt3 <I'm looking for the Iria Ruby.>
	Prompt3 <Iriaルビーを探している%JG。>
	%Prompt4 <Really.>
	Prompt4 <本当さ。>
	%Prompt5 <Actually, I'm looking for the Iria Ruby.>
	Prompt5 <実は、Iriaルビーを探している%JG。>
	%Prompt6 <I'm just here to investigate.>
	Prompt6 <ただ調査しに来ただけだ。>
	%Prompt7 <I'm here to get the Iria Ruby.>
	Prompt7 <Iriaルビーを取りに来た%JG。>
	%Prompt8 <I was sent to exterminate your kind!>
	Prompt8 <%JSたちの種を根絶しろと言われた%JG！>
	%Prompt9 <Uh, I need it for historic research.>
	Prompt9 <まあその、歴史研究に必要なんだ。>
	%Prompt10 <I was hired to retrieve it.>
	Prompt10 <それを取ってくるために雇われた%JG。>
	%Prompt11 <Why is the ruby so important?>
	Prompt11 <なぜそのルビーがそれほど重要なんだ？>
	%Prompt12 <Actually, Hwang-Sa Temple sent me here!>
	Prompt12 <実は Hwang-Sa 寺院に頼まれて来た%JG！>
	%Prompt13 <I'll take it whether you like it or not.>
	Prompt13 <%JSがどう思おうがルビーは持っていく。>
	%Prompt14 <I can see your point.>
	Prompt14 <なるほど。>
	%Prompt15 <I agree with you.>
	Prompt15 <確かに%JSの言う通りだ。>
	%Prompt16 <Sorry, I can't agree with that.>
	Prompt16 <残念だがその意見には賛成できない%JG。>
	%Prompt17 <I'll have to go there, I guess...>
	Prompt17 <そこへ行ったほうがよさそうだな…。>

end
inv
	Treasure 30000
	home <Storage Cell>
	name <IRIA Ruby>
	name_I18N <IRIAルビー>
	clue29 <if= V1 0 else GoDone ifYesNo 1 2 3 Mental ifG SkRoll 29 15 else GoNoDice Mental ifG SkRoll 32 10 else GoNoDice Mental ifG SkRoll 30 12 else GoNoDice Goto GoAccess>
	GoDone <Print 4>
	GoNoDice <Print 5>
	GoAccess <Mental Mental Reputation 7 -d20 Print 6 History 7 V= 1 1 PCStat+ 7 1 SkillXP 29 150 SkillXP 31 150 SkillXP 24 150 SkillXP 22 150 SkillXP 16 150 XPV 100>
	%Msg1 <This appears to be a PreZero AI core of some kind. Do you attempt to access the data inside?>
	Msg1 <これは旧紀のＡＩコアか何かのようだ。含まれるデータへのアクセスを試みるか？>
	%Msg2 <Try to access>
	Msg2 <アクセスを試みる>
	%Msg3 <Leave it alone>
	Msg3 <やめておく>
	%Msg4 <You've already learned all you can from the Ruby.>
	Msg4 <このルビーから学べることは既にすべて学んだ。>
	%Msg5 <You examine the Ruby extensively, but can't figure out how to access the data.>
	Msg5 <このルビーを様々な方法で調べてみたが、データにアクセスする方法は分からなかった。>
	%Msg6 <You make contact with the Ruby AI. Visions of the past age fill your head... Scientific knowledge is uploaded directly into your brain. You feel as though your central nervous system is about to burst from all the new information.>
	Msg6 <このルビーのＡＩにアクセスした。過去の時代の映像が頭の中に次々と浮かんだ…。科学的知識が脳に直接植えつけられた。まるで中枢神経がたくさんの新たな情報ではちきれるかのように感じる。>
	%Msg7 <You accessed data from the Iria Ruby.>
	Msg7 <Iriaルビーからデータを読み取った。>

end
