; BlancoEclipseDistribution
;
;  This library is free software; you can redistribute it and/or
;  modify it under the terms of the GNU Lesser General Public
;  License as published by the Free Software Foundation; either
;  version 2.1 of the License, or (at your option) any later version.
;
; BlancoEclipseDistributionInno SetuppXNvgt@CłB
; GNU LGPLCZX̂ƌJĂ܂B
;
; yfBNgz
;  eclipse Ȃǂ̕Kvt@CꎮɂāA炩߉𓀂ďĂZbgAbv쐬܂B

[Setup]
AppVerName=BlancoEclipseDistribution (3.3.2-[[date]])
AppName=BlancoEclipseDistribution
AppPublisher=blanco Framework
AppPublisherURL=http://www.igapyon.jp/blanco/
AppSupportURL=http://www.igapyon.jp/blanco/
AppUpdatesURL=http://www.igapyon.jp/blanco/
DefaultDirName={pf}\eclipse
DefaultGroupName=Eclipse
LicenseFile=doc\license.txt
InfoBeforeFile=doc\readme.txt
OutputBaseFilename=blancoEclipseDistribution-[[date]]
OutputDir="bin"
Compression=lzma
SolidCompression=yes
ShowLanguageDialog=no

[Languages]
Name: "eng"; MessagesFile: "compiler:Default.isl"
Name: "jap"; MessagesFile: "compiler:Languages\Japanese.isl"

[Tasks]
Name: "desktopicon" ;Description: "{cm:CreateDesktopIcon}" ;GroupDescription: "{cm:AdditionalIcons}" ;Flags: unchecked

[Types]
Name: "typical"     ;Description: "Eclipse Classic (SDK) 3.3.2 (+NLpack) + typical plugins"
Name: "eclipsesdk"  ;Description: "Eclipse Classic (SDK) 3.3.2 (+NLpack)"
Name: "custom"      ;Description: "Custom" ;Flags: iscustom

[Components]
Name: "doc"          ;Description: "Document"                          ;Types: typical eclipsesdk custom ;Flags: fixed
Name: "eclipsesdk"   ;Description: "Eclipse Classic (SDK) 3.3.2"       ;Types: typical eclipsesdk custom ;Flags: fixed
Name: "eclipsenlpack";Description: "Eclipse Classic (SDK) 3.3.2 NLpack";Types: typical eclipsesdk custom
Name: "blancofw"     ;Description: "blanco Framework"                  ;Types: typical custom
Name: "stepcounter"  ;Description: "StepCounter"                       ;Types: typical custom
Name: "subversive"   ;Description: "Subversive (experimental)"         ;Types: custom

[Files]
Source: "doc\*"                    ;DestDir: "{app}\doc"  ;Components: doc          ;Flags: ignoreversion recursesubdirs createallsubdirs
Source: "img\eclipse\*"            ;DestDir: "{app}"      ;Components: eclipsesdk   ;Flags: ignoreversion recursesubdirs createallsubdirs
Source: "build.xml"                ;DestDir: "{app}\src"  ;Components: eclipsesdk   ;Flags: ignoreversion
Source: "eclipseinst.iss"          ;DestDir: "{app}\src"  ;Components: eclipsesdk   ;Flags: ignoreversion
Source: "img\eclipse.nlpack\eclipse\*" ;DestDir: "{app}[[dropins-subdir]]"  ;Components: eclipsenlpack;Flags: ignoreversion recursesubdirs createallsubdirs
Source: "img\plugins\blancofw\*"   ;DestDir: "{app}[[dropins-subdir]]"      ;Components: blancofw     ;Flags: ignoreversion recursesubdirs createallsubdirs
Source: "img\plugins\stepcounter\*";DestDir: "{app}[[dropins-subdir]]"      ;Components: stepcounter  ;Flags: ignoreversion recursesubdirs createallsubdirs
Source: "img\plugins\subversive\*" ;DestDir: "{app}[[dropins-subdir]]"      ;Components: subversive   ;Flags: ignoreversion recursesubdirs createallsubdirs

[Icons]
Name: "{group}\Eclipse Classic (SDK) 3.3.2"            ;Filename: "{app}\eclipse.exe"
Name: "{group}\Eclipse Classic (SDK) 3.3.2 (384MB)"    ;Filename: "{app}\eclipse.exe"        ;Parameters: "-vmargs -Xms384M -Xmx384M"
Name: "{group}\Eclipse Classic (SDK) 3.3.2 (en_US)"    ;Filename: "{app}\eclipse.exe"        ;Parameters: "-vmargs -Duser.language=en -Duser.country=US"
Name: "{group}\Eclipse Classic (SDK) 3.3.2 (clean)"    ;Filename: "{app}\eclipse.exe"        ;Parameters: "-clean"
Name: "{group}\Eclipse Classic (SDK) 3.3.2 (consolelog)";Filename: "{app}\eclipse.exe"       ;Parameters: "-consolelog -debug"
Name: "{group}\Eclipse Classic (SDK) 3.3.2 (initialize)";Filename: "{app}\eclipse.exe"       ;Parameters: "-initialize"
Name: "{group}\Eclipse Foundation Software User Agreement";Filename: "{app}\notice.html"
Name: "{group}\Eclipse Public License 1.0"             ;Filename: "{app}\epl-v10.html"
Name: "{group}\Eclipse Project Release Notes"          ;Filename: "{app}\readme\readme_eclipse.html"
Name: "{group}\blancofw-readme"                        ;Filename: "{app}\doc\readme.txt"
Name: "{group}\blancofw-LICENSE"                       ;Filename: "{app}\doc\license.txt"
Name: "{userdesktop}\Eclipse Classic (SDK) 3.3.2"      ;Filename: "{app}\eclipse.exe"        ;Tasks: desktopicon

[Run]
Filename: "{app}\eclipse.exe" ;Description: "{cm:LaunchProgram,BlancoEclipseDistribution}"   ;Parameters: "-clean" ;Flags: nowait postinstall skipifsilent

; END OF FILE
