Story
	name <LM: Martian Princess>
	% A Martian Princess is on Earth, being pursued by assassins from
	% back home. If the PC aids her, he may get a new lancemate.

	% N1 is the scene in which the MP will be deployed.
	% N2 is the MP herself.
	Element2 <Prefab>
	Element3 <Prefab>

	% S1 = Initialization Counter (MP Reputation)
	%      If S1=1, PC has defeated the attackers
	% S2 = PC has fought the attackers (1)
	%      PC has spoken to the princess afterwards (2)
	%      FMR ambassador has arrived (3)
	% S3 = Have won combat exactly once

	% At startup, set the potential lancemate's skill level and reputation.
	Init_Start <ifNPCOK N2 else GoDelete if= S1 1 else GoInit S= 1 2 MoveChar N2 N1>
	start <ifNPCOK N2 else GoDelete if= S1 1 else GoInit S= 1 2 MoveChar N2 N1>
	GoInit <if= S1 0 S= 1 d50 S+ 1 10 NPCAbsoluteLevel N2 S1 SetNPCRep N2 6 S1 Compose ENC 2 .encounter>
	GoDelete <EndStory>
	.encounter <if= S2 0 if= d3 1 ifG PCScale 0 Block ifYesNo 1 2 3 else GoRefuse Goto GoStartCombat>
	% Failing to aid the princess results in the end of this story.
	GoRefuse <EndStory>
	GoStartCombat <SavePos Dynamic 2 Threat S1 120 .nu1 .nu2 S= 2 1 DynaNPC N2 -1 ComposeD START .encstart PassVar 1 N2>
	.nu1 <if= T1 0 if= L3 0 L= 3 1 LoseRenown Return>
	.nu2 <if= T2 0 if= L3 0 L= 3 1 XPV 100 Reputation 6 1 Reputation 1 1 Return>
	nu1 <if= T1 0 if= S3 0 S= 2 0>
	nu2 <if= T2 0 if= S2 1 if= S3 0 S= 3 1 S= 1 1 History 4 ifG SkRoll 11 15 else GoNU2NoSee Print 5>
	GoNU2NoSee <Print 6>
	.encstart <if= L2 0 ForceChat L1 L= 2 1>

	% Msg1 <In the distance you see a lone mecha pilot being pursued by several attackers.>
	Msg1 <遠くに一人のメックパイロットが数人の襲撃者に追われているのが見える。>
	% Msg2 <Help the pilot.>
	Msg2 <パイロットを助ける。>
	% Msg3 <It's none of my business.>
	Msg3 <関係ないな。>
	% Msg4 <You rescued Princess \NARRATIVE 2 from her Martian enemies.>
	Msg4 <\NARRATIVE 2 王女を火星の敵から救った。>
	% Msg5 <You see the Martian princess speed away in the direction of \NARRATIVE 1 .>
	Msg5 <火星の王女が \NARRATIVE 1 の方に離脱するのが見えた。>
	% Msg6 <You see the Martian princess speed away.>
	Msg6 <火星の王女が離脱していくのが見えた。>

	quarter <if= S2 2 if= d20 1 StoryLine .plot S= 2 3>
	.plot <TS_LANCE_Martian_PLOT_*.txt>

