Plot 0
	name <PLOT: Employment Trap>
	% The character has made an enemy in the corporate world.
	% This enemy will offer a job to the player- would you take
	% a job from your enemy? The job offer is valid, it's just
	% that the player will be facing many more enemies than he/she
	% can probably handle.

	element1 <Character Corporate ArchEnemy>
	% Element 2 -> Difficulcy Level


	% Time limit - this plot will fade after a short time.
	Init_Start <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 22500>
	START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 22500>
	GotoCheckTime <ifG ComTime V1 if= V2 0 AdvancePlot 0>

	% If combat has been entered, V2 = 1. This is important to keep
	% the events below from activating in scenes other than the
	% plot's combat...
	NU1 <if= T1 0 if= V2 1 AdvancePlot 1 LoseRenown LoseRenown     V= 2 2>
	NU2 <if= T2 0 if= V2 1 AdvancePlot 2 XPV 250 Reputation 6 1    V= 2 2>


sub

	Persona 1
	% V1 = Encounter PV.
	greeting <NewChat ifG PCMeks 0 else GoNoMeks if= E2 0 else GoAlreadyMet ifG React 24 else GoDoTrap Say 2 AdvancePlot 0>
	% rumor <!1 has a job available for a mecha pilot.>
	rumor <!1 はメックパイロット向けの仕事を用意している>
	GoAlreadyMet <Say 14  AddChat 7 AddChat 8 AddChat 9>
	GoNoMeks <EndChat Say 1 AdvancePlot 0>
	GoDoTrap <ifG React 0 else GoNoLike Say 3  AddChat 1 AddChat 2 AddChat 4>
	GoNoLike <ifG PCRep 6 d80 else GoNoRep Say 4  AddCHat 3 AddCHat 5>
	GoNoRep <ifG -5 PCRep 6 else GoNoWangtta Say 5  AddChat 2 AddCHat 1>
	GoNoWangtta <ifG PCRep 1 d50 else GoNoHero Say 6  AddChat 2 AddCHat 3>
	GoNoHero <ifG 0 PCRep 1 else GoNoVillain Say 7  AddChat 1 AddChat 5>
	GoNoVillain <ifG 0 PCRep 2 else GoNoChaos Say 8  AddChat 2 AddChat 3 AddChat 4>
	GoNoChaos <Say 9  AddCHat 1 AddCHat 2 AddChat 4>


	result1 <NewChat Say 12  AddCHat 6>
	result2 <NewChat AddReact -5 Say 10>
	result3 <Goto GoDescription>
	result4 <NewChat Say 13  AddChat 6>
	result5 <NewChat Say 11>
	result6 <Goto GoDescription>

	GoDescription <ifG PCRep 6 90 Else GoLvl9 V= 1 18000000 E= 2 10 Say 101 goto GoChoose>
	GoLvl9 <ifG PCRep 6 80 Else GoLvl8 V= 1 13000000 E= 2 9 Say 102 goto GoChoose>
	GoLvl8 <ifG PCRep 6 70 Else GoLvl7 V= 1  6600000 E= 2 8 Say 103 goto GoChoose>
	GoLvl7 <ifG PCRep 6 60 Else GoLvl6 V= 1  5100000 E= 2 7 Say 104 goto GoChoose>
	GoLvl6 <ifG PCRep 6 50 Else GoLvl5 V= 1  3200000 E= 2 6 Say 105 goto GoChoose>
	GoLvl5 <ifG PCRep 6 40 Else GoLvl4 V= 1  2500000 E= 2 5 Say 106 goto GoChoose>
	GoLvl4 <ifG PCRep 6 30 Else GoLvl3 V= 1  1800000 E= 2 4 Say 107 goto GoChoose>
	GoLvl3 <ifG PCRep 6 20 Else GoLvl2 V= 1  1400000 E= 2 3 Say 108 goto GoChoose>
	GoLvl2 <ifG PCRep 6 10 Else GoLvl1 V= 1   800000 E= 2 2 Say 109 goto GoChoose>
	GoLvl1 <                           V= 1   675000 E= 2 1 Say 110 goto GoChoose>
	GoChoose <NewChat  AddChat 7 AddChat 8 AddChat 9>

	result7 <EndChat Say 15 P= 2 1 SavePos Dynamic 2 V1 FrzNU1 FrzNU2 Encounter 1 75 .enemydata>
	FrzNU1 <if= T1 0 Return>
	FrzNU2 <if= T2 0 Salvage Return>
	.EnemyData <Villainous ArchEnemy>

	result8 <NewChat Say 16>
	result9 <EndChat Say 17  AdvancePlot 0 Reputation 6 -5 Reputation 6 d4 AddReact -10>

	% Msg1 <Do not disturb me while I am thinking. Go away.>
	Msg1 <考え事の邪魔をしないでください。しっしっ。>
	% Msg2 <Be careful about the types of work you get involved in. Not everyone is willing to concern themselves with whether you live or you die.>
	Msg2 <引き受ける仕事はよく選ぶことです。依頼主が皆、あなたの生死を気にかけるわけではありません。>
	% Msg3 <Our company always has job openings available for skilled pilots.>
	Msg3 <我が社は常に熟練したメックパイロット向けの仕事を用意しています。>
	% Msg4 <You know that I don't particularly like you... But our company has a situation, and I need the best pilot available. That's you.>
	Msg4 <知っての通り私はあなたのことを別に気に入っていません…。しかし、我が社は今困った事態を抱えているため、私は手の空いている優秀なパイロットを必要としています。そこであなたにお願いがあります。>
	% Msg5 <I need to hire a mecha pilot. Our company currently has openings for pilots of all skill levels.>
	Msg5 <私はメックパイロットを必要としています。 現在我が社は腕前を問わずメックパイロットを募集しています。>
	% Msg6 <A group of evil terrorists have been attacking our factories. Many workers have lost their lives... I don't particularly like you, but we need a pilot to stop these raiders before anyone else gets hurt.>
	Msg6 <我々の工場が邪悪なテロリストの集団に攻撃をうけており、数多くの労働者が命を落としています…。私は別にあなたのことを気に入っていませんが、これ以上被害者が出る前にあの襲撃者を止めてくれるパイロットが必要です。>
	% Msg7 <Often corporations have to deal with unpleasant work. There's always a need for mecha pilots who are not moved by weaknesses like hesitation or mercy.>
	Msg7 <企業はしばしば不快な仕事も扱わなければなりません。慈悲やためらいといった甘さに動じないメックパイロットが常に必要です。>
	% Msg8 <Our company has a few quasilegal issues which need to be resolved. I could use a good pilot with a talent for subterfuge. Are you interested in earning some money?>
	Msg8 <我が社は半ば法的な問題を抱えており、それを解決しなければなりません。そこで私は口のうまいパイロットを雇いたく思います。お金稼ぎはどうですか？>
	% Msg9 <Our corporation is currently hiring mecha pilots for various duties. No skilled applicants will be turned away.>
	Msg9 <我が社は現在様々な仕事向けにメックパイロットを募集しています。腕のいい志願者なら誰でも受け入れましょう。>
	% Msg10 <One way or the other, you will be...>
	Msg10 <どちらにしろ、あなたは…。>
	% Msg11 <That's just as well. You aren't my kind of employee.>
	Msg11 <それでも結構です。あなたも私の雇うような人ではありませんから。>
	% Msg12 <As a matter of fact, I do. You will be paid handsomely to protect this company's interests against hostile forces. Are you interested?>
	Msg12 <実は、その通りです。敵部隊から我が社の利益を守ってくれればかなりの金額を支払いましょう。どうですか？>
	% Msg13 <I believe you might have the qualities that we're looking for. You will be paid handsomely to protect this company's interests against hostile forces. Are you interested?>
	Msg13 <あなたなら我々が求めている程度の技量を持ち合わせているかもしれませんね。敵部隊から我が社の利益を守ってくれればかなりの金額を支払いましょう。どうですか？>
	% Msg14 <Are you ready for the mission we discussed yet? I've been waiting for you to get back.>
	Msg14 <我々が話した仕事の準備は整いましたか？ あなたが戻るのを待っていたのですよ。>
	% Msg15 <Here are all the details which you need to know. Report back here once the mission has been completed.>
	Msg15 <こちらがあなたが知る必要のある詳細情報のすべてです。任務が完了したらここへ戻りなさい。>
	% Msg16 <Certainly. Make sure that your equipment is in top shape before proceeding; I'd hate to see anything bad happen to you out there.>
	Msg16 <了解しました。作戦開始前に装備を万全に整えなさい。あなたに何かあってほしくはありませんから。>
	% Msg17 <I should've known that you couldn't handle this kind of mission. I guess you aren't much of a pilot after all.>
	Msg17 <所詮あなたにはこの類の仕事は扱えないと分かっておくべきでした。結局あなたは大したパイロットではありませんね。>

	% Msg101 <Your target is a large force of mecha raiders. Should be no problem for a pilot of your caliber. Pay is $120000.>
	Msg101 <あなたの標的はメックを有する襲撃者の大部隊ですが、あなたほどのメックパイロットなら問題なく倒せるでしょう。報酬は $120000 です。>
	% Msg102 <I need you to eliminate this gang of mecha bandits. They have a few heavy mecha, but nothing too serious. Your reward will be $65000.>
	Msg102 <メックを有する賊の一団を殲滅してください。彼らは大型メックを数機持っていますが、それほど問題はないでしょう。報酬は $65000 になります。>
	% Msg103 <You'll be going up against a large force of enemy mecha. I wouldn't expect them to put up much of a fight, though. The fee for this job is $33000.>
	Msg103 <あなたは敵メックの大部隊と戦うことになります。彼らは数こそ多けれどそれほど手ごわくはないと思います。この仕事の報酬は $33000 です。>
	% Msg104 <I need you to destroy a small gang of heavy mecha pilots. You'll be paid $17000 for this mission.>
	Msg104 <大型メックパイロットの小部隊を倒してください。この任務を遂行すれば $17000 を支払います。>
	% Msg105 <You must eliminate a gang of moderately experienced mecha pilots. Should be a piece of cake for someone of your abilities. Pay is $9000.>
	Msg105 <そこそこ腕の立つメックパイロットの一団を殲滅してください。あなたほどの腕を持つ人物にとっては楽な仕事でしょう。報酬は $9000 です。>
	% Msg106 <Your target is a medium sized gang of light mecha armors. Pay will be $5000 upon elimination of the enemy.>
	Msg106 <あなたの標的は小型メックの中部隊です。敵を殲滅すれば $5000 支払います。>
	% Msg107 <I need you to get rid of a small gang of enemy mecha. There shouldn't be more than 3 enemies to deal with. Your salary will be $3000.>
	Msg107 <敵メックの小部隊を排除してください。戦うべき敵は多くても３機でしょう。報酬は $3000 になります。>
	% Msg108 <Your mission is to eliminate a small mecha team which has been causing us trouble. I can give you $2000 for the mission.>
	Msg108 <あなたの任務は我々を悩ませているメック小隊を殲滅することです。この任務をやってくれれば $2000 支払いましょう。>
	% Msg109 <I need for you to destroy a small group of bandits. They shouldn't have anything bigger than a few light mechs. This job is worth $1000.>
	Msg109 <賊の小部隊を倒してください。彼らの戦力はせいぜい小型メック数機程度のはずです。この仕事は $1000 になります。>
	% Msg110 <I need for you to eliminate a small gang of powered armor raiders. Your pay will be $750.>
	Msg110 <武装した襲撃者の小部隊を殲滅してください。報酬は $750 になります。>

	% Prompt1 <Do you have a job for me?>
	Prompt1 <%JFに頼みたい仕事があるのか？>
	% Prompt2 <I'm not a corporate slave.>
	Prompt2 <%JFは企業の奴隷ではない%JG。>
	% Prompt3 <Okay, I'll help you.>
	Prompt3 <分かった、手を貸そう。>
	% Prompt4 <If you need a good pilot, you need me.>
	Prompt4 <腕利きのパイロットが必要なら、%JFがいる。>
	% Prompt5 <This isn't my kind of work.>
	Prompt5 <%JFのやるような仕事ではない%JG。>
	% Prompt6 <Tell me more.>
	Prompt6 <詳細を聞こう。>
	% Prompt7 <I'm ready to fight.>
	Prompt7 <戦いに行ける%JG。>
	% Prompt8 <Just give me some time to get ready.>
	Prompt8 <準備に時間をくれ。>
	% Prompt9 <Maybe I don't want this job...>
	Prompt9 <この仕事はやりたくない%JG…。>


	Plot 1
		% The player lost the battle.
		% Time limit - this plot will fade after a short time.
		Init_Start <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 17500>
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 17500>
		GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
	sub
		Persona 1
		greeting <NewChat Say d6 AddReact -5 AdvancePlot 0>
		% Msg1 <I should have known that you were going to fail. You are a disgrace.>
		Msg1 <あなたが失敗すると分かっておくべきでした。あなたにはがっかりです。>
		% Msg2 <That mission was a complete failure, thanks to you.>
		Msg2 <あなたのせいで、作戦は完全に失敗しました。>
		% Msg3 <I'm suprised you have the gall to show your face here after how badly you did on that mission.>
		Msg3 <任務であれほどひどい失敗をしてもここに顔を出そうというそのずうずうしさには呆れますね。>
		% Msg4 <That was one of the worst failures that I've ever witnessed. You are a shame as a pilot.>
		Msg4 <今回の失敗は私がこれまで見てきた中でも最もひどいものでした。あなたはパイロットの恥です。>
		% Msg5 <What was that? Did you even try to put up a fight, or did you fall asleep at the wheel out there?>
		Msg5 <何ですかあれは？ あれでも精一杯戦ったのですか？それとも居眠り運転でもしていたのですか？>
		% Msg6 <It would have been better if you had died on the field than have to live with the shame of such a horrible defeat. You are a disgrace as a pilot.>
		Msg6 <あれほどひどい負け方をしたという恥を背負って生きるよりは戦場で死んだほうがましでしょうね。あなたはパイロットの恥です。>
	end

	Plot 2
		% The player won the battle.
		% Time limit - this plot will fade after a short time.
		Init_Start <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 17500>
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 17500>
		GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
	sub
		Persona 1
		greeting <NewChat Say d6 AdvancePlot 0 if= E2 10 Else GoLvl9 CashPrize 120000>
		GoLvl9 <if= E2 9 Else GoLvl8 CashPrize 65000>
		GoLvl8 <if= E2 8 Else GoLvl7 CashPrize 33000>
		GoLvl7 <if= E2 7 Else GoLvl6 CashPrize 17000>
		GoLvl6 <if= E2 6 Else GoLvl5 CashPrize  9000>
		GoLvl5 <if= E2 5 Else GoLvl4 CashPrize  5000>
		GoLvl4 <if= E2 4 Else GoLvl3 CashPrize  3000>
		GoLvl3 <if= E2 3 Else GoLvl2 CashPrize  2000>
		GoLvl2 <if= E2 2 Else GoLvl1 CashPrize  1000>
		GoLvl1 <CashPrize 750>

		% Msg1 <You made it back here alive? I'm suprised. You're better than I thought. Here's your cash.>
		Msg1 <生きて帰ったのですか？これは驚きました。あなたは思ったより腕利きですね。こちらが報酬です。>
		% Msg2 <How on earth did you manage that? Well, you completed the mission... Here's your pay.>
		Msg2 <一体どうやってあの状況を克服できたのですか？まあ、あなたは任務を遂行しました…。こちらが報酬です。>
		% Msg3 <I hope you realize how lucky you are. Here's the pay that you just earned.>
		Msg3 <あなたがどれだけ自分が幸運か自覚していることを願う限りです。こちらがあなたへの報酬です。>
		% Msg4 <You were very lucky out there today, but that luck must run out sometime. Here's your money.>
		Msg4 <今日はあなたは大変ついていたようですが、その幸運もいつかは尽きましょう。こちらが報酬です。>
		% Msg5 <You're a luckier pilot than I had thought. Here's the cash you earned.>
		Msg5 <あなたは思ったより幸運なパイロットですね。こちらがあなたの報酬です。>
		% Msg6 <Why are you still alive? Er, I mean, congradulations on a job well done... Here's your pay.>
		Msg6 <なぜまだ生きているのです？ あ、その、任務成功おめでとうございます…。こちらが報酬です。>
	end

end
