# ---- language-env DON'T MODIFY THIS LINE!
# ----- Ū -----
# XIM С̾
# (XIM ϡlanguge-env ǻȤѿǤ)
set XIM=kinput2
# xprop ϡxbase-clients ѥå˴ޤޤޤ
if ( $?WINDOWID && -x /usr/bin/X11/xprop ) then
  # X Window System äƤ뤱 X Window System ̿븢¤
  # ʤȤ (su Ȥʤ) ؤк
  xprop -id $WINDOWID >& /dev/null || unset WINDOWID
endif
if ( $?WINDOWID && -x /usr/bin/X11/xprop ) then
  set XPROP=`xprop -id $WINDOWID WM_CLASS` >&/dev/null
  set CLASS=`echo $XPROP | sed -e 's/.*WM_CLASS(STRING) = "//' -e 's/[",]//g'`
  switch ("$CLASS")
  case *kterm* :
    set LANG=ja_JP.eucJP ; breaksw
  case *krxvt* :
    set LANG=ja_JP.eucJP ; breaksw
  case *k[aw]term* :
    set LANG=ja_JP.eucJP ; breaksw
  case *UXTerm* :
    set LANG=ja_JP.UTF-8 ; breaksw
  case *hanterm* :
    set LANG=ko_KR.eucKR ; breaksw
  case *caterm* :
    set LANG=zh_TW.Big5 ; breaksw
  case *crxvt-big5* :
    set LANG=zh_TW.Big5 ; breaksw
  case *crxvt-gb* :
    set LANG=zh_CN.GB2312 ; breaksw
  case *[xa]term* :
    set LANG=C ; breaksw
  default:
    breaksw
  endsw
else
  if ( $TERM == "linux" || $TERM == "xterm" || $TERM == "xterm-debian" ) then
    set LANG=C
  else
    set LANG=ja_JP.eucJP
  endif
endif
switch ($LANG)
  case ja_JP.eucJP:
    set JLESSCHARSET=japanese-euc ; set LV=-Oej ; breaksw
  case ja_JP.UTF-8:
    set JLESSCHARSET=utf-8 ; set LV=-Ou8 ; breaksw
  default:
    set JLESSCHARSET=latin1 ; set LV=-Al1
endsw
setenv LANG $LANG
setenv JLESSCHARSET $JLESSCHARSET
setenv LV $LV
setenv PAGER more
foreach pager ( lv jless less )
  if ( -x /usr/bin/$pager ) then
    setenv PAGER $pager
    break
  endif
end
# XMODIFIERS  setenv ʤΤϡemacs  Segmentation Fault 򵯤
# ˡȡDebian ˥塼ƥफεưˤбǤʤ
alias xemacs '(unsetenv XMODIFIERS ; exec \xemacs \!*)'
# nvi-m17n-canna ޤ nvi-m17n 󥹥ȡ뤵ƤФͥ
# Ū˻ȤʤŤäȤ򤷤ƤΤա
alias vi ':\
  if ( -x /usr/bin/nvi-m17n-canna ) then \
    (setenv NEXINIT "source ~/.nexrc-m17n-canna" ; exec /usr/bin/nvi-m17n-canna \!*) \
  else if ( -x /usr/bin/nvi-m17n ) then \
    (setenv NEXINIT "source ~/.nexrc-m17n" ; exec /usr/bin/nvi-m17n \!*) \
  else \
    \vi \!* \
  endif\
'
alias nvi-m17n '(setenv NEXINIT "source ~/.nexrc-m17n" ; exec /usr/bin/nvi-m17n \!*)'
alias nvi-m17n-canna '(setenv NEXINIT "source ~/.nexrc-m17n-canna" ; exec /usr/bin/nvi-m17n-canna \!*)'
# perl ˤ󤹤˥󥰤ФͭˤƤ
# setenv PERL_BADLANG 0
# ----- ߤ˱ -----
# ls ưman ls 
if ( $TERM == "dumb" || $TERM == "emacs" ) then
  alias ls 'ls -F'
else
  alias ls 'ls -F --color=auto'
endif
# ɸ२ǥ vi ˤ롣Debian Policy Manual 
setenv EDITOR vi
# ץץȡman tcsh 
set promptchars='%#'
set prompt='%B%~%#%b '
# mh 󥹥ȡ뤵Ƥ顢PATH ˲ä롣
[ -x /usr/bin/mh/mhmail ]
if ($status == 0) then
  set path=($path /usr/bin/mh)
endif
# եȤɤ°Ǻ뤫man umask 
umask 022
# less ưman less 
setenv LESS -M
if ( -x /usr/bin/lesspipe ) then
  setenv LESSOPEN "| /usr/bin/lesspipe '%s'"
  setenv LESSCLOSE "/usr/bin/lesspipe '%s' '%s'"
endif
# Ctrl-D ǥȤΤ롣man tcsh 
set ignoreeof
# ȥǥ쥯ȥΥХååץեɽ
# (ݤ "chkbackups | xargs rm" ¹ԤΤ)
alias chkbackups '/usr/bin/find . -name "?*~" -o -name "?*.bak" -o -name ".[^.]?*~" -o -name ".[^.]?*.bak" -maxdepth 1'
# X Window System Ǥ
if ( $?DISPLAY ) then
  # üɥΥȥѹ
  alias xtitle '/bin/echo -e "\033]0;\!*\007\c"'
endif
# ---- language-env end DON'T MODIFY THIS LINE!