sub
	% In SubComponents, the persona for the princess.
	Persona 2
	greeting <NewChat ifG S2 1 else GoCheckFirst Say 3>
	GoCheckFirst <if= S1 2 else GoInCombat S= 2 2 PCAlly N2 AddReact 10 Say 2 GiveKeyItem N3 AddChat 1 AddChat 2>
	GoInCombat <EndChat Say 1>

	result1 <NewChat Reputation 1 1 Say 4>
	result2 <NewChat Reputation 6 1 Reputation 4 d10 ifG PCRep 6 NPCRep N2 6 else GoR2NoGood AddReact 10 Say 5>
	GoR2NoGood <Say 6>

	%Msg1 <My name is \NARRATIVE 2 of the Free Mars Republic. I was sent to Earth for safety, but the enemies of my people have followed me here. Help me to defeat them and you will be greatly rewarded.>
	Msg1 <私は火星自由共和国の \NARRATIVE 2 です。私は身の安全を図るため地球へ送られたのですが、ここまで敵につけられていたようです。彼らを倒すのに手をお貸しいただけたなら大いにお礼をいたします。>
	%Msg2 <\PC , we meet again. I didn't have a chance to reward you for helping to fight the assassins. I hope this emerald will be sufficient... I am unfamiliar with the customs of the birthworld, perhaps you can help me to learn.>
	Msg2 <またお会いしましたね、 \PC 。暗殺者と戦うのにご協力いただいたお礼をすることができませんでした。このエメラルドで十分だといいのですが…。私はこの「誕生の世界」での慣わしに疎いので、それを学ぶのを手助けしてくださいませんか？>
	%Msg3 <I feel so heavy on this planet... I hope it's just the gravity, and not the food...>
	Msg3 <この惑星ではとても体が重く感じます…。単に重力のせいであって、食べ過ぎのせいではないといいのですが…。>
	%Msg3_1 <I long to once more behold the red dust valley. The terrain on this planet is so alien and unfamiliar to me.>
	Msg3_1 <赤い塵の谷をもう一度眺めてみたい。この惑星の地形はとても異質で私には馴染み難いのです。>
	%Msg3_2 <I am standing on the world where humanity was born... but yet, this is not my home.>
	Msg3_2 <私は今、人類の生まれた世界に立っている…。しかし、ここは私の故郷ではありません。>
	%Msg4 <My planet is trapped in a never-ending series of wars. This place is supposed to be more peaceful, but I have learned there are many dangers here as well. Fortunately I am not entirely helpless.>
	Msg4 <私の惑星はもはや終わることのない戦争の連鎖にとらわれているのです。この場所はもっと安全なはずでしたが、しかし私はここにも同じように危険が多くあるのだと学びました。しかしありがたいことに、私にはまだ希望が残っている…。>
	%Msg5 <You are highly skilled... I may have need of your services again. So long as you defend me against the enemies of my people, I can guarantee that you will be rewarded.>
	Msg5 <あなたは凄腕のパイロットです…。またあなたの助けが必要になるかもしれません。あなたが私を火星の敵から守るかぎり、報酬は約束しましょう。>
	%Msg6 <There isn't much on this world that I cannot afford. Should I require assistance I will keep you in mind.>
	Msg6 <この世界では私の手が届かぬ物はそれほど多くありません。万が一助けが必要になることがあれば、あなたのことを心に留めておきましょう。>

	%Prompt1 <I'm glad to be of help.>
	Prompt1 <力になれて嬉しい%JG。>
	%Prompt2 <Maybe, if you can afford my rates.>
	Prompt2 <%JFの依頼料を払えるのなら考えてもいい。>

end
inv
	NPC Mecha Pilot
	job <Princess>
	chardesc Female Sociable
	EquipChar 5000
	statline 16 8 13 17 10 13 15 18
	SDL_COLORS <100 200 80  250 212 200  220 20 55>
	Age 1
	skill 12 5
	skill 17 15
	skill 19 10
	skill 39 10
	mecha <Neko.txt>
	%CHAT_ATTACK1 <These opponents are not worthy of my fantastic skill.>
	CHAT_ATTACK1 <この程度の相手では話になりません。>
	%CHAT_ATTACK2 <You would not last an hour on Mars.>
	CHAT_ATTACK2 <あなたでは火星では一時間と持たないでしょうね。>
	%CHAT_ATTACK3 <For the glory of my people!>
	CHAT_ATTACK3 <火星の栄光のために!>
	%CHAT_SAFE1 <How very interesting.>
	CHAT_SAFE1 <何と面白い…。>
	%CHAT_SAFE2 <They don't have this on my world.>
	CHAT_SAFE2 <これは私の星にはありません。>
	%CHAT_SAFE3 <What is this called?>
	CHAT_SAFE3 <これは何というものですか？>
	%CHAT_EJECT1 <My bloodline must be preserved!>
	CHAT_EJECT1 <わが血筋を絶やすわけにはまいりません！>

	BigTreasure 25
	name <Phobos Emerald>
	name_I18N <フォボス・エメラルド>
	mass 1
	clue29 <Print 1>
	%Msg1 <Emeralds like these are formed on Phobos and Demois during cosmic storms. This one seems unusually large.>
	Msg1 <このようなエメラルドはフォボスやダイモスで宇宙嵐を浴びて生まれる。このエメラルドの大きさは尋常でない。>
	clue37 <Print 2>
	%Msg2 <This enormous emerald is absolutely flawless... it must be worth a fortune.>
	Msg2 <この大きなエメラルドは文字通り完璧だ…売れば大金になるだろう。>


end
